R_PurchasingSourceListItemTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Source List Item'

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@Metadata.ignorePropagatedAnnotations: true

define view entity R_PurchasingSourceListItemTP
  as select from I_MPPurchasingSourceItem
  association        to parent R_PurchasingSourceListTP as _PurchasingSourceTP     on  $projection.Material = _PurchasingSourceTP.Material
                                                                                   and $projection.Plant    = _PurchasingSourceTP.Plant

  association [1..1] to I_MaterialText                  as _MaterialText           on  _MaterialText.Material = $projection.Material
                                                                                   and _MaterialText.Language = $session.system_language

  association [0..1] to I_Supplier                      as _Supplier               on  $projection.Supplier = _Supplier.Supplier

  association [0..1] to I_MaterialPlanningUsage_SL      as _MaterialPlanningUsage  on  $projection.MRPSourcingControl = _MaterialPlanningUsage.MRPSourcingControl

  association [0..1] to I_MPPurchasingSourceStatus      as _PurchasingSourceStatus on  $projection.SourceListStatus = _PurchasingSourceStatus.SourceListStatus

  association [0..1] to I_Material                      as _Material               on  _Material.Material = $projection.Material

  association [1..1] to I_Plant                         as _Plant                  on  _Plant.Plant = $projection.Plant

  association [1..1] to I_Plant                         as _SupplyingPlant         on  _SupplyingPlant.Plant = $projection.SupplyingPlant

{
  key I_MPPurchasingSourceItem.SourceListRecord,
  key I_MPPurchasingSourceItem.Material,
  key I_MPPurchasingSourceItem.Plant,
      @ObjectModel.editableFieldFor: 'MaterialForEdit'
      I_MPPurchasingSourceItem.Material                 as MaterialForEdit,
      @ObjectModel.editableFieldFor: 'PlantForEdit'
      I_MPPurchasingSourceItem.Plant                    as PlantForEdit,
      @ObjectModel.editableFieldFor: 'SourceListRecordForEdit'
      I_MPPurchasingSourceItem.SourceListRecord         as SourceListRecordForEdit,
      I_MPPurchasingSourceItem.CreationDate,
      I_MPPurchasingSourceItem.CreatedByUserName,
      I_MPPurchasingSourceItem.ValidityStartDate,
      I_MPPurchasingSourceItem.ValidityEndDate,
      I_MPPurchasingSourceItem.Supplier,
      //      cast ( I_MPPurchasingSourceItem.OutlineAgreement as reorobjnrcn ) as OutlineAgreement,

      cast( case
      when I_MPPurchasingSourceItem.PurchaseOutlineAgreement <> ''
        then
      cast (  concat(LTRIM(PurchaseOutlineAgreement,'0') , concat('/', LTRIM(PurchaseOutlineAgreementItem , '0') ) ) as abap.sstring( 16 ) )
        else ' '
      end as reorobjnrcn )  as OutlineAgreement,
      I_MPPurchasingSourceItem.PurchaseOutlineAgreement,
      I_MPPurchasingSourceItem.PurchaseOutlineAgreementItem,
      I_MPPurchasingSourceItem.PurchasingOrganization,
      I_MPPurchasingSourceItem.SupplyingPlant,
      I_MPPurchasingSourceItem.SupplierIsFixed,
      I_MPPurchasingSourceItem.PurOutlineAgreementIsFixed,
      I_MPPurchasingSourceItem.IssgPlantIsFixed,
      I_MPPurchasingSourceItem.ManufacturerMaterial,
      I_MPPurchasingSourceItem.SourceOfSupplyIsBlocked,
      I_MPPurchasingSourceItem.PurchasingDocumentCategory,
      I_MPPurchasingSourceItem.SourceListRecordCategory,
      I_MPPurchasingSourceItem.MRPSourcingControl,
      I_MPPurchasingSourceItem.MRPArea,
      I_MPPurchasingSourceItem.OrderQuantityUnit,
      I_MPPurchasingSourceItem.OriginSystem,
      I_MPPurchasingSourceItem.InventorySpecialStockType,
      @Semantics.booleanIndicator: true
      cast( case
      when  ( I_MPPurchasingSourceItem.IssgPlantIsFixed = 'X' or
           I_MPPurchasingSourceItem.PurOutlineAgreementIsFixed  = 'X' or
           I_MPPurchasingSourceItem.SupplierIsFixed  = 'X' )
        then 'X'
      end as char1 )  as SourceOfSupplyIsFixed,

      //      cast ( I_MPPurchasingSourceItem.SourceListStatus as sl_status ) as SourceListStatus,

      cast( case
      when
      (
      I_MPPurchasingSourceItem.IssgPlantIsFixed = 'X' or
      I_MPPurchasingSourceItem.PurOutlineAgreementIsFixed  = 'X' or
      I_MPPurchasingSourceItem.SupplierIsFixed  = 'X'
      ) and I_MPPurchasingSourceItem.SourceOfSupplyIsBlocked = ' '
      then 'Fixed'

      when  ( I_MPPurchasingSourceItem.IssgPlantIsFixed = ' ' or
           I_MPPurchasingSourceItem.PurOutlineAgreementIsFixed  = ' ' or
           I_MPPurchasingSourceItem.SupplierIsFixed  = ' ' ) and I_MPPurchasingSourceItem.SourceOfSupplyIsBlocked = 'X'
           then 'Blocked'

      else ' '      
      end as sl_status )    as SourceListStatus,
      //      I_MPPurchasingSourceItem.SourceListStatusCriticality,

      cast(
      case
      when
      (
      I_MPPurchasingSourceItem.IssgPlantIsFixed = 'X' or
      I_MPPurchasingSourceItem.PurOutlineAgreementIsFixed  = 'X' or
      I_MPPurchasingSourceItem.SupplierIsFixed  = 'X'
      ) and I_MPPurchasingSourceItem.SourceOfSupplyIsBlocked = ' ' then 3
      when  ( I_MPPurchasingSourceItem.IssgPlantIsFixed = ' ' or
         I_MPPurchasingSourceItem.PurOutlineAgreementIsFixed  = ' ' or
         I_MPPurchasingSourceItem.SupplierIsFixed  = ' ' ) and I_MPPurchasingSourceItem.SourceOfSupplyIsBlocked = 'X'    then 1

      else 0
      end as mm_sl_status_criticality preserving type ) as SourceListStatusCriticality,


      I_MPPurchasingSourceItem._PurchaseContract,
      I_MPPurchasingSourceItem._PurchaseContractItem,
      I_MPPurchasingSourceItem._LogicalSystem,
      I_MPPurchasingSourceItem._PurchasingOrganization,
      I_MPPurchasingSourceItem._UnitOfMeasure,
      _Supplier.SupplierName                            as SupplierName,
      _Plant.PlantName                                  as PlantName,
      _MaterialText.MaterialName,
      _SupplyingPlant.PlantName                         as SupplyingPlantName,
      I_MPPurchasingSourceItem.LastChangeDateTime       as LastChangeDateTime,

      //Composition entities

      _PurchasingSourceTP,

      //Foreign entities     

      _MaterialPlanningUsage,
      _PurchasingSourceStatus,
      _MaterialText,
      _Supplier,
      _Material,
      _Plant,
      _SupplyingPlant

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIALTEXT",
"I_MPPURCHASINGSOURCEITEM",
"I_PLANT",
"I_SUPPLIER"
],
"ASSOCIATED":
[
"I_LOGICALSYSTEM",
"I_MATERIAL",
"I_MATERIALPLANNINGUSAGE_SL",
"I_MATERIALTEXT",
"I_MPPURCHASINGSOURCESTATUS",
"I_PLANT",
"I_PURCHASECONTRACT",
"I_PURCHASECONTRACTITEM",
"I_PURCHASINGORGANIZATION",
"I_SUPPLIER",
"I_UNITOFMEASURE",
"R_PURCHASINGSOURCELISTTP"
],
"BASE":
[
"I_MPPURCHASINGSOURCEITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/