PiqCds_RegistrationData

@AbapCatalog.sqlViewName: 'PIQCDSREGNDATA'
@ClientDependent: true
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Academic Program Registration Data'
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #X

define view PiqCds_RegistrationData

    with parameters p_date:abap.dats,
                    p_lang:abap.lang

    as select distinct from PiqCds_OrgUnitPrograms ( p_idate : $parameters.p_date, p_lang : $parameters.p_lang) as org
    inner join PiqCds_ProgramStudy ( p_idate : $parameters.p_date, p_lang : $parameters.p_lang ) as prog on org.ProgramOfStudy = prog.ProgramOfStudy and org.ActivePlanVersion = prog.ActivePlanVersion
    inner join PiqCds_StudyStudentRegn ( p_date : $parameters.p_date ) as study on prog.StudyObjectID = study.StudyObject and prog.ActivePlanVersion = study.ActivePlanVersion
    inner join hrp1771 as reg on study.StudyObject = reg.objid and study.ActivePlanVersion = reg.plvar and reg.otype = 'CS'
    inner join dd07t as text on text.domname = 'PIQREG_PERIODSTATUS' and text.ddlanguage = $parameters.p_lang and text.domvalue_l = reg.pr_status
    inner join dd07t as text1 on text1.domname = 'PIQHS_STATE' and text1.ddlanguage = $parameters.p_lang and text1.domvalue_l = reg.prs_state

    association [0..*] to PiqCdsAcademicYear            as _AcademicYear                on _AcademicYear.AcademicYear = reg.ayear
    association [0..*] to PiqCdsAcademicSession         as _AcademicSession             on _AcademicSession.AcademicSession = reg.perid
    association [0..*] to PiqCdsAcademicReason          as _LeaveOfAbsenceReason        on _LeaveOfAbsenceReason.Reason = reg.reason
    association [0..*] to PiqCdsAcademicReason          as _CancellationReason          on _CancellationReason.Reason = reg.cancreason
    association [0..*] to PiqCdsAcademicActivity        as _AcademicActivity            on _AcademicActivity.AcademicActivity = reg.cancprocess
    association [0..*] to PiqCdsProgRegnClassification  as _RegistationClassification   on _RegistationClassification.AcdmcProgRegnClassification = reg.regclass
    association [0..*] to PiqCdsAcademicLevel           as _AcademicLevel               on _AcademicLevel.AcademicLevel = reg.aclevel

    {
    org.ActivePlanVersion,
    org.OrganizationalUnit,
    org.OrganizationalUnitShortName,
    org.OrganizationalUnitName,
    org.ProgramOfStudy            as ProgramOfStudy,
    org.ProgramOfStudyShortName,
    org.ProgramOfStudyName,
    org.ProgramOfStudyType,
    org.ProgramOfStudyTypeName,

    study.StudyObject,
    study.StudentObjectId,
    study.StudentName,
    study.StudentNumber,

    _AcademicYear.AcademicYear,
    _AcademicYear._AcademicYearText[1:Language = $parameters.p_lang].AcademicYearName,

    _AcademicSession.AcademicSession,
    _AcademicSession._AcademicSessionText[1:Language = $parameters.p_lang].AcademicSessionName,

    _LeaveOfAbsenceReason.Reason as LeaveOfAbsenceReason,
    _LeaveOfAbsenceReason._ReasonText [1:Language = $parameters.p_lang].ReasonText as LeaveOfAbsenceReasonName,

    _CancellationReason.Reason as AcdmcProgRegnCanclnReason,
    _CancellationReason._ReasonText[1:Language = $parameters.p_lang].ReasonText as AcdmcProgRegnCanclnReasonName,

    _AcademicActivity.AcademicActivity as AcdmcProgRegnCanclnActivity,
    _AcademicActivity._AcademicActivityText[1:Language = $parameters.p_lang].AcademicActivityName as AcdmcProgRegnCanclnActyName,

    _RegistationClassification.AcdmcProgRegnClassification,
    _RegistationClassification._RegistationClassificationText[1:Language = $parameters.p_lang].AcdmcProgRegnClassfctnName,

    _AcademicLevel.AcademicLevel,
    _AcademicLevel._AcademicLevelText[1:Language = $parameters.p_lang].AcademicLevelName,

    reg.pr_status       as AcdmcSessionRegnStatus,
    text.ddtext         as AcdmcSessionRegnStatusName,
    reg.prs_state       as SessionRegnActivationState,
    text1.ddtext        as SessionRegnActivationStateName,
    reg.regdate         as AcdmcSessionRegistrationDate,
    reg.perct           as StudyCompletionRateInPercent,
    reg.cancdate        as AcdmcProgRegnCancellationDate,
    reg.adm_guid        as AdmissionUUID
    }
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"PIQCDSACADEMICACTIVITY",
"PIQCDSACADEMICACTIVITYTEXT",
"PIQCDSACADEMICLEVEL",
"PIQCDSACADEMICLEVELTEXT",
"PIQCDSACADEMICREASON",
"PIQCDSACADEMICREASONTEXT",
"PIQCDSACADEMICSESSION",
"PIQCDSACADEMICSESSIONTEXT",
"PIQCDSACADEMICYEAR",
"PIQCDSACADEMICYEARTEXT",
"PIQCDSPROGREGNCLASSFCTNTEXT",
"PIQCDSPROGREGNCLASSIFICATION",
"PIQCDS_ORGUNITPROGRAMS",
"PIQCDS_PROGRAMSTUDY",
"PIQCDS_STUDYSTUDENTREGN",
"DD07T",
"HRP1771"
],
"ASSOCIATED":
[
"PIQCDSACADEMICACTIVITY",
"PIQCDSACADEMICLEVEL",
"PIQCDSACADEMICREASON",
"PIQCDSACADEMICSESSION",
"PIQCDSACADEMICYEAR",
"PIQCDSPROGREGNCLASSIFICATION"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0
}
}*/