R_ManageJournalEntryItemTP

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Journal Entry Item - Transaction Processing'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XXL,
  dataClass: #MIXED
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
define view entity R_ManageJournalEntryItemTP
  as select from R_ManageJournalEntryItem as _Item

  association to parent R_ManageJournalEntryTP          as _Header                        on  $projection.CompanyCode        = _Header.CompanyCode
                                                                                          and $projection.FiscalYear         = _Header.FiscalYear
                                                                                          and $projection.AccountingDocument = _Header.AccountingDocument

  association [1..1] to E_OperationalAcctgDocItem       as _Extension                     on  $projection.CompanyCode        = _Extension.CompanyCode
                                                                                          and $projection.FiscalYear         = _Extension.FiscalYear
                                                                                          and $projection.AccountingDocument = _Extension.AccountingDocument
                                                                                          and $projection.AccountingDocumentItem   = _Extension.AccountingDocumentItem

  association [1..1] to I_CompanyCode                   as _CompanyCode                   on  $projection.CompanyCode = _CompanyCode.CompanyCode

  association [0..1] to I_ControllingArea               as _ControllingArea               on  $projection.ControllingArea = _ControllingArea.ControllingArea

  association [0..1] to I_FinancialTransactionTypeT     as _FinancialTransactionTypeT     on $projection.FinancialTransactionType = _FinancialTransactionTypeT.FinancialTransactionType
                                                                                          and _FinancialTransactionTypeT.Language = $session.system_language

  association [0..1] to I_GLAccountText                 as _GLAccountText                 on  $projection.ChartOfAccounts = _GLAccountText.ChartOfAccounts
                                                                                          and $projection.GLAccount       = _GLAccountText.GLAccount
                                                                                          and _GLAccountText.Language = $session.system_language

  association [0..1] to I_CostCenterText                as _CostCenterText                on  $projection.ControllingArea =  _CostCenterText.ControllingArea
                                                                                          and $projection.CostCenter      =  _CostCenterText.CostCenter
                                                                                          and $projection.PostingDate     <= _CostCenterText.ValidityEndDate
                                                                                          and $projection.PostingDate     >= _CostCenterText.ValidityStartDate
                                                                                          and _CostCenterText.Language    = $session.system_language

  association [0..1] to I_ProfitCenterText              as _ProfitCenterText              on  $projection.ControllingArea = _ProfitCenterText.ControllingArea
                                                                                          and $projection.ProfitCenter    = _ProfitCenterText.ProfitCenter
                                                                                          and $projection.PostingDate     <= _ProfitCenterText.ValidityEndDate
                                                                                          and $projection.PostingDate     >= _ProfitCenterText.ValidityStartDate
                                                                                          and _ProfitCenterText.Language    = $session.system_language

  association [0..1] to I_ProfitCenterText              as _PartnerProfitCenterText       on  $projection.ControllingArea = _PartnerProfitCenterText.ControllingArea
                                                                                          and $projection.PartnerProfitCenter    = _PartnerProfitCenterText.ProfitCenter
                                                                                          and $projection.PostingDate     <= _PartnerProfitCenterText.ValidityEndDate
                                                                                          and $projection.PostingDate     >= _PartnerProfitCenterText.ValidityStartDate
                                                                                          and _PartnerProfitCenterText.Language    = $session.system_language

  association [0..1] to I_FunctionalAreaText            as _FunctionalAreaText            on  $projection.FunctionalArea   = _FunctionalAreaText.FunctionalArea
                                                                                          and _FunctionalAreaText.Language = $session.system_language

  association [0..1] to I_FunctionalAreaText            as _PartnerFunctionalAreaText     on  $projection.PartnerFunctionalArea   = _PartnerFunctionalAreaText.FunctionalArea
                                                                                          and _PartnerFunctionalAreaText.Language = $session.system_language

  association [0..1] to I_BusinessAreaText              as _BusinessAreaText              on $projection.BusinessArea = _BusinessAreaText.BusinessArea
                                                                                          and _BusinessAreaText.Language = $session.system_language

  association [0..1] to I_BusinessAreaText              as _PartnerBusinessAreaText       on $projection.PartnerBusinessArea = _PartnerBusinessAreaText.BusinessArea
                                                                                          and _PartnerBusinessAreaText.Language = $session.system_language

  association [0..1] to I_SegmentText                   as _SegmentText                   on $projection.Segment = _SegmentText.Segment
                                                                                          and _SegmentText.Language = $session.system_language

  association [0..1] to I_SegmentText                   as _PartnerSegmentText            on $projection.PartnerSegment = _PartnerSegmentText.Segment
                                                                                          and _PartnerSegmentText.Language = $session.system_language

  association [0..1] to I_Partnercompany                as _PartnerCompany                on  $projection.PartnerCompany = _PartnerCompany.PartnerCompany

  association [0..1] to I_PostingKeyText                as _PostingKeyText                on $projection.PostingKey = _PostingKeyText.PostingKey
                                                                                          and _PostingKeyText.Language = $session.system_language

  association [0..1] to I_Plant                         as _Plant                         on  $projection.Plant = _Plant.Plant

  association [0..1] to I_Customer                      as _Customer                      on  $projection.Customer = _Customer.Customer

  association [0..1] to I_Supplier                      as _Supplier                      on  $projection.Supplier = _Supplier.Supplier

  association [0..1] to I_SpecialGLCodeText             as _SpecialGLCodeText             on $projection.FinancialAccountType = _SpecialGLCodeText.FinancialAccountType
                                                                                          and $projection.SpecialGLCode = _SpecialGLCodeText.SpecialGLCode
                                                                                          and _SpecialGLCodeText.Language = $session.system_language

  association [0..1] to I_MasterFixedAsset              as _MasterFixedAsset              on  $projection.CompanyCode      = _MasterFixedAsset.CompanyCode
                                                                                          and $projection.MasterFixedAsset = _MasterFixedAsset.MasterFixedAsset

  association [0..1] to I_FixedAsset                    as _FixedAsset                    on  $projection.CompanyCode      = _FixedAsset.CompanyCode
                                                                                          and $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset
                                                                                          and $projection.FixedAsset       = _FixedAsset.FixedAsset

  association [0..1] to I_AssetTransactionTypeText      as _AssetTransactionTypeText      on $projection.AssetTransactionType = _AssetTransactionTypeText.AssetTransactionType
                                                                                          and _AssetTransactionTypeText.Language = $session.system_language

  association [0..1] to I_CostCenterActivityTypeText    as _CostCtrActivityTypeT          on $projection.ControllingArea     = _CostCtrActivityTypeT.ControllingArea
                                                                                          and $projection.CostCtrActivityType = _CostCtrActivityTypeT.CostCtrActivityType
                                                                                          and $projection.PostingDate     <= _CostCtrActivityTypeT.ValidityEndDate
                                                                                          and $projection.PostingDate     >= _CostCtrActivityTypeT.ValidityStartDate
                                                                                          and _CostCtrActivityTypeT.Language    = $session.system_language


  association [0..1] to I_ProductText                   as _ProductText                   on  $projection.Product = _ProductText.Product
                                                                                          and _ProductText.Language    = $session.system_language

  association [0..1] to I_WBSElementBasicData           as _WBSElementBasicData           on  $projection.WBSElementInternalID = _WBSElementBasicData.WBSElementInternalID

  association [0..1] to I_CompanyCode                   as _CashLedgerCompanyCode         on  $projection.CashLedgerCompanyCode = _CashLedgerCompanyCode.CompanyCode

  association [0..1] to I_GlAccountTextInCompanycode    as _CashLedgerAccountText         on  $projection.CashLedgerCompanyCode = _CashLedgerAccountText.CompanyCode
                                                                                          and $projection.CashLedgerAccount   = _CashLedgerAccountText.GLAccount
                                                                                          and _CashLedgerAccountText.Language    = $session.system_language

  association [0..1] to I_FundText                      as _FundText                      on  $projection.FinancialManagementArea = _FundText.FinancialManagementArea
                                                                                          and $projection.Fund                    = _FundText.Fund
                                                                                          and _FundText.Language                  = $session.system_language

  association [0..1] to I_GrantText                     as _GrantText                     on  $projection.GrantID = _GrantText.GrantID
                                                                                          and _GrantText.Language = $session.system_language

  association [0..1] to I_BudgetPeriodText              as _BudgetPeriodText              on  $projection.BudgetPeriod   = _BudgetPeriodText.BudgetPeriod
                                                                                          and _BudgetPeriodText.Language = $session.system_language

  association [0..1] to I_FundText                      as _PartnerFundText               on  $projection.FinancialManagementArea = _PartnerFundText.FinancialManagementArea
                                                                                          and $projection.PartnerFund             = _PartnerFundText.Fund
                                                                                          and _PartnerFundText.Language            = $session.system_language

  association [0..1] to I_GrantText                     as _PartnerGrantText              on  $projection.PartnerGrant = _PartnerGrantText.GrantID
                                                                                          and _PartnerGrantText.Language = $session.system_language

  association [0..1] to I_BudgetPeriodText              as _PartnerBudgetPeriodText       on  $projection.PartnerBudgetPeriod   = _PartnerBudgetPeriodText.BudgetPeriod
                                                                                          and _PartnerBudgetPeriodText.Language = $session.system_language

  association [0..1] to I_PubSecBudgetAccountText       as _BudgetAccountText             on  $projection.PubSecBudgetAccount  = _BudgetAccountText.PubSecBudgetAccount
                                                                                          and $projection.PubSecBudgetAccountCoCode = _BudgetAccountText.PubSecBudgetAccountCoCode
                                                                                          and _BudgetAccountText.Language = $session.system_language

  association [0..1] to I_PaymentTermsText              as _PaymentTermsText             on  $projection.PaymentTerms  = _PaymentTermsText.PaymentTerms
                                                                                          and _PaymentTermsText.Language = $session.system_language

  association [0..1] to I_PaymentBlockingReasonText     as _PaymentBlockingReasonText     on  $projection.PaymentBlockingReason  = _PaymentBlockingReasonText.PaymentBlockingReason
                                                                                          and _PaymentBlockingReasonText.Language = $session.system_language

  association [0..1] to I_DunningAreaText               as _DunningAreaText               on  $projection.CompanyCode = _DunningAreaText.CompanyCode
                                                                                          and $projection.DunningArea   = _DunningAreaText.DunningArea
                                                                                          and _DunningAreaText.Language = $session.system_language

  association [0..1] to I_JournalEntryItemOneTimeData   as _OneTimeData                   on  $projection.CompanyCode            = _OneTimeData.CompanyCode
                                                                                          and $projection.FiscalYear             = _OneTimeData.FiscalYear
                                                                                          and $projection.AccountingDocument     = _OneTimeData.AccountingDocument
                                                                                          and $projection.AccountingDocumentItem = _OneTimeData.AccountingDocumentItem

  association [0..1] to I_FixedCashDiscountTypeText     as _FixedCashDiscountTypeText     on  $projection.FixedCashDiscount = _FixedCashDiscountTypeText.FixedCashDiscount
                                                                                          and _FixedCashDiscountTypeText.Language = $session.system_language

  association [0..1] to I_CountryText                   as _SupplyingCountryText          on  $projection.SupplyingCountry = _SupplyingCountryText.Country
                                                                                          and _SupplyingCountryText.Language = $session.system_language

  association [0..1] to I_FinServicesProductGroupT      as _FinServicesProductGroupT      on  $projection.FinancialServicesProductGroup = _FinServicesProductGroupT.FinancialServicesProductGroup
                                                                                          and _FinServicesProductGroupT.Language = $session.system_language

  association [0..1] to I_FinancialServicesBranchT      as _FinancialServicesBranchT      on  $projection.FinancialServicesBranch = _FinancialServicesBranchT.FinancialServicesBranch
                                                                                          and _FinancialServicesBranchT.Language = $session.system_language

  association [0..1] to I_FinancialDataSourceT          as _FinancialDataSourceT          on  $projection.FinancialDataSource = _FinancialDataSourceT.FinancialDataSource
                                                                                          and _FinancialDataSourceT.Language = $session.system_language

  association [0..1] to I_CustomerSupplierIndustryText  as _CustomerSupplierIndustryText  on  $projection.CustomerSupplierIndustry = _CustomerSupplierIndustryText.Industry
                                                                                          and _CustomerSupplierIndustryText.Language = $session.system_language

  association [0..1] to I_CustomerGroupText             as _CustomerGroupText             on  $projection.CustomerGroup = _CustomerGroupText.CustomerGroup
                                                                                          and _CustomerGroupText.Language = $session.system_language

  association [0..1] to I_CountryText                   as _CustomerSupplierCountryText   on $projection.CustomerSupplierCountry = _CustomerSupplierCountryText.Country
                                                                                          and _CustomerSupplierCountryText.Language    = $session.system_language

  association [0..1] to I_HouseBankText                 as _HouseBankText                 on  $projection.HouseBank         = _HouseBankText.HouseBank
                                                                                          and $projection.CompanyCode       = _HouseBankText.CompanyCode
                                                                                          and $projection.HouseBankAccount  = _HouseBankText.HouseBankAccount
                                                                                          and _HouseBankText.Language       = $session.system_language

  association [0..1] to I_HouseBankAccountText          as _HouseBankAccountText          on  $projection.HouseBank         = _HouseBankAccountText.HouseBank
                                                                                          and $projection.CompanyCode       = _HouseBankAccountText.CompanyCode
                                                                                          and $projection.HouseBankAccount  = _HouseBankAccountText.HouseBankAccount
                                                                                          and _HouseBankAccountText.Language       = $session.system_language

  //DCL

  association [0..1] to I_GLAccountInCompanyCode       as _GLAccountInCompanyCode        on  $projection.CompanyCode = _GLAccountInCompanyCode.CompanyCode
                                                                                         and $projection.GLAccount   = _GLAccountInCompanyCode.GLAccount

  association [0..1] to I_ProfitCenter                 as _CurrentProfitCenter           on  $projection.ControllingArea            = _CurrentProfitCenter.ControllingArea
                                                                                         and $projection.ProfitCenter               = _CurrentProfitCenter.ProfitCenter
                                                                                         and _CurrentProfitCenter.ValidityStartDate <= $session.system_date
                                                                                         and _CurrentProfitCenter.ValidityEndDate   >= $session.system_date

  association [0..1] to I_CostCenter                   as _CurrentCostCenter             on  $projection.ControllingArea          = _CurrentCostCenter.ControllingArea
                                                                                         and $projection.CostCenter               = _CurrentCostCenter.CostCenter
                                                                                         and _CurrentCostCenter.ValidityStartDate <= $session.system_date
                                                                                         and _CurrentCostCenter.ValidityEndDate   >= $session.system_date

  association [0..1] to I_AccountingDocumentType       as _AccountingDocumentType        on  $projection.AccountingDocumentType = _AccountingDocumentType.AccountingDocumentType

  association [0..1] to I_Order                        as _Order                         on  $projection.OrderID = _Order.OrderID

  association [0..1] to I_SalesDocument                as _SalesDoc                      on  $projection.SalesDocument = _SalesDoc.SalesDocument

  association [0..1] to I_SrvcDocByDocumentType        as _ServiceDocument               on  $projection.ServiceDocumentType = _ServiceDocument.ServiceDocumentType
                                                                                         and $projection.ServiceDocument     = _ServiceDocument.ServiceDocument

  //end DCL

{
  key CompanyCode,
  key FiscalYear,
  key AccountingDocument,
  key AccountingDocumentItem,

      ChartOfAccounts,
      ClearingDate,
      ClearingCreationDate,
      ClearingJournalEntry,

      PostingKey,
      FinancialAccountType,
      SpecialGLCode,
      SpecialGLTransactionType,
      DebitCreditCode,
      BusinessArea,
      PartnerBusinessArea,
      TaxCode,
      WithholdingTaxCode,
      TaxType,
      TransactionTypeDetermination,
      ValueDate,
      AssignmentReference,
      DocumentItemText,
      PartnerCompany,
      FinancialTransactionType,
      CorporateGroupAccount,
      PlanningLevel,
      ControllingArea,
      CostCenter,
      //ProjectInternalID,   -- to be retrieved later from WBS Element

      OrderID,
      BillingDocument,
      SalesDocument,
      SalesDocumentItem,
      ScheduleLine,
      ServiceDocumentType,
      ServiceDocument,
      ServiceDocumentItem,
      MasterFixedAsset,
      FixedAsset,
      cast( AssetTransactionType as fco_asset_transaction_type preserving type ) as AssetTransactionType,
      AssetValueDate,
      PersonnelNumber,
      IsSalesRelated,
      LineItemDisplayIsEnabled,
      @Semantics.booleanIndicator
      IsOpenItemManaged,
      IsNotCashDiscountLiable,
      IsAutomaticallyCreated,
      IsUsedInPaymentTransaction,
      OperationalGLAccount,
      GLAccount,
      Customer,
      Supplier,
      BranchAccount,
      IsBalanceSheetAccount,
      ProfitLossAccountType,
      SpecialGLAccountAssignment,
      DueCalculationBaseDate,
      PaymentTerms,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      CashDiscountBaseAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      CashDiscountAmount,
      CashDiscount1Days,
      CashDiscount2Days,
      NetPaymentDays,
      CashDiscount1Percent,
      CashDiscount2Percent,
      PaymentMethod,
      PaymentBlockingReason,
      FixedCashDiscount,
      HouseBank,
      BPBankAccountInternalID,
      TaxDistributionCode1,
      TaxDistributionCode2,
      TaxDistributionCode3,
      InvoiceReference,
      InvoiceReferenceFiscalYear,
      InvoiceItemReference,
      FollowOnDocumentType,
      StateCentralBankPaymentReason,
      SupplyingCountry,
      InvoiceList,
      BillOfExchangeUsage,
      DunningKey,
      DunningBlockingReason,
      LastDunningDate,
      DunningLevel,
      DunningArea,
      WithholdingTaxCertificate,
      Product,
      Plant,
      PurchasingDocument,
      PurchasingDocumentItem,
      AccountAssignmentNumber,
      IsCompletelyDelivered,
      LineItemIsCompleted,
      MaterialPriceControl,
      ValuationArea,
      InventoryValuationType,
      VATRegistration,
      DelivOfGoodsDestCountry,
      PaymentDifferenceReason,
      ProfitCenter,
      JointVenture,
      JointVentureCostRecoveryCode,
      JointVentureEquityGroup,
      TreasuryContractType,
      AssetContract,
      CashFlowType,
      TaxJurisdiction,
      REInternalFinNumber,
      SettlementReferenceDate,
      CommitmentItem,
      CommitmentItemShortID,
      CostObject,
      ProjectNetwork,
      OrderInternalBillOfOperations,
      OrderIntBillOfOperationsItem,
      WBSElementInternalID,
      WBSElementExternalID,
      WBSDescription,

      ProfitabilitySegment,
      JointVentureEquityType,
      IsEUTriangularDeal,
      CostOriginGroup,
      CompanyCodeCurrencyDetnMethod,
      ClearingIsReversed,
      PaymentMethodSupplement,
      AlternativeGLAccount,
      PartnerProfitCenter,
      Reference1IDByBusinessPartner,
      Reference2IDByBusinessPartner,
      IsNegativePosting,
      PaymentCardItem,
      PaymentCardPaymentSettlement,
      CreditControlArea,
      Reference3IDByBusinessPartner,
      DataExchangeInstruction1,
      DataExchangeInstruction2,
      DataExchangeInstruction3,
      DataExchangeInstruction4,
      Region,
      HasPaymentOrder,
      PaymentReference,
      TaxDeterminationDate,
      ClearingItem,
      BusinessPlace,
      TaxSection,
      CostCtrActivityType,
      @Semantics.booleanIndicator
      AccountsReceivableIsPledged,
      AcctsReceivablePledgingCode,
      BusinessProcess,
      FunctionalArea,
      CustomerIsInExecution,
      ClearingJournalEntryFiscalYear,
      LedgerGLLineItem,
      Segment,
      PartnerSegment,
      PartnerFunctionalArea,
      HouseBankAccount,
      CostElement,
      PaymentServiceProvider,
      PaymentRefByPaytSrvcProvider,
      SEPAMandate,
      ReferenceDocumentType,
      OriginalReferenceDocument,
      ReferenceDocumentLogicalSystem,
      AccountingDocumentItemRef,
      FiscalPeriod,
      AccountingDocumentCategory,
      PostingDate,
      DocumentDate,
      AccountingDocumentType,
      NetDueDate,
      CashDiscount1DueDate,
      CashDiscount2DueDate,
      OffsettingAccount,
      OffsettingAccountType,
      OffsettingChartOfAccounts,
      CashLedgerCompanyCode,
      CashLedgerAccount,
      FinancialManagementArea,
      FundsCenter,
      FundedProgram,
      Fund,
      GrantID,
      BudgetPeriod,
      PartnerFund,
      PartnerGrant,
      PartnerBudgetPeriod,
      PubSecBudgetAccount,
      PubSecBudgetAccountCoCode,

      CompanyCodeCurrency,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      AmountInCompanyCodeCurrency,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      CreditAmountInCoCodeCrcy,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      DebitAmountInCoCodeCrcy,

      FunctionalCurrency,
      @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
      AmountInFunctionalCurrency,
      @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
      CreditAmountInFunctionalCrcy,
      @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
      DebitAmountInFunctionalCrcy,

      TransactionCurrency,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      AmountInTransactionCurrency,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      CreditAmountInTransCrcy,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      DebitAmountInTransCrcy,

      BalanceTransactionCurrency,
      @Semantics: { amount : {currencyCode: 'BalanceTransactionCurrency'} }
      AmountInBalanceTransacCrcy,
      @Semantics: { amount : {currencyCode: 'BalanceTransactionCurrency'} }
      CreditAmountInBalanceTransCrcy,
      @Semantics: { amount : {currencyCode: 'BalanceTransactionCurrency'} }
      DebitAmountInBalanceTransCrcy,

      AdditionalCurrency1,
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency1'} }
      AmountInAdditionalCurrency1,
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency1'} }
      CreditAmountInAddlCrcy1,
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency1'} }
      DebitAmountInAddlCrcy1,

      AdditionalCurrency2,
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency2'} }
      AmountInAdditionalCurrency2,
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency2'} }
      CreditAmountInAddlCrcy2,
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency2'} }
      DebitAmountInAddlCrcy2,

      BaseUnit,

      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      Quantity,

      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      AbsoluteQuantity,

      GoodsMovementEntryUnit,
      @Semantics: { quantity : {unitOfMeasure: 'GoodsMovementEntryUnit'} }
      QuantityInEntryUnit,

      PurchasingDocumentPriceUnit,
      @Semantics: { quantity : {unitOfMeasure: 'PurchasingDocumentPriceUnit'} }
      PurchaseOrderQty,
      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      MaterialPriceUnitQty,

      EarmarkedFundsDocument,
      EarmarkedFundsDocumentItem,
      PaytSlipWthRefReference,
      TaxRateValidityStartDate,
      PaytSlipWthRefCheckDigit,
      PaytSlipWthRefSubscriber,
      PaymentReason,
      BranchCode,
      PaymentCurrency,
      @Semantics: { amount : {currencyCode: 'PaymentCurrency'} }
      AmountInPaymentCurrency,
      @Semantics: { amount : {currencyCode: 'PaymentCurrency'} }
      NetPaymentAmount,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      TaxBaseAmountInCoCodeCrcy,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      TaxBaseAmountInTransCrcy,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      WithholdingTaxAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      WithholdingTaxExemptionAmt,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      WithholdingTaxBaseAmount,
      TaxCountry,
      @Semantics.booleanIndicator
      AddressAndBankIsSetManually,
      @Semantics.booleanIndicator
      cast( '' as  xfeld preserving type ) as AddressIsChangedManually,
      @Semantics.booleanIndicator
      _OneTimeData.IsOneTimeAccount,
      @Semantics.booleanIndicator
      case
        when _OneTimeData.AccountingDocument = _Item.AccountingDocument and _OneTimeData.IsOneTimeAccount = ''
          then cast( 'X' as xzemp preserving type )
        else cast( '' as xzemp preserving type )
      end as AlternativePayeeIsAllowed,
      @Semantics.booleanIndicator
      cast( _Customer.AlternativePayeeIsAllowed as farp_isalternativepayer preserving type ) as PayerIsAlternativePayer,
      @Semantics.booleanIndicator
      cast( _Supplier.AlternativePayeeIsAllowed as farp_isalternativepayee preserving type ) as PayeeIsAlternativePayee,

      OplAcctgDocItmCntrySpcfcRef1,

      FinancialServicesProductGroup,
      FinancialServicesBranch,
      FinancialDataSource,
      CustomerGroup,
      CustomerSupplierCountry,
      CustomerSupplierIndustry,

      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      CashDiscountAmtInCoCodeCrcy,
      AccountingDocumentItemType,

      AlternativePayeePayer,
      @Semantics.booleanIndicator
      DownPaymentIsNetProcedure,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      TaxAmountInCoCodeCrcy,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      TaxAmount,

      //Dummy fields..not in I_OperationalAcctgDocItem

      @Semantics.booleanIndicator
      cast('' as fac_diekz) as RecrrgSuplrInvcIsSrvcInvoice,
      @Semantics.booleanIndicator
      cast('' as fac_xinve) as SuplrInvcIsCapitalGoodsRelated,
      @Semantics.booleanIndicator
      cast('' as xlgclr) as ClearingIsLedgerGroupSpecific,
      cast('' as dzollt) as AcctgDocItmCustomsTariffNumber,
      cast('00000000' as dzolld) as AcctgDocItmCstmsClearanceDate,
      @Semantics.booleanIndicator
      cast('' as exclude_flg) as InvcItmIsExcldFrmPromptPaytAct,
      cast('' as fac_egmld_bsez) as DeliveryOfGoodsReportingCntry,

      _Header,
      _CompanyCode,
      _ControllingArea,
      _FinancialTransactionTypeT,
      _GLAccountText,
      _CostCenterText,
      _ProfitCenterText,
      _PartnerProfitCenterText,
      _FunctionalAreaText,
      _PartnerFunctionalAreaText,
      _BusinessAreaText,
      _PartnerBusinessAreaText,
      _SegmentText,
      _PartnerSegmentText,
      _PartnerCompany,
      _PostingKeyText,
      _Plant,
      _Customer,
      _Supplier,
      _SpecialGLCodeText,
      _MasterFixedAsset,
      _FixedAsset,
      _AssetTransactionTypeText,
      _CostCtrActivityTypeT,
      _ProductText,
      _WBSElementBasicData,
      _CashLedgerCompanyCode,
      _CashLedgerAccountText,
      _FundText,
      _GrantText,
      _BudgetPeriodText,
      _PartnerFundText,
      _PartnerGrantText,
      _PartnerBudgetPeriodText,
      _BudgetAccountText,
      _PaymentTermsText,
      _PaymentBlockingReasonText,
      _DunningAreaText,
      _FixedCashDiscountTypeText,
      _SupplyingCountryText,
      _CustomerSupplierCountryText,
      _FinServicesProductGroupT,
      _FinancialServicesBranchT,
      _FinancialDataSourceT,
      _CustomerSupplierIndustryText,
      _CustomerGroupText,
      _HouseBankText,
      _HouseBankAccountText,

      //DCL

      AssetClass,
      _GLAccountInCompanyCode,
      _CurrentProfitCenter,
      _CurrentCostCenter,
      _AccountingDocumentType,
      _Order,
      _SalesDoc,
      _ServiceDocument
}