P_WBHK_COM_ITEM_ValueHelp

@AbapCatalog.sqlViewName: 'PWBHKCOMIPVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #BASIC
@VDM.private: true
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #XXL
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #MANDATORY
// 'Trading Contract with Commodity Items ValueHelp' with access control for display activity

// ABAP unit tests available in class: CL_CDS_P_WBHK_COM_ITEM_VALUEHELP

define view P_WBHK_COM_ITEM_ValueHelp

  as select    from wb2_d_comsub
         inner join wbhk on wbhk.tkonn = wb2_d_comsub.tkonn
         inner join wbhi on wbhi.tkonn = wb2_d_comsub.tkonn
                        and wbhi.tposn = wb2_d_comsub.tposn
         inner join wbhd on wbhd.tkonn = wb2_d_comsub.tkonn
                        and wbhd.tposn = wbhi.wbhd_tposn
    left outer to one join tvta on tvta.vkorg = wbhk.vkorg 
                        and tvta.vtweg = wbhk.vtweg 
                        and tvta.spart = wbhk.spart

  association [0..1] to knvv as _CustomerSalesArea on $projection.kunnr = _CustomerSalesArea.kunnr 
                                                  and $projection.vkorg = _CustomerSalesArea.vkorg 
                                                  and tvta.vtwku        = _CustomerSalesArea.vtweg
                                                  and tvta.spaku        = _CustomerSalesArea.spart
  association [0..1] to P_WLF_CDS_KNA1_BG as _CustomerComItem on $projection.customer = _CustomerComItem.customer_account  
  association [0..1] to P_WLF_CDS_LFA1_BG as _Supplier        on $projection.elifn = _Supplier.vendor_account
  association [0..1] to P_WLF_CDS_LFA1_BG as _SupplierComItem on $projection.vendor = _SupplierComItem.vendor_account  
{
  key wbhk.tkonn,
  key wb2_d_comsub.tposn as tposn,
  key wb2_d_comsub.side,
  key wb2_d_comsub.tposn_com,

      wb2_d_comsub.future,
      wb2_d_comsub.com_cat,
      wb2_d_comsub.hkpstp,
      wb2_d_comsub.matnr,
      wb2_d_comsub.vendor,
      wb2_d_comsub.customer,
      wb2_d_comsub.batch,
      wb2_d_comsub.ext_ref,

      wbhk.tkonn_ex,
      wbhk.tctyp,
      wbhk.tksachb,
      wbhk.kunnr,
      wbhd.elifn         as elifn,
      wbhk.vkorg,
      wbhk.vtweg,
      wbhk.spart,
      wbhd.ekorg         as ekorg,
      wbhd.ekgrp         as ekgrp,
      wbhk.ernam,
      wbhk.erdat,
      wbhk.erzeit,
      wbhk.aenam,
      wbhk.aedat,
      wbhk.aezeit,
      wbhk.tccat,

      _CustomerSalesArea.begru        as customer_begru,
      _CustomerComItem.customer_begru as com_item_customer_begru,
      _Supplier.vendor_begru,
      _SupplierComItem.vendor_begru   as com_item_supplier_begru
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_WLF_CDS_KNA1_BG",
"P_WLF_CDS_LFA1_BG",
"KNVV",
"TVTA",
"WB2_D_COMSUB",
"WBHD",
"WBHI",
"WBHK"
],
"ASSOCIATED":
[
"P_WLF_CDS_KNA1_BG",
"P_WLF_CDS_LFA1_BG",
"KNVV"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/