R_DebitMemoRequestItemTextTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}

@ObjectModel.semanticKey: ['DebitMemoRequest', 'DebitMemoRequestItem', 'Language', 'LongTextID']

@Metadata.ignorePropagatedAnnotations: true

@AccessControl.authorizationCheck: #CHECK

@EndUserText.label: 'Debit Memo Request Item - Text TP'
@ObjectModel.dataCategory: #TEXT
define view entity R_DebitMemoRequestItemTextTP
  as select from P_SalesDocumentItemText( P_SAPClient : $session.client ) as DebitMemoRequestItemText 

  inner join   I_SalesDocumentItemBasic               as SalesDocumentItemBasic       on  SalesDocumentItemBasic.SalesDocument      = DebitMemoRequestItemText.SalesDocument
                                                                                      and SalesDocumentItemBasic.SalesDocumentItem  = DebitMemoRequestItemText.SalesDocumentItem
                                                                                      and SalesDocumentItemBasic.SDDocumentCategory = 'L'

  inner join   I_SalesDocumentItemCategory            as SalesDocumentItemCategory    on SalesDocumentItemCategory.SalesDocumentItemCategory = SalesDocumentItemBasic.SalesDocumentItemCategory

  association to parent R_DebitMemoRequestItemTP     as _Item                        on  $projection.DebitMemoRequest     = _Item.DebitMemoRequest
                                                                                      and $projection.DebitMemoRequestItem = _Item.DebitMemoRequestItem

  association [0..*] to I_TextDeterminationProcedItem as _TextDeterminationProcedItem on  $projection.TextDeterminationProcedure          = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                      and $projection.LongTextID                          = _TextDeterminationProcedItem.LongTextID
                                                                                      and _TextDeterminationProcedItem.TextObjectCategory = 'VBBP'

  association [1..1] to R_DebitMemoRequestTP         as _DebitMemoRequest           on  $projection.DebitMemoRequest = _DebitMemoRequest.DebitMemoRequest

  association [0..1] to I_Language                    as _Language                    on  $projection.LanguageForEdit = _Language.Language

  association [0..1] to I_SDDocumentItemLongTextID    as _LongTextID                  on  $projection.LongTextIDForEdit = _LongTextID.LongTextID

{
  key cast(DebitMemoRequestItemText.SalesDocument as debit_memo_request preserving type)  as DebitMemoRequest,

  key cast(DebitMemoRequestItemText.SalesDocumentItem as debit_memo_request_item preserving type) as DebitMemoRequestItem,
      @Semantics.language: true
  key DebitMemoRequestItemText.Language,

  key DebitMemoRequestItemText.LongTextID,

      @ObjectModel.foreignKey.association: '_LongTextID'
      @ObjectModel.editableFieldFor: '_LongTextID'
      DebitMemoRequestItemText.LongTextID                                                  as LongTextIDForEdit,

      @ObjectModel.foreignKey.association: '_Language'
      @ObjectModel.editableFieldFor: '_Language'
      DebitMemoRequestItemText.Language                                                    as LanguageForEdit,
      @Semantics.text: true
      DebitMemoRequestItemText.LongText,

      @Consumption.hidden: true
      SalesDocumentItemCategory.TextDeterminationProcedure,

      _TextDeterminationProcedItem.TextDeterminationProcedureItem                           as TextDeterminationProcedureItem,

      //    For Access control

      @Consumption.hidden: true
      SalesDocumentItemBasic.SalesDocumentType                                              as DebitMemoRequestType,
      @Consumption.hidden: true
      SalesDocumentItemBasic.OrganizationDivision,
      @Consumption.hidden: true
      SalesDocumentItemBasic.SalesOrganization,
      @Consumption.hidden: true
      SalesDocumentItemBasic.DistributionChannel,

      //     Exposed associations

      _Item,
      _DebitMemoRequest,
      _Language,
      _LongTextID
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESDOCUMENTITEMBASIC",
"I_SALESDOCUMENTITEMCATEGORY",
"I_TEXTDETERMINATIONPROCEDITEM"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_SDDOCUMENTITEMLONGTEXTID",
"R_DEBITMEMOREQUESTITEMTP",
"R_DEBITMEMOREQUESTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/