R_PlannedOrderCapacityTP

@EndUserText.label: 'RAP BO Planned Order Capacity view'

@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED }

@Metadata.ignorePropagatedAnnotations: true

@AccessControl.personalData.blocking: #NOT_REQUIRED

define view entity R_PlannedOrderCapacityTP 
  as select from           I_CapacityRequirementItemCap as _CapacityRequirementItemCap

  // ATC - to one or many not specified

    left outer to one join I_BillOfOperationsOpBasic    as SubOperation on  SubOperation.BillOfOperationsType        = _CapacityRequirementItemCap.BillOfOperationsType
                                                                        and SubOperation.BillOfOperationsGroup       = _CapacityRequirementItemCap.BillOfOperationsGroup
                                                                        and SubOperation.BOOOperationInternalID      = _CapacityRequirementItemCap.BOOSubOperationInternalID      //SubOperation

                                                                        and SubOperation.BOOOpInternalVersionCounter = _CapacityRequirementItemCap.BOOSubOperationInternalVersion //SubOperation


  association to parent R_PlannedOrderTP as _PlannedOrder on $projection.PlannedOrder = _PlannedOrder.PlannedOrder

{
  key _CapacityRequirementItemCap.PlannedOrder,
  key _CapacityRequirementItemCap.CapacityRequirement,
  key _CapacityRequirementItemCap.CapacityRequirementItem,
  key _CapacityRequirementItemCap.CapacityRqmtItemCapacity,


      // Basic information

      _CapacityRequirementItemCap.BillOfOperationsSequence                      as Sequence,
      cast(_CapacityRequirementItemCap.Operation as pph_vornr preserving type ) as Operation,

      cast(
             case
                 when SubOperation.SuperiorOperationInternalID > '00000000' then SubOperation.Operation
                 else ''
             end as pph_vornr preserving type)                                  as SubOperation,
             
      _CapacityRequirementItemCap._WorkCenter.WorkCenter,

      // Dates/Times

      _CapacityRequirementItemCap.OperationLatestStartDate, 
      //as PlndOrdOpSchedldStartDate,

      
      _CapacityRequirementItemCap.OperationLatestStartTime,
      // as PlndOrdOpSchedldStartTime,

      
      _CapacityRequirementItemCap.OperationLatestEndDate,
      // as PlndOrdOpSchedldEndDate,

      
      _CapacityRequirementItemCap.OperationLatestEndTime,
      // as PlndOrdOpSchedldEndTime,

      
      _CapacityRequirementItemCap.OperationEarliestStartDate,
      _CapacityRequirementItemCap.OperationEarliestStartTime,
      _CapacityRequirementItemCap.OperationEarliestEndDate,
      _CapacityRequirementItemCap.OperationEarliestEndTime,
      // New Fields for Operations

      _CapacityRequirementItemCap.LtstSchedldProcStrtDte                        as OpLtstSchedldProcgStrtDte,
      _CapacityRequirementItemCap.LtstSchedldProcStrtTime                       as OpLtstSchedldProcgStrtTme,
      _CapacityRequirementItemCap.LtstSchedldTrdwnStrtDte                       as OpLtstSchedldTrdwnStrtDte,
      _CapacityRequirementItemCap.LtstSchedldTrdwnStrtTime                      as OpLtstSchedldTrdwnStrtTme,

      // Capacity durations

      _CapacityRequirementItemCap.CapacityRequirementUnit,
      _CapacityRequirementItemCap.ScheduledCapReqOpSegSetupDurn,
      _CapacityRequirementItemCap.RemainingCapReqOpSegSetupDurn,
      _CapacityRequirementItemCap.ScheduledCapReqOpSegProcgDurn,
      _CapacityRequirementItemCap.RemainingCapReqOpSegProcgDurn,
      _CapacityRequirementItemCap.ScheduledCapReqOpSegTrdwnDurn,
      _CapacityRequirementItemCap.RemainingCapReqOpSegTrdwnDurn,

      // case expressions are not supported in the projection layer


      cast(case
            when _CapacityRequirementItemCap._WorkCenter.CapacityInternalID = _CapacityRequirementItemCap.CapacityInternalID
                then 'X'
            else ''
            end  as pp_wrkcntr_cap_isleading)                                   as WrkCtrHasLeadingCapacity,

      // Texts

      case
        when SubOperation.SuperiorOperationInternalID > '00000000'
             then SubOperation.OperationText
        else _CapacityRequirementItemCap._BOOOperationInternalVersion.OperationText
      end                                                                       as OperationText,

      // @Semantics.systemDateTime.lastChangedAt: true

      _PlannedOrder.PlannedOrderLastChangeDateTime,

      //Fields required for DCL

      _CapacityRequirementItemCap._PlannedOrder.MRPController,
      _CapacityRequirementItemCap._PlannedOrder.MRPPlant,

      //for the association _Capacity

      _CapacityRequirementItemCap.CapacityInternalID,

      _PlannedOrder,
      _CapacityRequirementItemCap._Capacity,
      _CapacityRequirementItemCap._CapacityRequirement,
      _CapacityRequirementItemCap._UnitOfMeasure
}

where
  _CapacityRequirementItemCap.PlannedOrder is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONSOPBASIC",
"I_CAPACITYREQUIREMENTITEMCAP",
"I_PLANNEDORDER",
"I_WORKCENTER",
"R_PLANNEDORDERTP"
],
"ASSOCIATED":
[
"I_CAPACITY",
"I_CAPACITYREQUIREMENT",
"I_UNITOFMEASURE",
"R_PLANNEDORDERTP"
],
"BASE":
[
"I_CAPACITYREQUIREMENTITEMCAP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/