RSODP_ABAP_CDS_f4_all_p2

@AbapCatalog.sqlViewName: 'RSODPABAPCDSF4A2'
@ClientHandling.type: #CLIENT_INDEPENDENT
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering: { status: #ACTIVE, type: #SINGLE }
@AccessControl.authorizationCheck: #NOT_ALLOWED
@EndUserText.label: 'ABAP CDS value help 2'
define view RSODP_ABAP_CDS_f4_all_p2
as select from ddldependency as t0
          inner join ddldependency as t1 on t1.ddlname = t0.ddlname
          inner join ddheadanno as t2 on t2.strucobjn = t1.objectname
          left outer join tadir      as t4 on t4.obj_name  = t1.objectname
                                          and t4.pgmid     = 'R3TR'
                                          and t4.object    = 'STOB'
          left outer join ddheadanno as t5 on t5.strucobjn = t1.objectname
                                          and t5.name      = 'ANALYTICS.HIDDEN'
          left outer join ddheadanno as t6 on t6.strucobjn = t1.objectname
                                          and t6.name      = 'ANALYTICS.QUERY'
  association[*] to ddddlsrc02bt as _text on _text.ddlname = t0.ddlname and _text.strucobjn = t1.objectname and _text.as4local = 'A'
{
         key t0.objectname as viewname,
             t0.ddlname    as ddlname,
             t1.objectname as strucobjn,
             cast( left( t2.value, 255 ) as char255 ) as datacategory,
             t4.devclass   as devclass,
             cast( left( t5.value, 255 ) as char255 ) as hidden,
             cast( left( t6.value, 255 ) as char255 ) as query,
             _text
}
          where t0.state = 'A' and t0.objecttype = 'VIEW'
            and t1.state = 'A' and t1.objecttype = 'STOB'
            and t2.name = 'OBJECTMODEL.DATACATEGORY'
            and ( t2.value = '#CUBE'
               or t2.value = '#FACT'
               or t2.value = '#DIMENSION'
               or t2.value = '#TEXT'
               or t2.value = '#AGGREGATIONLEVEL'
               or t2.value = 'CUBE'
               or t2.value = 'FACT'
               or t2.value = 'DIMENSION'
               or t2.value = 'TEXT'
               or t2.value = 'HIERARCHY'
               or t2.value = '#HIERARCHY')
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DDHEADANNO",
"DDLDEPENDENCY",
"TADIR"
],
"ASSOCIATED":
[
"DDDDLSRC02BT"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0
}
}*/