P_WBHK_PRASP_ValueHelp

@AbapCatalog.sqlViewName: 'PWBHKPRASPVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #BASIC
@VDM.private: true
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #XXL
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #MANDATORY
// 'Trading Contract with Pricing Aspects ValueHelp' with access control for display activity

// ABAP unit tests available in class: CL_CDS_P_WBHK_PRASP_VALUEHELP

define view P_WBHK_PRASP_ValueHelp

  as select from wb2_d_prasp
    inner join wbhk on wbhk.tkonn = wb2_d_prasp.tkonn
    inner join wbhi on wbhi.tkonn = wb2_d_prasp.tkonn and wbhi.tposn = wb2_d_prasp.tposn
    inner join wbhd on wbhd.tkonn = wb2_d_prasp.tkonn and wbhd.tposn = wbhi.wbhd_tposn
    left outer to one join tvta on tvta.vkorg = wbhk.vkorg   and tvta.vtweg = wbhk.vtweg and tvta.spart = wbhk.spart

  association [0..1] to knvv as _CustomerSalesArea on $projection.kunnr = _CustomerSalesArea.kunnr 
                                                  and $projection.vkorg = _CustomerSalesArea.vkorg 
                                                  and tvta.vtwku        = _CustomerSalesArea.vtweg
                                                  and tvta.spaku        = _CustomerSalesArea.spart
  association [0..1] to P_WLF_CDS_LFA1_BG as _Supplier on $projection.elifn = _Supplier.vendor_account

{
  key wbhk.tkonn,
  key wb2_d_prasp.tposn as tposn,
  key wb2_d_prasp.side,
  key wb2_d_prasp.tposn_com,
  key wb2_d_prasp.pr_aspect,
  key wb2_d_prasp.pr_count,
      
      wb2_d_prasp.future,
      wb2_d_prasp.ext_ref,
      wb2_d_prasp.assgmt_rel,
      wb2_d_prasp.cond_type,
      wb2_d_prasp.cond_type2,
      wb2_d_prasp.cond_type3,
      wb2_d_prasp.cond_type4,       

      wbhk.tkonn_ex,        
      wbhk.tctyp,
      wbhk.tksachb,
      wbhk.kunnr,
      wbhd.elifn as elifn,
      wbhk.vkorg,
      wbhk.vtweg,
      wbhk.spart,
      wbhd.ekorg as ekorg,
      wbhd.ekgrp as ekgrp,
      wbhk.ernam,
      wbhk.erdat,
      wbhk.erzeit,
      wbhk.aenam,
      wbhk.aedat,
      wbhk.aezeit,
      wbhk.tccat,

      _CustomerSalesArea.begru as customer_begru,
      _Supplier.vendor_begru
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_WLF_CDS_LFA1_BG",
"KNVV",
"TVTA",
"WB2_D_PRASP",
"WBHD",
"WBHI",
"WBHK"
],
"ASSOCIATED":
[
"P_WLF_CDS_LFA1_BG",
"KNVV"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/