R_MassMaintCapIntervalShiftTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'capacity Interval Shift Data'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity R_MassMaintCapIntervalShiftTP
  as select from I_WorkCenterCapacityInterval_2 as _Intrvl
    inner join   I_WorkCenterCapacityShift_2    as _Shift on  _Intrvl.CapacityInternalID    = _Shift.CapacityInternalID
                                                          and _Intrvl.CapacityActiveVersion = _Shift.CapacityActiveVersion
                                                          and _Intrvl.IntervalEndDate       = _Shift.IntervalEndDate
   association to parent R_WorkCenterCapacityListTP as _CapListHeader on $projection.CapacityInternalID =  _CapListHeader.CapacityInternalID
{
  key _Intrvl.CapacityInternalID,
  key _Intrvl.CapacityActiveVersion,
  key _Intrvl.IntervalEndDate,
  key _Shift.WeekDay,
  key _Shift.AvailableCapacityShift,
      _Intrvl.IntervalStartDate,
      _Intrvl.StdAvailableCapacityIsValid,
      _Intrvl.ShiftSequence,
      _Intrvl.WorkDayRule,
      _Intrvl.CapacityNumberOfShifts,
      _Intrvl.AvailableCapacityIntervalDurn,
      _Shift.ShiftDefinition,
      _Shift.ShiftStartTime,
      _Shift.ShiftEndTime,
      _Shift.ShiftDefValidityStartDate,
      _Shift.ShiftDefValidityEndDate,
      _Shift.CapacityNumberOfCapacities,
      _Shift.CapacityPlanUtilizationPercent,
      _Shift.CapacityBreakDuration,
      _Shift.OperatingDurationInSeconds,
      _Shift.TotOperatingDurationInSeconds,
       //Units

      cast('H' as unit)                                                                 as WorkCenterCapacityUnit,
      cast('%' as unit)                                                                 as WorkCenterUtilizationUnit,
      //Association

      _CapListHeader
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_WORKCENTERCAPACITYINTERVAL_2",
"I_WORKCENTERCAPACITYSHIFT_2"
],
"ASSOCIATED":
[
"R_WORKCENTERCAPACITYLISTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/