R_InsurPlcyClauseTP_2

@EndUserText.label: 'Clause under Policy'
@VDM: {
  viewType:#TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
@AccessControl: {
authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   semanticKey: [ 'InsurPlcyClauseID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@ObjectModel.sapObjectNodeType.name: 'InsurancePolicy'
@AbapCatalog.extensibility: {
  extensible: true,
  elementSuffix: 'CLS',
  allowNewDatasources: false,
  allowNewCompositions: true,
  dataSources: [ '_Extension' ],
  quota: {
    maximumFields: 100,
    maximumBytes: 1000
  }
}
define view entity R_InsurPlcyClauseTP_2
  as select from I_InsurPlcyBsClauseBasic as Clause

  association        to parent R_InsurancePolicyTP_2 as _Policy    on  $projection.InsurPlcyUUID = _Policy.InsurPlcyUUID


  association [1..1] to E_InsurancePolicyClause      as _Extension on  $projection.InsurPlcySubCvrgID          = _Extension.InsurPlcySubCvrgID
                                                                   and $projection.InsurPlcyInsuredObjectID    = _Extension.InsurPlcyInsuredObjectID
                                                                   and $projection.InsurPlcyClauseID           = _Extension.InsurPlcyClauseID
                                                                   and $projection.InsurPlcyJrnlEndNmbr        = _Extension.InsurPlcyJrnlEndNmbr
                                                                   and $projection.InsurPlcyCoverageOptionID   = _Extension.InsurPlcyCoverageOptionID
                                                                   and $projection.InsurPlcyCoveragePackageID  = _Extension.InsurPlcyCoveragePackageID
                                                                   and $projection.InsurPlcyCoverageID         = _Extension.InsurPlcyCoverageID
                                                                   and $projection.InsurPlcyJrnlNmbr           = _Extension.InsurPlcyJrnlNmbr
                                                                   and $projection.InsurPlcyUUID               = _Extension.InsurPlcyUUID
                                                                   and $projection.InsurPlcyInsurContr         = _Extension.InsurPlcyInsurContr
                                                                   and $projection.InsurPlcyUndrwrtgDcsnRiskID = _Extension.InsurPlcyUndrwrtgDcsnRiskID
{
  key InsurPlcyUUID,
  key InsurPlcyInsurContr,
  key InsurPlcyCoveragePackageID,
  key InsurPlcyCoverageID,
  key InsurPlcyCoverageOptionID,
  key InsurPlcyInsuredObjectID,
  key InsurPlcyUndrwrtgDcsnRiskID,
  key InsurPlcySubCvrgID,
  key InsurPlcyClauseID,
      InsurPlcyJrnlEndNmbr,
      InsurPlcyJrnlNmbr,
      InsurPlcyProductPackageID,
      InsurPlcyClauseIsCanceled,
      InsurPlcyIndivClauseAgrmtText,
      InsurPlcyClauseDetailTextUUID,
      LongText,
      TextObjectCategory,
      TextObjectKey,
      Language,
      InsurPlcyClauseType,
      InsurPlcyClauseStartDate,
      InsurPlcyClauseEndDate,
      InsurPlcyClauseTemplate,
      InsurPlcyClauseClauseNumber,
      InsurancePolicyApplication,
      InsurPlcyBusinessObject,
      LastChangeDateTime,

      /*Association*/
      _Policy
}
where
      InsurPlcyInsurContr         = 0
  and InsurPlcyCoveragePackageID  = 0
  and InsurPlcyCoverageID         = 0
  and InsurPlcyCoverageOptionID   = 0
  and InsurPlcyInsuredObjectID    = 0
  and InsurPlcyUndrwrtgDcsnRiskID = 0
  and InsurPlcySubCvrgID          = 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURPLCYBSCLAUSEBASIC"
],
"ASSOCIATED":
[
"R_INSURANCEPOLICYTP_2"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/