R_OutboundDeliveryTP

@EndUserText.label: 'Outbound Delivery - TP'
@AccessControl.authorizationCheck: #MANDATORY
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@ObjectModel: {
    usageType: {
        dataClass:      #TRANSACTIONAL,
        serviceQuality: #B,
        sizeCategory:   #L
    },
    sapObjectNodeType.name: 'OutboundDelivery',
    semanticKey: ['OutboundDelivery'],
    representativeKey: 'OutboundDelivery'
}
@Metadata.ignorePropagatedAnnotations: true
define root view entity R_OutboundDeliveryTP
  as select from I_DeliveryDocument
  composition [0..*] of R_OutboundDeliveryItemTP    as _Item
  composition [1..*] of R_OutboundDeliveryPartnerTP as _Partner
  composition [0..*] of R_OutboundDeliveryTextTP    as _Text

  //Extensibility

  association [0..1] to E_DeliveryDocument          as _Extension on $projection.OutboundDelivery = _Extension.DeliveryDocument
{
      // Key fields

  key cast(DeliveryDocument as outbound_delivery preserving type)   as OutboundDelivery,

      // Partner

      ShipToParty,
      SoldToParty,
      Supplier,
      ReceivingPlant,
      CustomerGroup,

      // Warehouse

      Warehouse,
      WarehouseGate,
      WarehouseStagingArea,
      HandlingUnitInStock,
      TotalNumberOfPackage,

      // Shipment

      RouteSchedule,
      IncotermsClassification,
      IncotermsTransferLocation,
      BillOfLading,
      GoodsIssueOrReceiptSlipNumber                                 as GoodsMovementSlipNumber,
      TransportationGroup,
      ShipmentBlockReason,
      ShippingCondition,
      ShippingType,
      SpecialProcessingCode,
      MeansOfTransport,
      MeansOfTransportType,
      MeansOfTransportRefMaterial,
      ExternalTransportSystem,
      FactoryCalendarByCustomer,

      // Weight and Volume

      @Semantics.quantity.unitOfMeasure: 'HeaderWeightUnit'
      HeaderGrossWeight,
      @Semantics.quantity.unitOfMeasure: 'HeaderWeightUnit'
      HeaderNetWeight,
      HeaderWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'HeaderVolumeUnit'
      HeaderVolume,
      HeaderVolumeUnit,

      // International Trade

      @Semantics.booleanIndicator: true
      IsExportDelivery,

      // Financial Processing

      HeaderBillingBlockReason,
      InternalFinancialDocument,
      DepreciationPercentage                                        as DepreciationInPercent,
      PaymentGuaranteeProcedure,
      TransactionCurrency,
      StatisticsCurrency,

      // Organization

      DeliveryDocumentBySupplier,
      ExternalIdentificationType,
      ShippingPoint,
      SalesOrganization,
      SalesOffice,
      SalesDistrict,

      // Document Editing

      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      @Semantics.systemDate.createdAt: true
      CreationDate,
      @Semantics.systemTime.createdAt: true
      CreationTime,
      @Semantics.systemDate.lastChangedAt: true
      LastChangeDate,
      DeliveryVersion,

      // Control

      DeliveryPriority,
      DeliveryBlockReason,
      DeliveryDocumentType,
      SDDocumentCategory,
      CompleteDeliveryIsDefined,
      OrderCombinationIsAllowed,

      // Dates

      DocumentDate,
      PickingDate                                                   as PickDate,
      PickingTime                                                   as PickTime,
      TransportationPlanningDate,
      TransportationPlanningTime,
      LoadingDate,
      LoadingTime,
      PlannedGoodsIssueDate                                         as PlannedGoodsMovementDate,
      cast(GoodsIssueTime as le_wauhr preserving type)              as PlannedGoodsMovementTime,
      DeliveryDate,
      DeliveryTime,
      BillingDocumentDate,
      IntercompanyBillingDate,
      ActualGoodsMovementDate,
      cast(ActualGoodsMovementTime as le_wauhr_ist preserving type) as ActualGoodsMovementTime,
      ProofOfDeliveryDate,
      ConfirmationTime                                              as ProofOfDeliveryTime,
      ShippingLocationTimeZone,
      ReceivingLocationTimeZone,

      // Status

      OverallPickingStatus                                          as OverallPickStatus,
      OverallWarehouseActivityStatus,
      OverallPickingConfStatus                                      as OverallPickConfStatus,
      OverallPackingStatus,
      OverallGoodsMovementStatus,
      OverallDelivReltdBillgStatus,
      TransportationPlanningStatus,
      DistrStatusByDecentralizedWrhs,
      OverallProofOfDeliveryStatus,
      OverallIntcoBillingStatus,
      TotalCreditCheckStatus,
      OverallSDProcessStatus                                        as OverallDeliveryProcessStatus,
      TotalBlockStatus,
      OverallDelivConfStatus,
      HdrGeneralIncompletionStatus,
      HeaderDelivIncompletionStatus,
      HeaderPickgIncompletionStatus                                 as HeaderPickIncompletionStatus,
      HeaderPackingIncompletionSts,
      HdrGoodsMvtIncompletionStatus,
      HeaderBillgIncompletionStatus,
      OvrlItmGeneralIncompletionSts,
      OvrlItmPackingIncompletionSts,
      OvrlItmPickingIncompletionSts                                 as OvrlItmPickIncompletionSts,
      OvrlItmDelivIncompletionSts,
      OvrlItmGdsMvtIncompletionSts,
      DeliveryIsInPlant,

      // Associations

      _Item,
      _Partner,
      _Text
}
where
  SDDocumentCategory = 'J'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DELIVERYDOCUMENT"
],
"ASSOCIATED":
[
"R_OUTBOUNDDELIVERYITEMTP",
"R_OUTBOUNDDELIVERYPARTNERTP",
"R_OUTBOUNDDELIVERYTEXTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/