R_ProdnOrdConfMatlDocItemTP

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Production Order Conf Material Document'
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}

//@OData.entitySet.name: 'ProdnOrdConfMatlDocItm'


//@VDM.viewType: #COMPOSITE

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true


define view entity R_ProdnOrdConfMatlDocItemTP
  as select from I_MfgOrderConfMatlDocItem
  association    to parent R_ProductionOrdConfirmationTP as _ProdnOrdConf on  $projection.ConfirmationGroup = _ProdnOrdConf.ConfirmationGroup
                                                                          and $projection.ConfirmationCount = _ProdnOrdConf.ConfirmationCount
//  association [0..1] to A_Supplier                       as _Supplier     on  $projection.Supplier = _Supplier.Supplier

//  association [0..1] to A_Customer                       as _Customer     on  $projection.Customer = _Customer.Customer

  composition [0..*] of R_ProdnOrderConfBatchCharcTP as _ProdnOrderConfBatchCharc              // new in CE2102


{
      //Key

  key MfgOrderConfirmationGroup       as ConfirmationGroup,
  key MfgOrderConfirmation            as ConfirmationCount,
  key MaterialDocument,
  key MaterialDocumentItem,
  key MaterialDocumentYear,


      //General remarks

      //eTag Field is not necessary in the production order confirmation process.

      //Same behavior implemented like in the material document.


      //Order and Operation Data

      ManufacturingOrderType          as OrderType,
      ManufacturingOrder              as OrderID,
      ManufacturingOrderItem          as OrderItem,
      ManufacturingOrderCategory, // new field in CE2002


      //Goods Movement Data

      Material,
      Plant,
      Reservation,
      ReservationItem,
      StorageLocation,
      cast( '' as prvbe )             as ProductionSupplyArea, // only needed for create, "write-only"       // New field in CE2008!

      Batch,
      InventoryValuationType,
      GoodsMovementType,
      GoodsMovementRefDocType,
      InventoryUsabilityCode,
      InventorySpecialStockType,
      SalesOrder,
      SalesOrderItem,
      //_WBSElement.WBSElement,

      _WBSElement.WBSElementExternalID, // New field in CE1905!

      Supplier,
      Customer,
      ReservationIsFinallyIssued,
      IsCompletelyDelivered,
      ShelfLifeExpirationDate,
      ManufactureDate,
      StorageType,
      StorageBin,

      //Text

      MaterialDocumentItemText,

      //Quantities and UoM

      EntryUnit,
      _EntryUnit.UnitOfMeasureISOCode as EntryUnitISOCode, // New field in CE2002!

      _EntryUnit.UnitOfMeasureSAPCode as EntryUnitSAPCode, // CE2102

      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      QuantityInEntryUnit,

      //Associations

      _ProdnOrdConf,
      @Consumption.hidden: true
      _Supplier,
      @Consumption.hidden: true
      _Customer,
      _ProdnOrderConfBatchCharc

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MFGORDERCONFMATLDOCITEM",
"I_UNITOFMEASURE",
"I_WBSELEMENTBASICDATA"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_SUPPLIER",
"R_PRODNORDERCONFBATCHCHARCTP",
"R_PRODUCTIONORDCONFIRMATIONTP"
],
"BASE":
[
"I_MFGORDERCONFMATLDOCITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/