R_InspectionCharacteristicTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #TRANSACTIONAL
@EndUserText.label: 'Inspection Characteristic - TP'
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #B,
  sizeCategory: #XL,
  dataClass: #TRANSACTIONAL
}
define view entity R_InspectionCharacteristicTP
  as select from I_InspectionCharacteristic

  composition [0..1] of R_InspectionResultTP    as _InspectionResult

  association        to parent R_InspectionOperationTP as _InspectionOperation      on  $projection.InspectionLot               = _InspectionOperation.InspectionLot
                                                                                    and $projection.InspPlanOperationInternalID = _InspectionOperation.InspPlanOperationInternalID

  association [1..1] to R_InspectionLotTP       as _InspectionLot                   on  $projection.InspectionLot = _InspectionLot.InspectionLot
  association        to one I_InspSubsetCharacteristic as _InspSubsetCharacteristic on  $projection.InspectionLot                            = _InspSubsetCharacteristic.InspectionLot
                                                                                    and $projection.InspPlanOperationInternalID              = _InspSubsetCharacteristic.InspPlanOperationInternalID
                                                                                    and $projection.InspectionCharacteristic                 = _InspSubsetCharacteristic.InspectionCharacteristic
                                                                                    and _InspSubsetCharacteristic.InspectionSubsetInternalID = '000000'
{
  key InspectionLot,
  key InspPlanOperationInternalID,
  key InspectionCharacteristic,
      InspectionSpecificationText,
      @Semantics.booleanIndicator: true
      HasInspCharcPrtlSmpl,
      BOOCharacteristicInspRelevance,
      InspCharcUnplannedProcessing,
      InspSpecIsQuantitative,
      @Semantics.booleanIndicator: true
      InspSpecIsMeasuredValueRqd,
      @Semantics.booleanIndicator: true
      InspSpecIsSelectedSetRequired,
      @Semantics.booleanIndicator: true
      InspSpecIsLongTermInspection,
      InspSpecRecordingType,
      InspResultIsDocumentationRqd,
      InspSpecCharcCategory,
      InspSpecResultCalculation,
      @Semantics.booleanIndicator: true
      InspSpecHasSamplingProcedure,
      @Semantics.booleanIndicator: true
      InspSpecIsDefectRecordingRqd,
      @Semantics.booleanIndicator: true
      InspSpecIsDefectsRecgAutomatic,
      @Semantics.booleanIndicator: true
      InspSpecIsChgDocRequired,
      @Semantics.booleanIndicator: true
      InspSpecHasControlChart,
      InspCharcIsNotPlanned,
      InspectionMethod,
      InspectionMethodPlant,
      InspectionMethodVersion,
      InspectionSpecificationPlant,
      InspectionSpecification,
      InspectionSpecificationVersion,
      InspCharcPrtlSmpl,
      InspectionCharacteristicStatus,
      InspSpecDecimalPlaces,
      SamplingProcedure,
      InspectionSpecificationUnit,
      BOOCharcMatlToSampleUnitRate,
      BOOCharcSampleToMatlUnitRate,      
      DefectFractionEstimationProced,
      InspSampleValuationRule,
      QuantityUnit,
      InspCharacteristicSampleSize,
      InspCharacteristicSampleUnit,
      InspSpecSampleQuantityFactor,
      @Semantics.quantity.unitOfMeasure: 'InspectionSpecificationUnit'
      InspSpecTargetValue,
      @Semantics.booleanIndicator: true
      InspSpecHasTargetValue,
      @Semantics.quantity.unitOfMeasure: 'InspectionSpecificationUnit'
      InspSpecUpperLimit,
      @Semantics.booleanIndicator: true
      InspSpecHasUpperLimit,
      @Semantics.quantity.unitOfMeasure: 'InspectionSpecificationUnit'
      InspSpecLowerLimit,
      @Semantics.booleanIndicator: true
      InspSpecHasLowerLimit,
      InspSpecImportanceCode,
      CharacteristicAttributeCatalog,
      SelectedCodeSet,
      SelectedCodeSetPlant,
      InspSpecAdditionalCatalog2,
      InspSpecAdditionalCatalog3,
      InspSpecAdditionalCatalog4,
      InspSpecAdditionalCatalog5,
      InspSpecAddlSeldCodeSetPlant2,
      InspSpecAddlSeldCodeSetPlant3,
      InspSpecAddlSeldCodeSetPlant4,
      InspSpecAddlSeldCodeSetPlant5,
      InspSpecAdditionalSelectedSet2,
      InspSpecAdditionalCodeGroup2,
      InspSpecAdditionalSelectedSet3,
      InspSpecAdditionalCodeGroup3,
      InspSpecAdditionalSelectedSet4,
      InspSpecAdditionalCodeGroup4,
      InspSpecAdditionalSelectedSet5,
      InspSpecAdditionalCodeGroup5,
      InspSpecificationHasLongText,
      InspectorQualification,
      @Semantics.booleanIndicator: true
      InspSpecHasFormula,
      InspSpecFormula1,
      InspSpecFormula2,
      InspSpecInformationField1,
      InspSpecInformationField2,
      InspSpecInformationField3,
      InspSpecDefectCodeGrpRjcnLower,
      InspSpecDefectCodeRjcnLower,
      InspSpecDefectCodeGrpRjcnUpper,
      InspSpecDefectCodeRjcnUpper,
      InspSpecDefectCodeGrpRejection,
      InspSpecDefectCodeRejection,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      InspCharcQuantity,
      InspectionLotSampleUnit,      
      InspSpecControlIndicators,
      UnplndCharcInspSubsetIntID,
      InspLotDynamicRule,
      QualityLevelInternalID,
      SamplingProcedureInspSubset,
      ProductionOrderOperationActy,
      ProductionOrderOpActyVers,
      InspCharcConfirmationNumber,
      BOOCharacteristicVersion,
      InspCharcCreationDate,
      InspectionsNotSkippedDnmntr,
      QltyCtrlChartAggrgnCriterion,
      BOOCharcGroup,
      BOOCharcSourceCharc,
      BOOCharcGroupDivision,
      
      //Relevant fields from 0-Instance of QASV

      _InspSubsetCharacteristic.QualityControlChart, 
      _InspSubsetCharacteristic.InspSampleAcceptanceNumber, 
      _InspSubsetCharacteristic.InspSampleRejectionNumber, 
      _InspSubsetCharacteristic.InspSampleValuationRule as InspSingleSampleValuationRule,
      _InspSubsetCharacteristic.InspectionSampleSize, 
      _InspSubsetCharacteristic.InspLotDynRuleStage, 
      _InspSubsetCharacteristic.InspectionSeverity, 
      _InspSubsetCharacteristic.InspSampleAcceptanceFactor,
      @Semantics.booleanIndicator
      _InspSubsetCharacteristic.InspSampleHasAcceptanceFactor, 
      _InspSubsetCharacteristic.InspectionCharacteristicStatus as InspectionSampleStatus,
      @Semantics.quantity.unitOfMeasure: 'InspCharacteristicSampleUnit'            
      _InspSubsetCharacteristic.InspectionSampleQuantity, 

      /* Associations */
      _CharcAttribSelectedCodeSet,
      _InspCharacteristic,
      _InspCharacteristicSampleUnit,
      _InspCharacteristicStatus,
      _InspectionLot,
      _InspectionMethodPlant,
      _InspectionMethodVersion,
      _InspectionOperation,
      _InspectionResult,
      _InspectionResultValue,
      _InspectionSpecificationPlant,
      _InspectionSpecificationUnit,
      _InspLotDynamicRule,
      _InspSampleResult,
      _InspSpecificationVersion,
      _InspSpecImportanceCode,
      _QuantityUnit,
      _BOOCharcInspRelevance
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSPECTIONCHARACTERISTIC",
"I_INSPSUBSETCHARACTERISTIC"
],
"ASSOCIATED":
[
"I_BOOCHARCINSPRELEVANCE",
"I_CHARCATTRIBSELECTEDCODESET",
"I_INSPECTIONMETHODVERSION",
"I_INSPECTIONRESULTSTATUS",
"I_INSPECTIONRESULTVALUE",
"I_INSPLOTDYNAMICRULE",
"I_INSPSPECIFICATIONVERSION",
"I_INSPSPECIMPORTANCECODE",
"I_INSPSUBSETCHARACTERISTIC",
"I_INSPSUBSETRESULT",
"I_PLANT",
"I_UNITOFMEASURE",
"R_INSPECTIONLOTTP",
"R_INSPECTIONOPERATIONTP",
"R_INSPECTIONRESULTTP"
],
"BASE":
[
"I_INSPECTIONCHARACTERISTIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/