P_SupDmndOvwSTODateBasic

@ClientHandling.algorithm: #SESSION_VARIABLE
//@EndUserText.label: 'Basic View for STO Demand Date'

@VDM: {
  viewType: #BASIC
}
@VDM.private: true
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog: {
  sqlViewName: 'PSUPDMNDOVWSTO1',
  compiler.compareFilter: true
 }
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #XXL
   }
}
define view P_SupDmndOvwSTODateBasic
  as select from    ekko as ekko
    inner join      ekpo as ekpo  on  ekko.ebeln = ekpo.ebeln
    inner join      ekpv as ekpv  on  ekpo.ebeln = ekpv.ebeln
                                  and ekpo.ebelp = ekpv.ebelp
    inner join      eket as eket  on  ekpo.ebeln = eket.ebeln
                                  and ekpo.ebelp = eket.ebelp
                                  and eket.menge > 0
    left outer to many join eket as eket1 on  eket.ebeln    = eket1.ebeln
                                  and eket.ebelp            = eket1.ebelp
                                  and eket.arun_req_dlvdate = eket1.arun_req_dlvdate
{
  eket.ebeln            as PurchasingDocument,
  ekpo.ebelp            as PurchasingDocumentItem,
  eket.arun_req_dlvdate as EarliestRequestedDeliveryDate,
  eket.mbdat            as RequestedDate,
  eket1.mbdat           as ProductAvailabilityDate,
  ekpo.matnr            as Material,
  ekpo.matkl            as MaterialGroup,
  ekko.reswk            as Plant,
  ekko.ekorg            as PurchasingOrganization,
  ekko.ekgrp            as PurchasingGroup,
  ekpv.vkorg            as SalesOrganization,
  ekpv.vtweg            as DistributionChannel,
  ekpv.spart            as Division,
  eket1.mng02           as ConfdOrderQtyByMatlAvailCheck,
  eket1.menge           as ScheduleLineOrderQuantity,
  eket1.glmng            as DeliveredQuantityInBaseUnit,
  eket1.eindt           as  ConfirmedDeliveryDate,
  eket1.etenr           as ScheduleLine
}
where
        ekko.reswk      <> '' //Supplying Plant should be present

  and(
        ekpo.elikz != 'X'
  ) -- delivery completed indicator at item level
  and(
        ekpo.retpo != 'X'
  ) -- return po
  and(
        ekpo.loekz      =  ' '
  ) -- deletion indicator
  and(
        ekpo.eglkz != 'X'
  ) -- final delivery indicator
  and(
        ekpo.pstyp      =  '0'
    or  ekpo.pstyp      =  '7'
    or  ekpo.pstyp      =  '2'
  ) -- item category in purchasing doc
  and(
        ekko.bstyp      =  'F'
  ) -- purchasing doc category  , F is PO

  and(
        ekko.memorytype =  ''
  ) -- Category of Incompletess
  and(
        ekko.loekz != 'X'
  ) -- deletion indicator
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EKET",
"EKKO",
"EKPO",
"EKPV"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/