R_REContrOrglAssgmtTermTP

@AccessControl.authorizationCheck: #CHECK

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]

@ObjectModel.representativeKey: 'RETermNumber'
@Analytics.technicalName: 'RRECNORGASSTP' 
@ObjectModel.semanticKey: ['InternalRealEstateNumber', 'RETermType', 'RETermNumber', 'ValidityStartEndDateValue' ]
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@EndUserText.label: 'Real Estate Orgl Assgmt Term TP'

define view entity R_REContrOrglAssgmtTermTP
  as select from I_REOrganizationalAssgmtTerm as _REOrganizationalAssgmtTerm
  association        to parent R_REContractTP       as _REContract              on $projection.InternalRealEstateNumber = _REContract.InternalRealEstateNumber
  association [1..1] to I_REEntryValidity           as _REEntryValidity        on  $projection.REEntryValidity = _REEntryValidity.REEntryValidity
  
// Additional view non draft/RAP relevant fields

  association [1..1] to I_REOrglAssgmtTermAddl      as _REOrglAssgmtTermAddl    on $projection.InternalRealEstateNumber = _REOrglAssgmtTermAddl.InternalRealEstateNumber
                                                                                    and $projection.RETermType = _REOrglAssgmtTermAddl.RETermType
                                                                                    and $projection.RETermNumber = _REOrglAssgmtTermAddl.RETermNumber
                                                                                    and $projection.ValidityStartDate = _REOrglAssgmtTermAddl.ValidityStartDate                                                                          
{
  key       InternalRealEstateNumber,
  key       RETermType,
  key       RETermNumber,
  key       cast(concat(ValidityStartDate, ValidityEndDate ) as recadateperiod) as ValidityStartEndDateValue,
            //  Workaround Smart Elements Fiori DATS Null value issue: cast to tstmp and back to dats in case of null

            @Semantics.businessDate.from: true
            cast( coalesce(ValidityStartDate,'00000000' ) as rebdvdmvalidfrom ) as ValidityStartDate,
            
            @ObjectModel.foreignKey.association: '_REEntryValidity'
            case
              when ValidityStartDate > $session.system_date then cast ('2' as recavdmentryvalidity)
              when ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date then cast('3' as recavdmentryvalidity)
              else cast ('1' as recavdmentryvalidity)
            end                                                                 as REEntryValidity,

            case
              when ValidityStartDate > $session.system_date then 2
              when ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date then 3
              else 1
            end                                                                 as REEntryValidityCriticality,

            _RETerm.RETermName,
            RealEstateObjectType,
            _REKeyAssgmt.REIdentificationKey,
            ValidityEndDate,
            BusinessArea,
            ProfitCenter,
            REStatusObject,
            TaxJurisdiction,
            Fund,
            FundsCenter,
            cast ( CommitmentItem as fm_fipex preserving type )                 as CommitmentItem,
            FunctionalArea,
            REFundsManagementGrantID,
            BudgetPeriod,
            @ObjectModel.foreignKey.association: '_ControllingArea'
            ControllingArea,
            TaxCalculationProcedure,
            FinancialManagementArea,

            _REObjectType,
            _REContract,
            _REEntryValidity,
            _REOrglAssgmtTermAddl,
            _RETermType,
            _RETerm,
            _BusinessArea,
            _FunctionalArea,            
            _BudgetPeriod,
            _Grant,
            _REKeyAssgmt,
            _ControllingArea,
            
            //text

            _ProfitCenterText,
            _TaxJurisdictionText,
            _FundText,
            _FunctionalAreaText,
            _RETermTypeText,
            _BusinessAreaText
}
where
  _REKeyAssgmt.RealEstateObjectType = 'IS'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_REKEYASSGMT",
"I_REORGANIZATIONALASSGMTTERM",
"I_RETERM"
],
"ASSOCIATED":
[
"I_BUDGETPERIOD",
"I_BUSINESSAREA",
"I_BUSINESSAREATEXT",
"I_CONTROLLINGAREA",
"I_FUNCTIONALAREA",
"I_FUNCTIONALAREATEXT",
"I_FUNDTEXT",
"I_GRANT",
"I_PROFITCENTERTEXT",
"I_REENTRYVALIDITY",
"I_REKEYASSGMT",
"I_REOBJECTTYPE",
"I_REORGLASSGMTTERMADDL",
"I_RETERM",
"I_RETERMTYPE",
"I_RETERMTYPETEXT",
"I_TAXJURISDICTIONTEXT",
"R_RECONTRACTTP"
],
"BASE":
[
"I_REORGANIZATIONALASSGMTTERM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/