R_InsurClmSrvcsSubrogationTP

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Claim Services Subrogation Header TP'
@AbapCatalog.extensibility.extensible
@AbapCatalog.extensibility.elementSuffix: 'ICL'
@AbapCatalog.extensibility.quota.maximumFields: 100
@AbapCatalog.extensibility.quota.maximumBytes: 1000
@AbapCatalog.extensibility.dataSources: ['_Extension']
@Metadata.ignorePropagatedAnnotations: true
@VDM: {
  viewType:#TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
@ObjectModel: {
   semanticKey: [ 'InsuranceClaim' ],
usageType:{
  dataClass:      #TRANSACTIONAL,
  serviceQuality: #C,
  sizeCategory:   #L
},
sapObjectNodeType.name: 'InsurClmSrvcsSubrogation'
}
define view entity R_InsurClmSrvcsSubrogationTP
  as select from I_InsurClmSubrogation
  association        to parent R_InsurClmSrvcsInsurClaimTP as _InsuranceClaim on  $projection.InsuranceClaim = _InsuranceClaim.InsuranceClaim
  composition [1..*] of R_InsurClmSrvcsSubrogtnItemTP as _InsurClmSubrogtnItem
  composition [1..*] of R_InsurClmSrvcsRblsHeaderTP as _InsurClmSubrogtnRbls
  association [1..1] to E_InsurClmSubrogation              as _Extension      on  $projection.InsuranceClaim          = _Extension.InsuranceClaim
                                                                              and $projection.InsurClmSubrogationUUID = _Extension.InsurClmSubrogationUUID
{
  key I_InsurClmSubrogation.InsuranceClaim,
  key I_InsurClmSubrogation.InsurClmSubrogationUUID,
      I_InsurClmSubrogation.ChangedOnDateTime,
      I_InsurClmSubrogation.LastChangedByUser,
      I_InsurClmSubrogation.InsurClmDatabaseLineStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimSubrogationType'
      I_InsurClmSubrogation.InsurClaimSubrogationType,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurClmSubrogationReason'
      I_InsurClmSubrogation.InsurClmSubrogationReason,
      @Semantics.amount.currencyCode: 'InsurClaimSubrogationCurrency'
      I_InsurClmSubrogation.InsurClmSubrogationEstAmount,
      I_InsurClmSubrogation.InsurClaimSubrogationCurrency,
      I_InsurClmSubrogation.InsurClmSubrogationLbltyRate,
      I_InsurClmSubrogation.InsurClmSubrogtnProbltyRate,
      I_InsurClmSubrogation.InsurClmSubrogationPartyLiable,
      I_InsurClmSubrogation.InsurClmLtgtnUUID,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurClmSubrogationStatus'
      I_InsurClmSubrogation.InsurClmSubrogationStatus,
      I_InsurClmSubrogation.InsurClmSubrogationStatusText,
      I_InsurClmSubrogation.InsurClmSubrogationSentDate,
      I_InsurClmSubrogation.InsurClmSubrogationIsFinished,
      I_InsurClmSubrogation.InsurClmSubrogtnClsRsnTxt,
      I_InsurClmSubrogation.InsurClmSubrogationNumber,
      I_InsurClmSubrogation.InsurClmSubrogationCompId,

      /* Associations */
      _InsuranceClaim,
      _InsurClmSubrogtnItem,
      _InsurClmSubrogtnRbls
} where I_InsurClmSubrogation.InsurClmActive = 'A'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURCLMSUBROGATION"
],
"ASSOCIATED":
[
"R_INSURCLMSRVCSINSURCLAIMTP",
"R_INSURCLMSRVCSRBLSHEADERTP",
"R_INSURCLMSRVCSSUBROGTNITEMTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/