P_StkPostgHistCancelBasic02

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Stock posting history cancel documents part 2'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM:
      {
        viewType: #COMPOSITE,
        private: true
      }
define view entity P_StkPostgHistCancelBasic02

  with parameters
    @Environment.systemField: #SYSTEM_DATE
    P_StartDate : sydate,
    @Environment.systemField: #SYSTEM_DATE
    P_EndDate   : sydate

  as select from I_MaterialDocumentRecord as matdoc

  association [1..1] to I_MaterialDocumentRecord as matdoc_predecessor on  matdoc.ReversedMaterialDocument             =  matdoc_predecessor.MaterialDocument
                                                                       and matdoc.ReversedMaterialDocumentYear         =  matdoc_predecessor.MaterialDocumentYear
                                                                       and matdoc.ReversedMaterialDocumentItem         =  matdoc_predecessor.MaterialDocumentItem
                                                                       and matdoc.ReversedMaterialDocument             <> ''
                                                                       and matdoc.StockIdentifyingMaterial             =  matdoc_predecessor.StockIdentifyingMaterial
                                                                       and matdoc.Plant                                =  matdoc_predecessor.Plant
                                                                       and matdoc.StockIdfgStorageLocation             =  matdoc_predecessor.StockIdfgStorageLocation
                                                                       and matdoc.StockIdentifyingBatch                =  matdoc_predecessor.StockIdentifyingBatch
                                                                       and matdoc.SpecialStockIdfgSupplier             =  matdoc_predecessor.SpecialStockIdfgSupplier
                                                                       and matdoc.SpecialStockIdfgSalesOrder           =  matdoc_predecessor.SpecialStockIdfgSalesOrder
                                                                       and matdoc.SpecialStockIdfgSalesOrderItem       =  matdoc_predecessor.SpecialStockIdfgSalesOrderItem
                                                                       and matdoc.SpecialStockIdfgWBSElement           =  matdoc_predecessor.SpecialStockIdfgWBSElement
                                                                       and matdoc.SpecialStockIdfgCustomer             =  matdoc_predecessor.SpecialStockIdfgCustomer
                                                                       and matdoc.InventoryStockType                   =  matdoc_predecessor.InventoryStockType
                                                                       and matdoc.InventorySpecialStockType            =  matdoc_predecessor.InventorySpecialStockType
                                                                       and matdoc.SpecialStockIdfgStockOwner           =  matdoc_predecessor.SpecialStockIdfgStockOwner
                                                                       and matdoc.ResourceID                           =  matdoc_predecessor.ResourceID
                                                                       and matdoc_predecessor.GoodsMovementIsCancelled =  'X'

{
  key    MaterialDocument,
  key    MaterialDocumentYear,
  key    MaterialDocumentItem,

         CostEstimate,
         matdoc.CompanyCode             as CompanyCode,

         // stock fields for filter

         StockIdentifyingMaterial       as Material,
         Plant,
         StockIdfgStorageLocation       as StorageLocation,
         StockIdentifyingBatch          as Batch,
         SpecialStockIdfgSupplier       as Supplier,
         SpecialStockIdfgSalesOrder     as SalesOrder,
         SpecialStockIdfgSalesOrderItem as SalesOrderItem,
         SpecialStockIdfgWBSElement     as WBSElementInternalID,
         SpecialStockIdfgCustomer       as Customer,
         InventoryStockType,
         InventorySpecialStockType,
         SpecialStockIdfgStockOwner,
         ResourceID,
         InventoryValuationType,

         // stock quantity

         MaterialBaseUnit,
         @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
         MatlStkChangeQtyInBaseUnit,

         CompanyCodeCurrency,
         @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
         GoodsMovementStkAmtInCCCrcy,

         // reference documents

         PurchaseOrder,
         PurchaseOrderItem,
         ManufacturingOrder,
         ManufacturingOrderItem,
         DeliveryDocument,
         DeliveryDocumentItem,
         Reservation,
         ReservationItem,

         // other fields

         GoodsMovementType,
         GoodsMovementRefDocType,
         GoodsReceiptType,
         ConsumptionPosting,
         PostingDate,

         // Reversal Document

         matdoc_predecessor.PostingDate as PredecessorPostingDate
}
where
       PostingDate                    >= $parameters.P_StartDate
  and  PostingDate                    <= $parameters.P_EndDate
  and  GoodsMovementCancellationType  =  '2'
  and(
       matdoc_predecessor.PostingDate < $parameters.P_StartDate
    or matdoc_predecessor.PostingDate > $parameters.P_EndDate
  )
  and(
       MatlStkChangeQtyInBaseUnit     <> 0
    or TotalGoodsMvtAmtInCCCrcy       =  0
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIALDOCUMENTRECORD"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/