P_UpdatedResidualOpenItem

@AbapCatalog.sqlViewName: 'PAGRIU'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
//@EndUserText.label: 'Residual item update'

@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #NOT_REQUIRED

//@ObjectModel.representativeKey: 'AccountingDocumentItem'

@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #D

@VDM.viewType: #CONSUMPTION

@Metadata.ignorePropagatedAnnotations: true

//@UI.presentationVariant.sortOrder.by: 'LastChangeDate, ChangeDocumentCreationDate, ChangeDocumentCreationTime'

//@UI.presentationVariant.sortOrder.direction: #ASC

@VDM.private: true
define view P_UpdatedResidualOpenItem as 
select from I_OperationalAcctgDocItem as ResidualItem

    inner join I_AccountingDocument      as ResidualHeader on

        // Make sure that ResidualItem is A/R item


        ResidualItem.FinancialAccountType      = 'D' and

    // Make sure that ResidualItem is only searched in relevant categories


        (
            ResidualItem.AccountingDocumentCategory = '' or

            ResidualItem.AccountingDocumentCategory = 'S' or

            ResidualItem.AccountingDocumentCategory = 'A'
        )  and

    // Make sure that ResidualItem is a residual item


        ResidualItem.FollowOnDocumentType      = 'V'  and

    // Make sure that ResidualHeader is not a reversal accounting document


        ResidualItem.CompanyCode               = ResidualHeader.CompanyCode  and

        ResidualItem.FiscalYear                = ResidualHeader.FiscalYear and

        ResidualItem.AccountingDocument        = ResidualHeader.AccountingDocument and

        ( ResidualHeader.IsReversal is null or ResidualHeader.IsReversal = '' )
        
    inner join P_ResItemSession as Session on client = $session.client    

    left outer to many join I_ChangeDocument          as ResidualChange on

        (
            ResidualChange.ChangeDocObjectClass    = 'BELEG' or 
      
            ResidualChange.ChangeDocObjectClass = 'BELEGR'
      
        ) and

        ResidualChange.ChangeDocObject           = concat(
            Session.client, concat(
                ResidualHeader.CompanyCode, concat(
                    ResidualHeader.AccountingDocument, ResidualHeader.FiscalYear
                )
            )
        )       
{

  key ResidualItem.CompanyCode,

  key ResidualItem.FiscalYear,

  key ResidualItem.AccountingDocument,

  key ResidualItem.AccountingDocumentItem,
  
  key ResidualChange.CreationDate                   as ChangeDocCreationDate,

  key ResidualChange.CreationTime                   as ChangeDocumentCreationTime,
  
  key ResidualChange.ChangeDocument,

      ResidualItem.AssignmentReference,

      ResidualHeader.AccountingDocumentHeaderText,

      ResidualItem.DocumentItemText,

      ResidualItem.PaymentDifferenceReason,

      ResidualHeader.AccountingDocumentCreationDate as CreationDate,

      ResidualHeader.CreationTime                   as CreationTime,

      ResidualHeader.LastChangeDate                 as LastChangeDate,
     
      ResidualItem.PostingDate,
      ResidualItem.DocumentDate,
      ResidualItem.NetDueDate,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      ResidualItem.CashDiscountBaseAmount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      ResidualItem.CashDiscountAmount,
      ResidualItem.PaymentTerms,
      ResidualItem.CashDiscount1Days,
      ResidualItem.CashDiscount2Days,
      ResidualItem.NetPaymentDays,
      ResidualItem.CashDiscount1Percent,
      ResidualItem.CashDiscount2Percent,
      ResidualItem.DueCalculationBaseDate,
      ResidualItem.FixedCashDiscount,
      ResidualItem.PaymentBlockingReason,
      ResidualItem.TransactionCurrency
}

where
  ( LastChangeDate is not null or LastChangeDate <> '00000000' )
  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACCOUNTINGDOCUMENT",
"I_CHANGEDOCUMENT",
"I_OPERATIONALACCTGDOCITEM",
"P_RESITEMSESSION"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/