R_CntrlSuplrQtanScheduleLine

@AbapCatalog.sqlViewName: 'RCNTRLQTNSCHDLN'
@VDM.viewType: #BASIC
@EndUserText.label: 'Restricted View for Cntrl Suplr Qtan Item Schedule Line'
@AbapCatalog.preserveKey:true

@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L

define view R_CntrlSuplrQtanScheduleLine
  as select from I_PurgDocScheduleLineBasic

  association [1..1] to R_CentralSupplierQuotation   as _CentralSupplierQuotation   on  $projection.CentralSupplierQuotation = _CentralSupplierQuotation.CentralSupplierQuotation

  association [1..1] to R_CntrlSupplierQuotationItem as _CntrlSupplierQuotationItem on  $projection.CentralSupplierQuotation     = _CntrlSupplierQuotationItem.CentralSupplierQuotation
                                                                                    and $projection.CentralSupplierQuotationItem = _CntrlSupplierQuotationItem.CentralSupplierQuotationItem
{

  key PurchasingDocument                                                                  as CentralSupplierQuotation,
  key PurchasingDocumentItem                                                              as CentralSupplierQuotationItem,
  key ScheduleLine,

      DelivDateCategory,
      cast( ScheduleLineDeliveryDate as mm_a_delivery_date preserving type)               as ScheduleLineDeliveryDate,
      SchedLineStscDeliveryDate,
      ScheduleLineDeliveryTime,
      ScheduleLineOrderQuantity,
      RoughGoodsReceiptQty,
      OrderQuantityUnit,
      cast (ScheduleLineCommittedQuantity as vdm_awarded_quantity preserving type)        as AwardedQuantity,
      cast (PerformancePeriodStartDate as vdm_performanceperiodstartdate preserving type) as PerformancePeriodStartDate,
      cast (PerformancePeriodEndDate as vdm_performanceperiodenddate preserving type)     as PerformancePeriodEndDate,

      //Associations

      _CentralSupplierQuotation,
      _CntrlSupplierQuotationItem,
      _DeliveryDateCategory
}
where
  ScheduleLine = '0001'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURGDOCSCHEDULELINEBASIC"
],
"ASSOCIATED":
[
"I_DELIVERYDATECATEGORY",
"R_CENTRALSUPPLIERQUOTATION",
"R_CNTRLSUPPLIERQUOTATIONITEM"
],
"BASE":
[
"I_PURGDOCSCHEDULELINEBASIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/