R_InhRepairNoteTP

@EndUserText.label: 'Notes for In-House Repair'
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@AccessControl: {
  authorizationCheck: #MANDATORY
}
@Metadata: {
  ignorePropagatedAnnotations: true
}
@ObjectModel: {
  usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
}


define view entity R_InhRepairNoteTP
  as select from P_InhRepairNote  as ihrnote

  // We need an empty string field for the text. String fields cannot be created as "cast('' as systring)...".

  // Hence, we implement a dummy join that never returns a matching record but provides the string field (which then is null).

    left outer to one join crms4t_note_temp as _InoteTemp on _InoteTemp.id = ihrnote.InHouseRepair

  association        to parent I_InHouseRepairTP as _InHouseRepairTP    on  $projection.InHouseRepair = _InHouseRepairTP.InHouseRepair

  association [1..1] to I_InHouseRepair          as _InHouseRepair      on  $projection.CustMgmtObjectType = _InHouseRepair.CustMgmtObjectType
                                                                        and $projection.InHouseRepair      = _InHouseRepair.InHouseRepair

  association [0..1] to I_TextObjectType         as _TextObjectType     on  $projection.TextObjectType     = _TextObjectType.TextObjectType
                                                                        and $projection.TextObjectCategory = _TextObjectType.TextObjectCategory

  association [0..1] to I_TextObjectCategory     as _TextObjectCategory on  $projection.TextObjectCategory = _TextObjectCategory.TextObjectCategory

  association [0..1] to I_Language               as _Language           on  $projection.Language = _Language.Language
{
  key  ihrnote.InHouseRepair,

       @ObjectModel.foreignKey.association: '_TextobjectType'
  key  ihrnote.TextObjectType,

       @Semantics.language: true
       @ObjectModel.foreignKey.association: '_Language'
  key  ihrnote.Language,

       ihrnote.InHouseRepairUUID,

       @ObjectModel.foreignKey.association: '_TextObjectCategory'
       ihrnote.TextObjectCategory,

       @Semantics.user.createdBy: true
       ihrnote.CreatedByUser,

       // required for association to I_InhouseRepair. This is neccessary due to restrictions in projection view

       // when using custom query

       ihrnote.CustMgmtObjectType,
       
       // required for ETag

       _InHouseRepair.LastChangeDateTime,
      
       @Semantics.text:true
       _InoteTemp.text as InhRepairNoteText,

       _TextObjectType,
       _TextObjectCategory,
       _Language,

       _InHouseRepairTP,
       _InHouseRepair

}
where
  ihrnote.CustMgmtObjectType = 'BUS2000256'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INHOUSEREPAIR",
"P_INHREPAIRNOTE",
"CRMS4T_NOTE_TEMP"
],
"ASSOCIATED":
[
"I_INHOUSEREPAIR",
"I_INHOUSEREPAIRTP",
"I_LANGUAGE",
"I_TEXTOBJECTCATEGORY",
"I_TEXTOBJECTTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/