R_BPUsrRoleText

@EndUserText.label: 'Business PartnerUser Role Text'
@AbapCatalog.viewEnhancementCategory: [#NONE]
@ObjectModel.dataCategory: #TEXT
@AccessControl.authorizationCheck: #CHECK
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XL,
  dataClass: #MASTER
}
@Search.searchable: true

define view entity R_BPUsrRoleText
  as select from           tb003 as Role
    inner join             bpu_rolecat_whl  on  bpu_rolecat_whl.rolecategory                 = Role.rolecategory
                                            and bpu_rolecat_whl.hcm_integration_code         = '1' //Dependent from HCM Integration Switch

                                            and bpu_rolecat_whl.solution_characteristic_code = '2' //Cloud & OnPremise

    left outer to one join bum_wf_d_roletxt on  bum_wf_d_roletxt.rolecategory = Role.rolecategory
                                            and bum_wf_d_roletxt.spras        = $session.system_language
  association [0..1] to I_BusinessPartnerRoleText as _RoleText                  on  _RoleText.BusinessPartnerRole = Role.role
                                                                                and _RoleText.Language            = $session.system_language
  association [0..1] to I_BusinessPartnerRoleText as _RoleTextBasicRoleCategory on  _RoleTextBasicRoleCategory.BusinessPartnerRole = bpu_rolecat_whl.basic_rolecategory
                                                                                and _RoleTextBasicRoleCategory.Language            = $session.system_language
{
              @Semantics.language: true
  key         _RoleText.Language                 as Language,
  key         Role.role                          as Role,
              Role.rolecategory                  as RoleCategory,
              @UI.hidden: true
              bpu_rolecat_whl.basic_rolecategory as BasicRoleCategory,
              @Semantics.text: true
              @EndUserText.label: 'Role Description'
              @Search.defaultSearchElement: true
              @Search.fuzzinessThreshold: 0.8
              @Search.ranking: #HIGH
              case
              when bum_wf_d_roletxt.rlctitle is not initial
              then bum_wf_d_roletxt.rlctitle
              when _RoleTextBasicRoleCategory.BusinessPartnerRoleShortName is not initial
              then _RoleTextBasicRoleCategory.BusinessPartnerRoleShortName
              else _RoleText.BusinessPartnerRoleShortName
              end                                as BusinessPartnerRoleShortName
}
where
  _RoleText.Language = $session.system_language
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNERROLETEXT",
"BPU_ROLECAT_WHL",
"BUM_WF_D_ROLETXT",
"TB003"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/