R_CustomerReturnShipToPartyTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Returns Order Ship-to Party - TP'
define view entity R_CustomerReturnShipToPartyTP
  as select from I_CustomerReturnPartner as CustomerReturnPartner

  association        to parent R_CustomerReturnTP as _CustomerReturn          on  $projection.CustomerReturn = _CustomerReturn.CustomerReturn
  
  association [0..1] to I_Language                as _CorrespondenceLanguage  on  $projection.CorrespondenceLanguage = _CorrespondenceLanguage.Language
  association [0..1] to I_TransportationZone      as _TransportationZone      on  $projection.transportzone = _TransportationZone.TransportZone
                                                                              and $projection.country       = _TransportationZone.CountryCode
  association [0..1] to I_FormOfAddress           as _FormOfAddress           on  $projection.FormOfAddress = _FormOfAddress.FormOfAddress

{


  key cast(CustomerReturnPartner.CustomerReturn as vdm_customer_return preserving type) as CustomerReturn,

      @ObjectModel.text.element:  [ 'FullName' ]
      CustomerReturnPartner.Customer                                                   as Partner,                  
      
      @Semantics.text:true
      @Semantics.name.fullName: true
      CustomerReturnPartner.FullName,
      
      @Semantics.name.givenName: true
      CustomerReturnPartner._OrgNamePostalAddress.AddresseeName1                       as BusinessPartnerName1,
      
      @Semantics.name.familyName: true
      CustomerReturnPartner._OrgNamePostalAddress.AddresseeName2                       as BusinessPartnerName2,
      
      @Semantics.name.additionalName: true
      CustomerReturnPartner._OrgNamePostalAddress.AddresseeName3                       as BusinessPartnerName3,
      
      @Semantics.name.additionalName: true
      CustomerReturnPartner._OrgNamePostalAddress.AddresseeName4                       as BusinessPartnerName4,

      @ObjectModel.foreignKey.association: '_FormOfAddress'
      @Semantics.name.jobTitle: true
      CustomerReturnPartner.FormOfAddress,     

      @Semantics.address.zipCode:true
      CustomerReturnPartner._OrgNamePostalAddress.PostalCode,

      @Semantics.address.city:true
      CustomerReturnPartner._OrgNamePostalAddress.CityName,

      CustomerReturnPartner._OrgNamePostalAddress.DistrictName,

      @Semantics.address.country:true
      @ObjectModel.foreignKey.association: '_Country'
      CustomerReturnPartner._OrgNamePostalAddress.Country,

      @ObjectModel.foreignKey.association: '_Region'
      @Semantics.address.region: true
      CustomerReturnPartner._OrgNamePostalAddress.Region,

      @Semantics.address.street: true
      CustomerReturnPartner._OrgNamePostalAddress.StreetName,

      @Semantics.address.street: true
      CustomerReturnPartner._OrgNamePostalAddress.StreetPrefixName1,

      @Semantics.address.street: true
      CustomerReturnPartner._OrgNamePostalAddress.StreetPrefixName2,

      @Semantics.address.street: true
      CustomerReturnPartner._OrgNamePostalAddress.StreetSuffixName1,

      @Semantics.address.street: true
      CustomerReturnPartner._OrgNamePostalAddress.StreetSuffixName2,

      @Semantics.address.streetNoNumber: true
      CustomerReturnPartner._OrgNamePostalAddress.HouseNumber,

      @Semantics.telephone.type: [#WORK]
      CustomerReturnPartner.InternationalPhoneNumber,
      
      @Semantics.telephone.type: [#WORK]
      cast(' ' as ad_tlxtns)                                                                           as PhoneNumberExtension,    

      @Semantics.telephone.type: [#CELL]
      CustomerReturnPartner.InternationalPhoneNumber                                                   as InternationalMobilePhoneNumber,

      @Semantics.telephone.type: [#FAX]
      CustomerReturnPartner.InternationalFaxNumber,

      @Semantics.telephone.type: [#FAX]
      cast(' ' as ad_fxxtns)                                                                           as FaxNumberExtension,

      @Semantics.eMail.address: true
      @Semantics.eMail.type:  [#WORK]
      CustomerReturnPartner.EmailAddress,

      @Semantics.address.postBox: true
      CustomerReturnPartner._OrgNamePostalAddress.POBox,

      @Semantics.address.zipCode:true
      CustomerReturnPartner._OrgNamePostalAddress.POBoxPostalCode,

      @EndUserText.label     : 'Correspondence Language'
      @ObjectModel.foreignKey.association: '_CorrespondenceLanguage'
      CustomerReturnPartner.CorrespondenceLanguage,

      CustomerReturnPartner._OrgNamePostalAddress.TaxJurisdiction,

      @ObjectModel.foreignKey.association: '_TransportationZone'
      CustomerReturnPartner._OrgNamePostalAddress.TransportZone,

      @Semantics.text: true
      CustomerReturnPartner.UnloadingPointName,

      CustomerReturnPartner.VATRegistration,
      
      @Consumption.hidden: true
      CustomerReturnPartner.AddressID,
      
      
      CustomerReturnPartner.AddressPersonID,

      CustomerReturnPartner.AddressObjectType,
      
      CustomerReturnPartner.SDDocPartnerAddrIsDocSpecific,
      //DCL

      @Consumption.hidden: true
      _CustomerReturn.CustomerReturnType,
      @Consumption.hidden: true
      _CustomerReturn.SalesOrganization,
      @Consumption.hidden: true
      _CustomerReturn.DistributionChannel,
      @Consumption.hidden: true
      _CustomerReturn.OrganizationDivision,
            
      // Exposed associations

      _CustomerReturn,
      _CorrespondenceLanguage,
      _FormOfAddress,   
      _TransportationZone,      
      CustomerReturnPartner._OrgNamePostalAddress._Country,
      CustomerReturnPartner._OrgNamePostalAddress._Region
      
}
where
//      CustomerReturnPartner._CustomerReturn.ReferenceSDDocumentCategory = 'H' and 

  CustomerReturnPartner.PartnerFunction                   = 'WE'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRORGNAMEPOSTALADDRESS",
"I_CUSTOMERRETURNPARTNER",
"R_CUSTOMERRETURNTP"
],
"ASSOCIATED":
[
"I_COUNTRY",
"I_FORMOFADDRESS",
"I_LANGUAGE",
"I_REGION",
"I_TRANSPORTATIONZONE",
"R_CUSTOMERRETURNTP"
],
"BASE":
[
"I_ADDRORGNAMEPOSTALADDRESS"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/