R_SalesContractItemPartnerTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_DfltAddrRprstn' ]
}

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}

@ObjectModel.semanticKey: ['SalesContract', 'SalesContractItem', 'PartnerFunction']

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Sales Contract Item Partner - TP'
define view entity R_SalesContractItemPartnerTP
  as select from I_SalesDocItemCompletePartner as ItemPartner

    inner join   I_SalesDocumentBasic          as SalesContract on  SalesContract.SalesDocument      = ItemPartner.SalesDocument
                                                                and SalesContract.SDDocumentCategory = 'G'

  association [1..1] to R_SalesContractTP            as _SalesContract          on  $projection.SalesContract = _SalesContract.SalesContract

  association        to parent R_SalesContractItemTP as _Item                   on  $projection.SalesContract     = _Item.SalesContract
                                                                                and $projection.SalesContractItem = _Item.SalesContractItem
  association [0..1] to I_PartnerFunction            as _PartnerFunction        on  $projection.PartnerFunctionForEdit = _PartnerFunction.PartnerFunction
  association [0..1] to I_FormOfAddress              as _FormOfAddress          on  $projection.FormOfAddress = _FormOfAddress.FormOfAddress
  association [0..1] to I_Language                   as _CorrespondenceLanguage on  $projection.CorrespondenceLanguage = _CorrespondenceLanguage.Language
  association [0..1] to I_TransportationZone         as _TransportationZone     on  $projection.transportzone = _TransportationZone.TransportZone
                                                                                and $projection.country       = _TransportationZone.CountryCode

{

  key cast(ItemPartner.SalesDocument as sales_contract preserving type)          as SalesContract,

  key cast(ItemPartner.SalesDocumentItem as sales_contract_item preserving type) as SalesContractItem,

  key cast(ItemPartner.PartnerFunction as parvw_unv preserving type )            as PartnerFunction,

      @ObjectModel.foreignKey.association: '_PartnerFunction'
      cast(ItemPartner.PartnerFunction as parvw_unv preserving type )            as PartnerFunctionForEdit,
      ItemPartner.Customer,
      ItemPartner.Supplier,
      @ObjectModel.text.element: ['FullName']
      ItemPartner.Partner,

      @Semantics.name.fullName: true
      @Semantics.text: true
      ItemPartner.FullName,

      _PartnerFunction.SDDocumentPartnerType,

      ItemPartner.PartnerIsSpecificForSDDocItem,

      ItemPartner.ReferenceBusinessPartner,
      ItemPartner.Personnel,
      ItemPartner.ContactPerson,
      ItemPartner.SDDocPartnerAddrIsDocSpecific,

      @ObjectModel.foreignKey.association: '_FormOfAddress'
      @Semantics.name.jobTitle: true
      ItemPartner.FormOfAddress,

      @ObjectModel.foreignKey.association: '_CorrespondenceLanguage'
      ItemPartner.CorrespondenceLanguage,

      @ObjectModel.foreignKey.association: '_TransportationZone'
      ItemPartner._OrgNamePostalAddress.TransportZone,

      @Semantics.address.street: true
      ItemPartner._OrgNamePostalAddress.StreetName,

      @Semantics.address.streetNoNumber: true
      ItemPartner._OrgNamePostalAddress.HouseNumber,

      @Semantics.address.zipCode:true
      ItemPartner._OrgNamePostalAddress.PostalCode,

      @Semantics.address.country:true
      @ObjectModel.foreignKey.association: '_Country'
      ItemPartner._OrgNamePostalAddress.Country,

      @ObjectModel.foreignKey.association: '_Region'
      @Semantics.address.region: true
      ItemPartner._OrgNamePostalAddress.Region,

      ItemPartner._OrgNamePostalAddress.DistrictName,

      @Semantics.address.city:true
      ItemPartner._OrgNamePostalAddress.CityName,

      @Semantics.address.postBox: true
      ItemPartner._OrgNamePostalAddress.POBox,

      @Semantics.address.zipCode:true
      ItemPartner._OrgNamePostalAddress.POBoxPostalCode,

      ItemPartner._OrgNamePostalAddress.TaxJurisdiction,


      ItemPartner.AddressID,

      ItemPartner.AddressPersonID,

      ItemPartner.AddressObjectType,

      ItemPartner.SDDocPartnerAddressRefType,

      ItemPartner.BPAddrDeterminationTransaction,

      ItemPartner.BPRefAddressIDForDocSpcfcAddr,

      ItemPartner.VATRegistration,

      @Semantics.text: true
      ItemPartner.UnloadingPointName,

      @Semantics.telephone.type: [#WORK]
      ItemPartner.InternationalPhoneNumber,

      @Semantics.telephone.type:  [#CELL]
      ItemPartner.InternationalMobilePhoneNumber,

      @Semantics.eMail.address: true
      @Semantics.eMail.type:  [#WORK]
      ItemPartner.EmailAddress,

      @Consumption.hidden: true
      _SalesContract.SalesContractType,
      @Consumption.hidden: true
      _SalesContract.SalesOrganization,
      @Consumption.hidden: true
      _SalesContract.DistributionChannel,
      @Consumption.hidden: true
      _SalesContract.OrganizationDivision,

      //Associations

      _Item,
      _SalesContract,
      _PartnerFunction,
      _CorrespondenceLanguage,
      _TransportationZone,
      _FormOfAddress,

      ItemPartner._ContactPerson,
      ItemPartner._DfltAddrRprstn,
      ItemPartner._BusinessPartnerAddress,
      ItemPartner._BPRefAddressForDocSpcfcAddr,
      ItemPartner._OrgNamePostalAddress._Country,
      ItemPartner._OrgNamePostalAddress._Region
} 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRORGNAMEPOSTALADDRESS",
"I_PARTNERFUNCTION",
"I_SALESDOCITEMCOMPLETEPARTNER",
"I_SALESDOCUMENTBASIC",
"R_SALESCONTRACTTP"
],
"ASSOCIATED":
[
"I_ADDRESS_2",
"I_BUSPARTADDRESS",
"I_CONTACTPERSON",
"I_COUNTRY",
"I_FORMOFADDRESS",
"I_LANGUAGE",
"I_PARTNERFUNCTION",
"I_REGION",
"I_TRANSPORTATIONZONE",
"R_SALESCONTRACTITEMTP",
"R_SALESCONTRACTTP"
],
"BASE":
[
"I_ADDRORGNAMEPOSTALADDRESS",
"I_SALESDOCITEMCOMPLETEPARTNER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/