P_SupDmndAllDocSDDate

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
  viewType: #BASIC,
  private: true
}
@AccessControl: {
  authorizationCheck: #NOT_REQUIRED,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog: {
  sqlViewName: 'PSUPDMNDADSDDATE',
  compiler.compareFilter: true
 }
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XXL
   }
}
define view P_SupDmndAllDocSDDate
 as select from  I_SalesDocumentScheduleLine as ScheduleLine1
{
  ScheduleLine1.SalesDocument               as RequirementDocumentNumber,
  ScheduleLine1.SalesDocumentItem           as RequirementDocumentItem,
  ScheduleLine1.ConfdSchedLineReqdDelivDate as RequestedDate,
  ScheduleLine1.ProductAvailabilityDate     as ProductAvailabilityDate,
  ScheduleLine1._SalesDocumentItem.Material                             as Material,
  ScheduleLine1._SalesDocumentItem.Plant                                as Plant,
  case
    when ScheduleLine1._SalesDocumentItem. SDDocumentCategory = 'C' or ScheduleLine1._SalesDocumentItem.SDDocumentCategory = 'I'
      then
         (
            case
              when ScheduleLine1.OrderToBaseQuantityDnmntr != 0 or ScheduleLine1.OrderToBaseQuantityNmrtr != 0
                then cast( ScheduleLine1.ConfdOrderQtyByMatlAvailCheck * division(ScheduleLine1.OrderToBaseQuantityNmrtr,ScheduleLine1.OrderToBaseQuantityDnmntr,3) as ovr_conf_so_sl_qty )
              else cast( ScheduleLine1.ConfdOrderQtyByMatlAvailCheck as ovr_conf_so_sl_qty )
            end
         )
    when ScheduleLine1._SalesDocumentItem.SDDocumentCategory = 'G'
      then ScheduleLine1.ConfirmedRqmtQtyInBaseUnit
    else 0
  end                                       as ConfdOrderQtyByMatlAvailCheck,
  ScheduleLine1.DeliveredQuantityInBaseUnit,
  ScheduleLine1.RequestedRqmtQtyInBaseUnit,
  ScheduleLine1.ConfirmedRqmtQtyInBaseUnit,
  ScheduleLine1.ConfdSchedLineReqdDelivDate as RequestedDeliveryDate
}
where
       ( ScheduleLine1. RequestedRqmtQtyInBaseUnit > 0 or
         ScheduleLine1.ConfirmedRqmtQtyInBaseUnit > 0  or
         ScheduleLine1. PurchaseRequisition <> '' )
  and  ScheduleLine1._SalesDocumentItem.SDDocReferenceStatus != 'C'  //Reference Status != Completely processed

  and  ScheduleLine1._SalesDocumentItem.SalesDocumentItemType != 'B' //Item Type != Text item

  and  ScheduleLine1._SalesDocumentItem.DeliveryStatus != 'C'        //Delivery Status != Completely processed

  and  ScheduleLine1._SalesDocumentItem.SalesDocumentRjcnReason            = ' ' //RejectionReason = ' '

  and  ScheduleLine1._SalesDocumentItem.IsReturnsItem != 'X' //Returns != 'X'

  and(
       ScheduleLine1._SalesDocumentItem.InventorySpecialStockType          = ' '
    or ScheduleLine1._SalesDocumentItem.InventorySpecialStockType          = 'E'
  ) //Consider Orders on Hand


  and (
       ScheduleLine1._SalesDocumentItem.SDDocumentCategory  = 'C' //Document Category = Order

    or ScheduleLine1._SalesDocumentItem.SDDocumentCategory  = 'I' //Document Category = Order without Charge

    or ScheduleLine1._SalesDocumentItem.SDDocumentCategory  = 'G' //Document Category = Contract

  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESDOCUMENTITEM",
"I_SALESDOCUMENTSCHEDULELINE"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/