R_FinWBSElementHierarchyNode

/* This view selects only fro HRRP_DIRECTORY and does not consider WBSElementStructure */
@EndUserText.label: 'Hierarchy Node of WBS Element'
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.internalName:#LOCAL
@ObjectModel: { dataCategory: #HIERARCHY }
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER
//hierarchy Annotation

@ObjectModel.representativeKey: 'HierarchyNode'
@Analytics.technicalName: 'RFIWBSELEMENTHN'
@Hierarchy.parentChild:
[{ recurse:          {   parent: ['ParentNode'],   child:  ['HierarchyNode']  },
  siblingsOrder:    [{   by: 'HierarchyNodeSequence',    direction: #ASC   }],
  directory:        '_Hierarchy'
  }]
@Metadata.ignorePropagatedAnnotations: true 
//@Analytics.dataExtraction: {enabled:true}   

//@ObjectModel.modelingPattern: #ANALYTICAL_PARENT_CHILD_HIERARCHY_NODE

//@ObjectModel.supportedCapabilities: [ #ANALYTICAL_PARENT_CHILD_HIERARCHY_NODE ]  


define view entity R_FinWBSElementHierarchyNode
  as select from    hrrp_node_n
    left outer to one join I_WBSElementBasicData  on hrrp_node_n.leafvalue = I_WBSElementBasicData.WBSElement
    association [1..1] to R_FinWBSElementHierarchy      as _Hierarchy      on  $projection.WBSElementHierarchy = _Hierarchy.WBSElementHierarchy                                                                           
                                                                           and $projection.ValidityEndDate     = _Hierarchy.ValidityEndDate
    association [0..*] to R_FinWBSElementHierarchyNodeT as _Text           on  $projection.WBSElementHierarchy = _Text.WBSElementHierarchy
                                                                           and $projection.HierarchyNode       = _Text.HierarchyNode
                                                                           and $projection.WBSElementExternalID   = ''                                                                          
{
      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @ObjectModel.foreignKey.association: '_Hierarchy'
  key cast ( hrrp_node_n.hryid_42 as fis_finwbshier preserving type )   as WBSElementHierarchy,
  
  key hrrp_node_n.hrynode                                            as HierarchyNode,
      @Semantics.businessDate.to: true
  key cast(hrrp_node_n.hryvalto as fis_datbi preserving type )       as ValidityEndDate,
      hrrp_node_n.parnode                                            as ParentNode,
      @VDM.lifecycle.status:    #DEPRECATED
      cast( '000000000000001' as hryversn )                           as HierarchyVersion,
   
      @Semantics.businessDate.from: true
      cast(hrrp_node_n.hryvalfrom as fis_datab preserving type )     as ValidityStartDate,
      cast(coalesce(I_WBSElementBasicData.WBSElementExternalID, '') as fis_wbsext_no_conv preserving type ) as WBSElementExternalID,
      cast(hrrp_node_n.posid as fis_wbs_no_conv preserving type )   as WBSElement,
      cast('' as fis_parent_wbsext_no_conv)                        as ParentWBSElementExternalID,
      hrrp_node_n.nodetype                                           as NodeType,
      hrrp_node_n.hryseqnbr                            as HierarchyNodeSequence,
      hrrp_node_n.hrylevel                             as HierarchyNodeLevel,      
      _Hierarchy,
      _Text
        
}
where
      hrrp_node_n.nodetype    <> 'D'
  and hrrp_node_n.hrytyp =  '0110'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_WBSELEMENTBASICDATA",
"HRRP_NODE_N"
],
"ASSOCIATED":
[
"R_FINWBSELEMENTHIERARCHY",
"R_FINWBSELEMENTHIERARCHYNODET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/