R_HierRuntimeRepresentation

@AbapCatalog.sqlViewName: 'RHRRPDIR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Hierarchy Directory'
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@ObjectModel: {
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #B,
    sizeCategory: #XXL
   }
}
@ClientHandling.algorithm: #SESSION_VARIABLE

define view R_HierRuntimeRepresentation
  as select from hrrp_dir_n
  association [0..*] to R_HierRuntimeRprstnText as _Text on  $projection.HierarchyID     = _Text.HierarchyID
                                                         and $projection.ValidityEndDate = _Text.ValidityEndDate
{
               @ObjectModel.text.association: '_Text'
  key          hryid_42                                              as HierarchyID,
  key          cast( '000000000000001' as hryversn preserving type ) as HierarchyVersion, //keep it for compatibility


               @Semantics.businessDate.to: true
  key          cast(hryvalto as fis_datbi preserving type )          as ValidityEndDate,
               hrytyp                                                as HierarchyType,

               @Semantics.businessDate.from: true
               cast(hryvalfrom as fis_datab preserving type )        as ValidityStartDate,

               @Semantics.user.lastChangedBy: true
               upduser                                               as LastChangedByUser,
               @Semantics.systemDateTime.lastChangedAt: true
               updtime                                               as LastChangeDateTime,

               hrycls                                                as HierarchyClass,
               hrysid                                                as HierarchyShortID,
               cretime                                               as FromCreationDateTime,
               creuser                                               as CreatedByUser, //VDM_CREATEDBYUSERID

               //HRRP_SI_CLFD

               kokrs                                                 as ControllingArea, //FIS_KOKRS

               ktopl                                                 as ChartOfAccounts, //FIS_KTOPL

               itclg                                                 as ConsolidationChartOfAccounts,
               sityp                                                 as SubItemCategory,
               scen_id                                               as ValidationScenarioID,
               fikrs                                                 as FinancialManagementArea,
               fma_fisyear                                           as FinMgmtAreaFiscalYear,
               //HRRP_SI_HATTR

               salesorganization                                     as SalesOrganization,
               distributionchannel                                   as DistributionChannel,
               division                                              as Division,
               //HRRP_SI_FSV

               dspra                                                 as Language,
               xergs                                                 as GroupChartOfAccountIsUsed,
               aktva                                                 as FinancialStatementAssetsItem,
               pssva                                                 as FinStatementLiabilitiesItem,
               ergak                                                 as FinancialStatementNetLossItem,
               ergpa                                                 as FinStatementNetProfitItem,
               erggv                                                 as FinStatementProfitAndLossItem,
               zuord                                                 as FinancialStatementOrphansItem,
               anhng                                                 as FinancialStatementNotesItem,
               aging                                                 as GeneralLedgerAgingScope,
               funareaassigned                                       as FunctionalAreaIsUsed,
               semtagassigned                                        as SemanticTagIsUsed,

               _Text
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_DIR_N"
],
"ASSOCIATED":
[
"R_HIERRUNTIMERPRSTNTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/