R_CostAccountingLineItem

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #NOT_REQUIRED
}
@EndUserText.label: 'Cost Accounting Line Item'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XXL,
  dataClass: #MIXED
}
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
define view entity R_CostAccountingLineItem   
  as select from I_GLAccountLineItemRawData as _Item
      
{
  key _Item.FiscalYear,
  key cast(_Item.ReferenceDocument as referencedocument preserving type) as ReferenceDocument,
  key _Item.ControllingArea,
  key _Item.CompanyCode,  
  key _Item.LedgerGLLineItem,
  key _Item.ReferenceDocumentItem,
  key _Item.ReferenceDocumentType, 
  key _Item.AccountingDocument, 
  key _Item.ReferenceDocumentContext,  
          
      _Item.TransactionSubitem,
      _Item.ControllingDocumentItem,
      _Item.SourceLedger,  
      _Item.DocumentItemText,
      _Item.FiscalPeriod,
      _Item.FiscalYearPeriod,
      _Item.PartnerCompanyCode,
      
      cast(_Item.GLAccount as fco_allocation_account preserving type) as GLAccount,   
      
      _Item.PersonnelNumber,        
    
      _Item.AccountAssignment,      
      _Item.AccountAssignmentType,
      _Item.PartnerAccountAssignment,
      _Item.PartnerAccountAssignmentType,
      
      //Cost Center/Activity Type

      _Item.CostCenter,
      _Item.PartnerCostCenter,      
      _Item.CostCtrActivityType,
      _Item.PartnerCostCtrActivityType,          

      //WBS Element

      _Item.WBSElementInternalID,      
      cast(_Item._WBSElementBasicData.WBSElementExternalID as fis_wbsext_no_conv preserving type) as WBSElementExternalID,
      
      _Item.PartnerWBSElementInternalID,
      cast(_Item._PartnerWBSElementBasicData.WBSElementExternalID as fis_par_psp_pnr_ext preserving type) as PartnerWBSElementExternalID,
      
      cast(_Item._ProjectBasicData.ProjectExternalID as fis_part_projectext_no_conv) as ProjectExternalID,
      
      _Item.ServiceDocumentType,
      _Item.ServiceDocument,
      _Item.ServiceDocumentItem,
      
      //Network

      _Item.ProjectNetwork,
      cast(_Item.RelatedNetworkActivity as fis_npvrg_conv) as RelatedNetworkActivity, 
      
      //Activity or Order

      _Item.OrderID,  
      
      //Order operation

      cast(_Item.OrderOperation as vdm_vornr) as OrderOperation, 
      
      //Cost object

      _Item.CostObject,        
      
      //Sales Order

      _Item.SalesDocument,
      _Item.SalesDocumentItem, 
      
      _Item.WorkItem,
      _Item.BusinessProcess,
      _Item.Product,
      _Item.Plant,
          
      //Recovery indicator

      _Item.JointVentureCostRecoveryCode,
      _Item.SenderCostRecoveryCode,
            
      //Public Sector

      _Item.Fund,
      _Item.FunctionalArea,
      _Item.GrantID,
      _Item.BudgetPeriod,
      _Item.PartnerFund,
      _Item.PartnerFunctionalArea,
      _Item.PartnerGrant,
      _Item.PartnerBudgetPeriod,
      
      _Item.FinancialManagementArea,
      
      _Item.BillableControl,
      
      cast(
        case _Item.AccountAssignmentType
          when 'EO' then _Item.AccountAssignment
          else ''
      end as rkeobjnr) as PartnerProfitabilitySegment,  
      
      @Semantics.booleanIndicator
      cast(
        case _Item.AccountAssignmentType
          when 'EO' then 'X'
          else ''
      end as profitabilitysegmentisassigned preserving type) as ProfitabilitySegmentIsAssigned,      
           
      _Item.OperatingConcern,  

      //RealEstate

      cast(_Item.CompanyCode as vvsbukrs preserving type) as SenderRECompanyCode,
      _Item.REBusinessEntity,
      _Item.RealEstateBuilding,
      _Item.RealEstateProperty,
      _Item.RERentalObject,
      _Item.RealEstateContract,
      _Item.REServiceChargeKey,
      _Item.RESettlementUnitID,
      _Item.SettlementReferenceDate,      
      
      _Item.ChartOfAccounts, 
      _Item.PostingDate,
      _Item.DocumentDate,
      _Item.AccountingDocCreatedByUser,
      _Item.IsReversal,
      _Item.IsReversed,    
      _Item.ReversalReferenceDocument, 
      _Item.PredecessorReferenceDocument,
      _Item.PredecessorReferenceDocItem,  
      
      _Item.ControllingObject,      
      
      _Item.ControllingBusTransacType,
      _Item.BusinessTransactionCategory,
      cast(_Item.OriginCtrlgDebitCreditCode as beknz_mask preserving type ) as OriginCtrlgDebitCreditCode,
      _Item.DebitCreditCode,
      _Item.IsSettled,
      _Item.IsSettlement,
      _Item.ServicesRenderedDate,
      
      _Item.BaseUnit,
      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      cast(_Item.Quantity as lstxx) as Quantity,
      
      _Item.TransactionCurrency,      
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      _Item.AmountInTransactionCurrency,
      
      _Item.CompanyCodeCurrency,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      _Item.AmountInCompanyCodeCurrency,
      
      _Item.GlobalCurrency,
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      _Item.AmountInGlobalCurrency,
      
      _Item.FreeDefinedCurrency1,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
      _Item.AmountInFreeDefinedCurrency1,
      
      _Item.FreeDefinedCurrency2,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
      _Item.AmountInFreeDefinedCurrency2,
      
      _Item.FreeDefinedCurrency3,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
      _Item.AmountInFreeDefinedCurrency3,
      
      _Item.FreeDefinedCurrency4,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
      _Item.AmountInFreeDefinedCurrency4,
      
      _Item.FreeDefinedCurrency5,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
      _Item.AmountInFreeDefinedCurrency5,
      
      _Item.FreeDefinedCurrency6,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
      _Item.AmountInFreeDefinedCurrency6,
      
      _Item.FreeDefinedCurrency7,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
      _Item.AmountInFreeDefinedCurrency7,
      
      _Item.FreeDefinedCurrency8,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
      _Item.AmountInFreeDefinedCurrency8,
      
      _Item.FunctionalCurrency,
      @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
      _Item.AmountInFunctionalCurrency,
      
      _Item.AccountingDocumentType,
      
      _Item.ProfitCenter,
      _Item.PartnerProfitCenter,
      _Item._JournalEntry,
      
      //Profitability Segment fields

      _Item.Customer,
      _Item.CustomerGroup,
      _Item.CustomerSupplierIndustry,
      _Item.CustomerSupplierCountry,
      _Item.SalesDistrict,
      _Item.SoldProduct,
      _Item.SoldProductGroup,
      _Item.SalesOrganization,
      _Item.DistributionChannel,
      _Item.OrganizationDivision,
      _Item.BillToParty,
      _Item.ShipToParty

}
where
  (
    ( (_Item.ControllingBusTransacType = 'RKU1'
      or _Item.ControllingBusTransacType = 'KAMV'
      or _Item.ControllingBusTransacType = 'RKU2'      
      or _Item.ControllingBusTransacType = 'RKU3'
      ) and _Item.ControllingObject <> ''
    )  
    or 
      (_Item.ControllingBusTransacType = 'RKL')     
    or
    (
      _Item.ControllingBusTransacType = 'COIN' 
      and
        _Item.IsReversal = '' and _Item.IsReversed = ''
      and 
        _Item.ControllingObject <> ''  
      and
      (
          _Item.BusinessTransactionCategory <> 'ACAA' and
          _Item.BusinessTransactionCategory <> 'ACAC' and
          _Item.BusinessTransactionCategory <> 'ACAD' and
          _Item.BusinessTransactionCategory <> 'ACEA' and
          _Item.BusinessTransactionCategory <> 'ACPA' and
          _Item.BusinessTransactionCategory <> 'ACPC' and
          _Item.BusinessTransactionCategory <> 'ACPD' and
          _Item.BusinessTransactionCategory <> 'EBDP' and
          _Item.BusinessTransactionCategory <> 'EBVP' and
          _Item.BusinessTransactionCategory <> 'EBWP' and
          _Item.BusinessTransactionCategory <> 'TBCS' and
          _Item.BusinessTransactionCategory <> 'TBRR' and
          _Item.BusinessTransactionCategory <> 'KOAE' and
          _Item.BusinessTransactionCategory <> 'RMWF' and
          _Item.BusinessTransactionCategory <> 'GLA0'
      ) 
    )  
  )
  and _Item._Ledger.IsLeadingLedger = 'X'
  and _Item.JournalEntryIsSecondaryEntry = ''
  and _Item.LogicalSystem = ''
  and _Item.AccountAssignmentType <> ''
  and _Item.ReferenceDocument <> ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_GLACCOUNTLINEITEMRAWDATA",
"I_LEDGER",
"I_PROJECTBASICDATA",
"I_WBSELEMENTBASICDATA"
],
"ASSOCIATED":
[
"I_JOURNALENTRY"
],
"BASE":
[
"I_GLACCOUNTLINEITEMRAWDATA"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/