R_CostRevnProfitabilitySegment

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #NOT_REQUIRED
}
@EndUserText.label: 'Cost Revenue Reassignment Profitability Segment'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XXL,
  dataClass: #MIXED
}
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
define view entity R_CostRevnProfitabilitySegment   
  as select from I_GLAccountLineItemRawData as _Item
    
  inner join I_AccountAssignmentType as _AccountAssignmentType  on _AccountAssignmentType.AccountAssignmentType = _Item.AccountAssignmentType 
  
{
  key _Item.FiscalYear,
  key cast(_Item.ReferenceDocument as referencedocument preserving type) as ReferenceDocument,
  key _Item.ControllingArea,  
  key _Item.LedgerGLLineItem,
  key _Item.ReferenceDocumentItem,
      _Item.CompanyCode,  
      _Item.ReferenceDocumentType, 
      _Item.AccountingDocument, 
      _Item.ReferenceDocumentContext,  
          
      _Item.TransactionSubitem,
      _Item.ControllingDocumentItem,
      _Item.SourceLedger,  
      
      _Item.Customer,
      _Item.CustomerGroup,
      _Item.CustomerSupplierIndustry,
      _Item.CustomerSupplierCountry,
      _Item.SalesDistrict,
      _Item.SoldProduct,
      _Item.SoldProductGroup,
      _Item.SalesOrganization,
      _Item.DistributionChannel,
      _Item.OrganizationDivision,
      _Item.BillToParty,
      _Item.ShipToParty,
          
      //WBS Element

      _Item.WBSElementInternalID,      
      cast(_Item._WBSElementBasicData.WBSElementExternalID as fis_wbsext_no_conv preserving type) as WBSElementExternalID,

      _Item.ServiceDocumentType,
      _Item.ServiceDocument,
      _Item.ServiceDocumentItem,
      
      
      _Item.FunctionalArea,
      _Item.PartnerCompanyCode,
      _Item.ControllingBusTransacType,
      _Item.BusinessTransactionCategory,
      cast(_Item.OriginCtrlgDebitCreditCode as beknz_mask preserving type ) as OriginCtrlgDebitCreditCode,
      _Item.DebitCreditCode
      

}
where
  (
    _Item.ControllingBusTransacType = 'RKU1'
    or _Item.ControllingBusTransacType = 'KAMV'
    or _Item.ControllingBusTransacType = 'RKU2'      
    
  )
  and (_Item.AccountAssignmentType = 'EO' or _Item.PartnerAccountAssignmentType = 'EO')
  and _Item.ReferenceDocumentType = 'COBK'
  and _Item._Ledger.IsLeadingLedger = 'X'
  and _Item.ControllingObject <> ''
  and _Item.JournalEntryIsSecondaryEntry = ''
  and _Item.LogicalSystem = ''
  and _Item._JournalEntry.SenderLogicalSystem = ''
  and (_Item.SourceLedger = _Item._JournalEntry.LedgerGroup or _Item._JournalEntry.LedgerGroup = '' )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACCOUNTASSIGNMENTTYPE",
"I_GLACCOUNTLINEITEMRAWDATA",
"I_JOURNALENTRY",
"I_LEDGER",
"I_WBSELEMENTBASICDATA"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/