P_SuplrCoCodePurgOrganization

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'PSUPPCOCOPUOR'
@Metadata.ignorePropagatedAnnotations: true
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.preserveKey:true
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.private: true
@VDM.viewType: #COMPOSITE
@ObjectModel: {
   usageType.serviceQuality: #C,
   usageType.sizeCategory: #XL,
   usageType.dataClass: #MIXED
}
define view P_SuplrCoCodePurgOrganization
  //companycode = '' => plant-specific purchasing

  as select from I_SupplierPurchasingOrg        as _SupplierPurchasingOrg
  //t024e

    inner join   I_PurchasingOrganization       as _PurchasingOrgWithCoCode on  _PurchasingOrgWithCoCode.PurchasingOrganization = _SupplierPurchasingOrg.PurchasingOrganization
                                                                            and _PurchasingOrgWithCoCode.CompanyCode            = ''
    
    inner join   P_PlntCompanyCodePurchasingOrg as _PlantCoCode             on _PlantCoCode.PurchasingOrganization = _SupplierPurchasingOrg.PurchasingOrganization
    
    inner join   I_SupplierCompany              as _SupplierCompany         on  _SupplierPurchasingOrg.Supplier = _SupplierCompany.Supplier
                                                                            and _SupplierCompany.CompanyCode    = _PlantCoCode.CompanyCode
{
  key    _SupplierPurchasingOrg.Supplier                                                     as Supplier,
  key    _SupplierCompany.CompanyCode                                                        as CompanyCode,
  key    _SupplierPurchasingOrg.PurchasingOrganization,

         //LFM1

         _SupplierPurchasingOrg.PurOrdAutoGenerationIsAllowed,
         _SupplierPurchasingOrg.PurchasingGroup,
         cast (_SupplierPurchasingOrg.PaymentTerms as farp_dzterm_po preserving type)        as SupplierPurgOrgPaymentTerms,
         _SupplierPurchasingOrg.PurchasingIsBlockedForSupplier,
         cast (_SupplierPurchasingOrg.DeletionIndicator as supplist_loevm_m preserving type) as SuplrIsDeltdPurgOrg,
         _SupplierPurchasingOrg.InvoiceIsGoodsReceiptBased,
         _SupplierPurchasingOrg.PurchaseOrderCurrency,
         _SupplierPurchasingOrg.IncotermsClassification,
         _SupplierPurchasingOrg.IncotermsTransferLocation,
         _SupplierPurchasingOrg._IncotermsClassification
}

//company-specific purchasing

//table t024e

union all select from I_PurchasingOrganization as _PurchasingOrgWithCoCode
  inner join          I_SupplierPurchasingOrg  as _SupplierPurchasingOrg on _PurchasingOrgWithCoCode.PurchasingOrganization = _SupplierPurchasingOrg.PurchasingOrganization
  
  inner join          I_SupplierCompany        as _SupplierCompany       on  _SupplierPurchasingOrg.Supplier = _SupplierCompany.Supplier
                                                                         and _SupplierCompany.CompanyCode    = _PurchasingOrgWithCoCode.CompanyCode

{
  key    _SupplierPurchasingOrg.Supplier                                                     as Supplier,
  key    _PurchasingOrgWithCoCode.CompanyCode                                                as CompanyCode,
  key    _SupplierPurchasingOrg.PurchasingOrganization,

         //LFM1

         _SupplierPurchasingOrg.PurOrdAutoGenerationIsAllowed,
         _SupplierPurchasingOrg.PurchasingGroup,
         cast (_SupplierPurchasingOrg.PaymentTerms as farp_dzterm_po preserving type)        as SupplierPurgOrgPaymentTerms,
         _SupplierPurchasingOrg.PurchasingIsBlockedForSupplier,
         cast (_SupplierPurchasingOrg.DeletionIndicator as supplist_loevm_m preserving type) as SuplrIsDeltdPurgOrg,
         _SupplierPurchasingOrg.InvoiceIsGoodsReceiptBased,
         _SupplierPurchasingOrg.PurchaseOrderCurrency,
         _SupplierPurchasingOrg.IncotermsClassification,
         _SupplierPurchasingOrg.IncotermsTransferLocation,
         _SupplierPurchasingOrg._IncotermsClassification
}
//group-wide purchasing

union all select from I_SupplierCompany        as _SupplierCompany
  //t024e

  inner join          I_SupplierPurchasingOrg  as _SupplierPurchasingOrg   on _SupplierPurchasingOrg.Supplier = _SupplierCompany.Supplier

  inner join          I_PurchasingOrganization as _PurchasingOrgWithCoCode on  _PurchasingOrgWithCoCode.PurchasingOrganization = _SupplierPurchasingOrg.PurchasingOrganization
                                                                           and _PurchasingOrgWithCoCode.CompanyCode            = ''

  association [0..1] to P_PlntCompanyCodePurchasingOrg as _PlantCoCode on _PlantCoCode.PurchasingOrganization = _SupplierPurchasingOrg.PurchasingOrganization


{
  key    _SupplierPurchasingOrg.Supplier                                                     as Supplier,
  key    _SupplierCompany.CompanyCode                                                        as CompanyCode,
  key    _SupplierPurchasingOrg.PurchasingOrganization,

         //LFM1

         _SupplierPurchasingOrg.PurOrdAutoGenerationIsAllowed,
         _SupplierPurchasingOrg.PurchasingGroup,
         cast (_SupplierPurchasingOrg.PaymentTerms as farp_dzterm_po preserving type)        as SupplierPurgOrgPaymentTerms,
         _SupplierPurchasingOrg.PurchasingIsBlockedForSupplier,
         cast (_SupplierPurchasingOrg.DeletionIndicator as supplist_loevm_m preserving type) as SuplrIsDeltdPurgOrg,
         _SupplierPurchasingOrg.InvoiceIsGoodsReceiptBased,
         _SupplierPurchasingOrg.PurchaseOrderCurrency,
         _SupplierPurchasingOrg.IncotermsClassification,
         _SupplierPurchasingOrg.IncotermsTransferLocation,
         _SupplierPurchasingOrg._IncotermsClassification
}
where
  _PlantCoCode.PurchasingOrganization is null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCHASINGORGANIZATION",
"I_SUPPLIERCOMPANY",
"I_SUPPLIERPURCHASINGORG",
"P_PLNTCOMPANYCODEPURCHASINGORG"
],
"ASSOCIATED":
[
"I_INCOTERMSCLASSIFICATION"
],
"BASE":
[
"I_SUPPLIERPURCHASINGORG"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/