R_ProfitCenterTP

@AccessControl.authorizationCheck: #MANDATORY

@EndUserText.label: 'Profit Center - TP'

@ObjectModel: {
  usageType: {
    serviceQuality: #B,
    sizeCategory: #L,
    dataClass: #MASTER
  },
  semanticKey: ['ControllingArea', 'ProfitCenter', 'ValidityEndDate'],
  sapObjectNodeType.name: 'ProfitCenter'
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@Metadata.ignorePropagatedAnnotations: true

define root view entity R_ProfitCenterTP
  as select from I_ProfitCenter

  composition [0..*] of R_ProfitCenterTextTP      as _ProfitCenterTextTP
  composition [0..*] of R_PrftCtrCompCodeAssgmtTP as _PrftCtrCompCodeAssgmtTP
{
  key ControllingArea,
  key ProfitCenter,
      @Semantics.businessDate.to: true
  key ValidityEndDate,
      @Semantics.businessDate.from: true
      ValidityStartDate,

      @ObjectModel.editableFieldFor: 'ControllingArea'
      ControllingArea                                                                as ControllingAreaForEdit,
      @ObjectModel.editableFieldFor: 'ProfitCenter'
      ProfitCenter                                                                   as ProfitCenterForEdit,
      @ObjectModel.editableFieldFor: 'ValidityEndDate'
      ValidityEndDate                                                                as ValidityEndDateForEdit,

      _Text[1:Language=$session.system_language].ProfitCenterName,
      _Text[1:Language=$session.system_language].ProfitCenterLongName                as ProfitCenterLongName,
      ProfitCtrResponsiblePersonName,
      ProfitCtrResponsibleUser,
      ProfitCenterCreationDate,
      ProfitCenterCreatedByUser,

      cast ( ProfitCenterIsBlocked as fac_mpc_lock_indicator preserving type )       as ProfitCenterIsBlocked,

      cast( ProfitCenterStandardHierarchy as fac_mpc_pcg preserving type )           as ProfitCenterStandardHierarchy,
      Segment,
      Department                                                                     as ProfitCenterDepartment,

      FormulaPlanningTemplate,
      FormOfAddress                                                                  as ProfitCenterTitleName,
      AddressName,
      AdditionalName,
      ProfitCenterAddrName3,
      ProfitCenterAddrName4,
      StreetAddressName,
      CityName,
      PostalCode,
      District,
      cast(Country as fis_land1 preserving type )                                    as Country,
      Region,
      TaxJurisdiction,
      POBox,
      POBoxPostalCode,

      Language,
      PhoneNumber1,
      PhoneNumber2,
      FaxNumber,
      cast( TeleboxNumber as fac_mpc_comm_telbx preserving type )                    as TeleboxNumber,
      cast( TelexNumber as fac_mpc_comm_telx1 preserving type )                      as TelexNumber,
      cast( TeletexNumber as fac_mpc_teltx preserving type )                         as TeletexNumber,
      cast( DataCommunicationPhoneNumber as fac_mpc_comm_data_line preserving type ) as DataCommunicationPhoneNumber,
      cast( ProfitCenterPrinterName as fac_mpc_comm_printer preserving type )        as ProfitCenterPrinterName,

      case( length( ControllingArea ) )
        when 2 then cast( concat_with_space(ControllingArea, ProfitCenter, 2 ) as cdobjectv )
        when 3 then cast( concat_with_space(ControllingArea, ProfitCenter, 1 ) as cdobjectv )
        else cast( concat(ControllingArea, ProfitCenter) as cdobjectv )
      end                                                                            as ChangeDocObject,

      /* Associations */
      _ProfitCenterTextTP,
      _PrftCtrCompCodeAssgmtTP

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PROFITCENTER",
"I_PROFITCENTERTEXT"
],
"ASSOCIATED":
[
"R_PRFTCTRCOMPCODEASSGMTTP",
"R_PROFITCENTERTEXTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/