R_PrelimBillgDocItemTextTP

DDL: R_PRELIMBILLGDOCITEMTEXTTP Type: view_entity TRANSACTIONAL

Prelim Billing Document Item - Text TP

R_PrelimBillgDocItemTextTP is a Transactional CDS View that provides data about "Prelim Billing Document Item - Text TP" in SAP S/4HANA. It reads from 3 data sources (I_BillingDocumentType, P_BillingDocumentText, I_PrelimBillingDocument) and exposes 15 fields with key fields PrelimBillingDocument, PrelimBillingDocumentItem, Language, LongTextID. It has 4 associations to related views.

3 data source(s) 15 fields

Data Sources (3)

SourceAliasJoin Type
I_BillingDocumentType BillingDocumentType inner
P_BillingDocumentText P_BillingDocumentText from
I_PrelimBillingDocument PrelimBillingDocument inner

Associations (4)

CardinalityTargetAliasCondition
[1..1] R_PrelimBillingDocumentTP _PrelimBillingDocument $projection.PrelimBillingDocument = _PrelimBillingDocument.PrelimBillingDocument
[0..1] I_Language _Language $projection.Language = _Language.Language
[0..1] I_SDDocumentLongTextID _LongTextID $projection.LongTextID = _LongTextID.LongTextID
[0..1] I_TextDeterminationProcedItem _TextDeterminationProcedItem $projection.TextDeterminationProcedure = _TextDeterminationProcedItem.TextDeterminationProcedure and $projection.LongTextID = _TextDeterminationProcedItem.LongTextID and _TextDeterminationProcedItem.TextObjectCategory = 'VBBP' and _TextDeterminationProcedItem.TextDeterminationProcedObject = 'F'

Annotations (8)

NameValueLevelField
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #TRANSACTIONAL view
AccessControl.authorizationCheck #MANDATORY view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.dataCategory #TEXT view
EndUserText.label Prelim Billing Document Item - Text TP view

Fields (15)

KeyFieldSource TableSource FieldDescription
KEY PrelimBillingDocument Text BillingDocument
KEY PrelimBillingDocumentItem Text BillingDocumentItem
KEY Language Text Language
KEY LongTextID Text LongTextID
LongText Text LongText
TextDeterminationProcedure I_BillingDocumentType BillgProcDocItmTxtDetnProced
TextDeterminationProcedureItem _TextDeterminationProcedItem TextDeterminationProcedureItem
_Item _Item
_PrelimBillingDocument _PrelimBillingDocument
_Language _Language
_LongTextID _LongTextID
SalesOrganization I_PrelimBillingDocument SalesOrganization
BillingDocumentType I_PrelimBillingDocument BillingDocumentType
IsRelevantForAccrual I_PrelimBillingDocument IsRelevantForAccrual
PBDIsInMyResponsibility _PrelimBillingDocument PBDIsInMyResponsibility 
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #L
  },
  dataCategory: #TEXT,
  semanticKey: ['PrelimBillingDocument', 'PrelimBillingDocumentItem', 'Language', 'LongTextID']
}

@EndUserText.label: 'Prelim Billing Document Item - Text TP'
define view entity R_PrelimBillgDocItemTextTP
  as select from P_BillingDocumentText( P_SAPClient : $session.client,
                                        P_td_object : 'VBBP') as Text

    inner join   I_PrelimBillingDocument                      as PrelimBillingDocument on PrelimBillingDocument.PrelimBillingDocument = Text.BillingDocument
    inner join   I_BillingDocumentType                        as BillingDocumentType   on PrelimBillingDocument.BillingDocumentType = BillingDocumentType.BillingDocumentType

  association        to parent R_PrelimBillingDocumentItemTP as _Item                        on  $projection.PrelimBillingDocument     = _Item.PrelimBillingDocument
                                                                                             and $projection.PrelimBillingDocumentItem = _Item.PrelimBillingDocumentItem

  association [1..1] to R_PrelimBillingDocumentTP            as _PrelimBillingDocument       on  $projection.PrelimBillingDocument = _PrelimBillingDocument.PrelimBillingDocument

  association [0..1] to I_Language                           as _Language                    on  $projection.Language = _Language.Language

  association [0..1] to I_SDDocumentLongTextID               as _LongTextID                  on  $projection.LongTextID = _LongTextID.LongTextID

  association [0..1] to I_TextDeterminationProcedItem        as _TextDeterminationProcedItem on  $projection.TextDeterminationProcedure                     = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                             and $projection.LongTextID                                     = _TextDeterminationProcedItem.LongTextID
                                                                                             and _TextDeterminationProcedItem.TextObjectCategory            = 'VBBP'
                                                                                             and _TextDeterminationProcedItem.TextDeterminationProcedObject = 'F'

{
  key Text.BillingDocument                             as PrelimBillingDocument,

  key Text.BillingDocumentItem                         as PrelimBillingDocumentItem,

      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key Text.Language,

      @ObjectModel.foreignKey.association: '_LongTextID'
  key Text.LongTextID,

      Text.LongText,

      BillingDocumentType.BillgProcDocItmTxtDetnProced as TextDeterminationProcedure,

      _TextDeterminationProcedItem.TextDeterminationProcedureItem,

      _Item,
      _PrelimBillingDocument,
      _Language,
      _LongTextID,

      @Consumption.hidden: true
      PrelimBillingDocument.SalesOrganization,
      @Consumption.hidden: true
      PrelimBillingDocument.BillingDocumentType,
      @Consumption.hidden: true
      PrelimBillingDocument.IsRelevantForAccrual,
      @Consumption.hidden: true
      _PrelimBillingDocument.PBDIsInMyResponsibility
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLINGDOCUMENTTYPE",
"I_PRELIMBILLINGDOCUMENT",
"I_TEXTDETERMINATIONPROCEDITEM",
"R_PRELIMBILLINGDOCUMENTTP"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_SDDOCUMENTLONGTEXTID",
"R_PRELIMBILLINGDOCUMENTITEMTP",
"R_PRELIMBILLINGDOCUMENTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More