R_InsurClaimItemTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Insurance Claim Item - TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM: {
  viewType:#TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
@ObjectModel: {
   semanticKey: [ 'InsuranceClaim' ],
usageType:{
  dataClass:      #TRANSACTIONAL,
  serviceQuality: #C,
  sizeCategory:   #XL
}
}
define view entity R_InsurClaimItemTP as select from I_InsurClmItem as ClaimItem          
    inner join I_InsurClmItemEvaluation as ClaimItemEval
          on ClaimItem.InsuranceClaim         = ClaimItemEval.InsuranceClaim
          and ClaimItem.InsurClmSubclm         = ClaimItemEval.InsurClmSubclm
          and ClaimItem.InsurClmItem           = ClaimItemEval.InsurClmItem
          and ClaimItem.InsurClmItemEvaluation = ClaimItemEval.InsurClmItemEvaluation
    association to parent R_InsuranceClaimTP as _InsuranceClaim
          on $projection.InsuranceClaim = _InsuranceClaim.InsuranceClaim
    association [1..1] to E_InsuranceClaimItem   as _Extension  on  $projection.InsuranceClaim = _Extension.InsuranceClaim
                                                                and $projection.InsurClmSubclm = _Extension.InsurClmSubclm
                                                                and $projection.InsurClmItem   = _Extension.InsurClmItem
                                                            
{    
  key ClaimItem.InsuranceClaim,
  key ClaimItem.InsurClmSubclm,
  key ClaimItem.InsurClmItem,
  key ClaimItemEval.InsurClmItemEvaluation,
      ClaimItem.LastChangeDateTime            as LastChangeDateTime,
      @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimItemCategory'
      ClaimItem.InsurClmItemCat               as InsurClmItemCat,
      @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimItemType'
      ClaimItem.InsurClmItemType              as InsurClmItemType,
      @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimCoverageType'
      ClaimItem.InsurClmCoverageType          as InsurClmCoverageType,
      @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimBenefitType'
      ClaimItem.InsurBnftType                 as InsurBnftType,
       @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimItemStatus'
      ClaimItem.InsurClmItemStatus            as InsurClmItemStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClaimItemRejectionRsn'
      ClaimItem.InsurClmItemRjcnRsn           as InsurClmItemRjcnRsn,
      ClaimItem.InsurClmItemDescription       as InsurClmItemDescription,
      @ObjectModel.sapObjectNodeTypeReference: 'InsuranceClmItemEvaluationBase'
      ClaimItem.InsurClmItemEvalBase          as InsurClmItemEvalBase,
      @Semantics.quantity.unitOfMeasure: 'InsurClmItemEvalQuantityUnit'
      ClaimItem.InsurClmItemEvalQuantity      as InsurClmItemEvalQuantity,
      ClaimItem.InsurClmItemEvalQuantityUnit  as InsurClmItemEvalQuantityUnit,
      @Semantics.amount.currencyCode: 'InsurClmItemEvalCurrency'
      ClaimItem.InsurClmItemEvalPerUnitAmt    as InsurClmItemEvalPerUnitAmt,
      @Semantics.amount.currencyCode: 'InsurClmItemEvalCurrency'
      ClaimItem.InsurClmItemEvalAmount        as InsurClmItemEvalAmount,
      ClaimItem.InsurClmItemEvalCurrency      as InsurClmItemEvalCurrency,
      ClaimItem.InsurClmItemEvalFactor        as InsurClmItemEvalFactor,
      @Semantics.amount.currencyCode: 'InsurClmItemEvalCurrency'
      ClaimItem.InsurClmItmEvalActlCshValAmt  as InsurClmItmEvalActlCshValAmt,
      ClaimItem.InsurClmItmEvalActlCshValPct  as InsurClmItmEvalActlCshValPct,
      ClaimItem.InsurClmBRFCalcExpression     as InsurClmBRFCalcExpression,
      ClaimItem.InsurClmItemTaxCode           as InsurClmItemTaxCode,
      ClaimItem.InsurClmItemSubclmRef         as InsurClmItemSubclmRef,
      ClaimItem.InsurClmItemRef               as InsurClmItemRef,
      ClaimItem.InsurClmDamagedObject         as InsurClmDamagedObject,
      //      ClaimItemEval.InsurClmItemEvalCat        as InsurClmItemEvalCat,

      ClaimItemEval.InsurClmItemEvalDate       as InsurClmItemEvalDate,
      ClaimItemEval.InsurClmItemLiabilityRate  as InsurClmItemLiabilityRate,
      @Semantics.amount.currencyCode: 'InsurClmItemEvalCurrency'
      ClaimItemEval.InsurClmItemClmdAmount     as InsurClmItemClmdAmount,
     
      //Associations

      _InsuranceClaim
     
}
where ClaimItem.InsurClmDatabaseLineStatus     <> 'X'
  and ClaimItemEval.InsurClmDatabaseLineStatus <> 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURCLMITEM",
"I_INSURCLMITEMEVALUATION"
],
"ASSOCIATED":
[
"R_INSURANCECLAIMTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/