P_TR_StRpElectronicLedgerHdr

@AbapCatalog.sqlViewName: 'PTRELDGRHDR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #COMPOSITE
@VDM.private: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #P
@ObjectModel.usageType.dataClass: #MIXED
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.blocking:#BLOCKED_DATA_INCLUDED

define view P_TR_StRpElectronicLedgerHdr
  with parameters
    P_CompanyCode            : bukrs,
    P_FromPostingDate        : fis_budat_from,
    P_ToPostingDate          : fis_budat_to,
    P_Ledger                 : fins_ledger,
    P_Language               : lang,
    P_CountryChartOfAccounts : abap_boolean,
    P_StatryRptgEntity       : srf_reporting_entity,
    P_StatryRptCategory      : srf_rep_cat_id,
    P_StatryRptRunID         : srf_report_run_id

  as select distinct from P_TR_StRpElectronicLedger( P_SAPClient:$session.client,
                                                     P_CompanyCode:$parameters.P_CompanyCode,
                                                     P_FromPostingDate:$parameters.P_FromPostingDate,
                                                     P_ToPostingDate: $parameters.P_ToPostingDate,
                                                     P_ledger:$parameters.P_Ledger,
                                                     P_Language:$parameters.P_Language,
                                                     P_CountryChartOfAccounts:$parameters.P_CountryChartOfAccounts )

    inner join            I_StRpJournalEntryLog as _ReportedItemsLog on  _ReportedItemsLog.CompanyCode        = P_TR_StRpElectronicLedger.CompanyCode
                                                                     and _ReportedItemsLog.AccountingDocument = P_TR_StRpElectronicLedger.AccountingDocument
                                                                     and _ReportedItemsLog.FiscalYear         = P_TR_StRpElectronicLedger.FiscalYear
                                                                     and _ReportedItemsLog.StatryRptCategory  = $parameters.P_StatryRptCategory
                                                                     and _ReportedItemsLog.StatryRptgEntity   = $parameters.P_StatryRptgEntity
                                                                     and _ReportedItemsLog.StatryRptRunID     = $parameters.P_StatryRptRunID

  association [0..1] to I_Currency as _ReportingCurrency on $projection.CompanyCodeCurrency = _ReportingCurrency.Currency
{

  key P_TR_StRpElectronicLedger.CompanyCode,
  key P_TR_StRpElectronicLedger.AccountingDocument,
  key P_TR_StRpElectronicLedger.FiscalYear,
  key _ReportedItemsLog.StatryRptCategory,
  key _ReportedItemsLog.StatryRptgEntity,
  key _ReportedItemsLog.StatryRptRunID,
      P_TR_StRpElectronicLedger.PostingDate as PostingDateAsText,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      sum(P_TR_StRpElectronicLedger.AmountInCompanyCodeCurrency) as AmountInCompanyCodeCurrency,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      sum(P_TR_StRpElectronicLedger.TR_MonetaryAmtInCoCodeCrcy)  as TR_MonetaryAmtInCoCodeCrcy,
      @Semantics.currencyCode: true
      P_TR_StRpElectronicLedger.CompanyCodeCurrency,
      P_TR_StRpElectronicLedger.AccountingDocCreatedByUser,
      cast(case
      when P_TR_StRpElectronicLedger.DebitCreditCode  = 'S'
      then 'D'
      else 'C'
      end                    as shkzg) as DebitCreditCode,
      P_TR_StRpElectronicLedger.AccountingDocumentHeaderText,
      P_TR_StRpElectronicLedger.TR_EDocHeaderAndRefDocIDText ,
      P_TR_StRpElectronicLedger.DocumentHeaderSeqNumber,
      P_TR_StRpElectronicLedger.DocumentDate as DocumentDateAsText,
      P_TR_StRpElectronicLedger.DocumentReferenceID,
      P_TR_StRpElectronicLedger.TR_ElectronicLedgerDocType,
      P_TR_StRpElectronicLedger.TR_ElectronicLedgerExtDocName,
      P_TR_StRpElectronicLedger.AccountingDocumentType,
      P_TR_StRpElectronicLedger.PostingPeriod,
      _ReportingCurrency               as _ReportingCurrency
}
group by
  P_TR_StRpElectronicLedger.CompanyCode,
  P_TR_StRpElectronicLedger.AccountingDocument,
  P_TR_StRpElectronicLedger.FiscalYear,
  _ReportedItemsLog.StatryRptCategory,
  _ReportedItemsLog.StatryRptgEntity,
  _ReportedItemsLog.StatryRptRunID,
  P_TR_StRpElectronicLedger.PostingDate,
  P_TR_StRpElectronicLedger.DebitCreditCode,
  P_TR_StRpElectronicLedger.CompanyCodeCurrency,
  P_TR_StRpElectronicLedger.AccountingDocCreatedByUser,
  P_TR_StRpElectronicLedger.AccountingDocumentHeaderText,
  P_TR_StRpElectronicLedger.TR_EDocHeaderAndRefDocIDText ,
  P_TR_StRpElectronicLedger.DocumentHeaderSeqNumber,
  P_TR_StRpElectronicLedger.DocumentDate,
  P_TR_StRpElectronicLedger.DocumentReferenceID,
  P_TR_StRpElectronicLedger.TR_ElectronicLedgerDocType,
  P_TR_StRpElectronicLedger.TR_ElectronicLedgerExtDocName,
  P_TR_StRpElectronicLedger.AccountingDocumentType,
  P_TR_StRpElectronicLedger.PostingPeriod;
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_STRPJOURNALENTRYLOG"
],
"ASSOCIATED":
[
"I_CURRENCY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/