P_SrvcDocIntOrdFinData

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog:{
sqlViewName: 'PSRVCINTORDDAT',
compiler.compareFilter: true,
preserveKey: true
}
@ObjectModel: {
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #D,
     sizeCategory:   #XXL
   }
   }

@VDM: {
  viewType: #COMPOSITE,
  private:true
}

define view P_SrvcDocIntOrdFinData
  as select from           I_GLAccountLineItemSemTag
    inner join             I_UserSetGetParamForCtrlgArea on I_GLAccountLineItemSemTag.GLAccountHierarchy = I_UserSetGetParamForCtrlgArea.CtrlgStdFinStatementVersion

  association [1..1] to I_SrvcDocFUPInternalOrder as _SrvcDocIntOrdData on $projection.OrderID = _SrvcDocIntOrdData.InternalOrder

  association [0..1] to P_Calendar                as _YTDCalendar       on _YTDCalendar.CalendarDate = $session.system_date

{
          @ObjectModel.foreignKey.association: '_Ledger'
          @Environment.sql.passValue: true
  key     Ledger,
          @ObjectModel.foreignKey.association: '_SourceLedger'
  key     SourceLedger,
          @ObjectModel.foreignKey.association: '_CompanyCode'
          @Environment.sql.passValue: true
  key     CompanyCode,
          @ObjectModel.foreignKey.association: '_FiscalYear'
          @Environment.sql.passValue: true
  key     FiscalYear,
          @ObjectModel.foreignKey.association: '_JournalEntry'
  key     AccountingDocument,
  key     LedgerGLLineItem,
          @ObjectModel.foreignKey.association: '_Hierarchy'
          @Environment.sql.passValue: true
  key     GLAccountHierarchy,
          @ObjectModel.foreignKey.association: '_SemanticTag'
  key     SemanticTag,
          @Semantics.businessDate.from: true
  key     ValidityStartDate,
          @Semantics.businessDate.to: true
  key     ValidityEndDate,
          @ObjectModel.foreignKey.association: '_Order'
  key     OrderID,
  key     OrderItem,

          AccountAssignment,
          AccountAssignmentType,

          _SrvcDocIntOrdData.ServiceDocument,
          _SrvcDocIntOrdData.ServiceDocumentType,

          @Semantics.currencyCode:true
          CompanyCodeCurrency,
          @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
          RevenueAmountInCompanyCodeCrcy, //Revenue

          @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
          CostAmountInCompanyCodeCrcy, //Cost

          @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
          RecognizedMarginAmtInCCCrcy, //Profit


          case
            when _YTDCalendar.FirstDayOfYearDate <= PostingDate and PostingDate <= $session.system_date
            then RevenueAmountInCompanyCodeCrcy
            end as YTDSrvcContrRevnAmtInDC,

          case
          when _YTDCalendar.FirstDayOfYearDate <= PostingDate and PostingDate <= $session.system_date
          then CostAmountInCompanyCodeCrcy
          end   as YTDSrvcContrCostInDC,

          case
          when _YTDCalendar.FirstDayOfYearDate <= PostingDate and PostingDate <= $session.system_date
          then RecognizedMarginAmtInCCCrcy
          end   as YTDSrvcContrPrftMarginAmtInDC,

          CreationDate,
          PostingDate,
          DocumentDate,
          @Semantics.fiscal.yearVariant: true
          @ObjectModel.foreignKey.association: '_FiscalYearVariant'
          I_GLAccountLineItemSemTag.FiscalYearVariant,
          FiscalPeriod,
          FiscalQuarter,

          @ObjectModel.foreignKey.association: '_SalesOrganization'
          SalesOrganization,
          @ObjectModel.foreignKey.association: '_DistributionChannel'
          DistributionChannel,
          OrganizationDivision,
          _Ledger,
          _SourceLedger,
          _CompanyCode,
          _FiscalYear,
          _JournalEntry,
          _Hierarchy,
          _SemanticTag,
          _CompanyCodeCurrency,
          _FiscalYearVariant,
          _SalesOrganization,
          _DistributionChannel,
          _Order
}
where
       OrderID                 is not initial
  and  AccountAssignmentType   =  'OR'
  and  AccountAssignment       is not initial
  and  Ledger                  is not initial
  and  _Ledger.IsLeadingLedger =  'X'
  and(
       GLAccountHierarchy      is not initial
    or GLAccountHierarchy      <> ''
  )
  and(
       SemanticTag             =  'REC_MARGIN'
    or SemanticTag             =  'RECO_COS'
    or SemanticTag             =  'RECO_REV'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_GLACCOUNTLINEITEMSEMTAG",
"I_LEDGER",
"I_SRVCDOCFUPINTERNALORDER",
"I_USERSETGETPARAMFORCTRLGAREA",
"P_CALENDAR"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCY",
"I_DISTRIBUTIONCHANNEL",
"I_FINANCIALSTATEMENTHIERARCHY",
"I_FISCALYEARFORCOMPANYCODE",
"I_FISCALYEARVARIANT",
"I_JOURNALENTRY",
"I_LEDGER",
"I_ORDER",
"I_SALESORGANIZATION",
"I_SEMANTICTAG",
"I_SRVCDOCFUPINTERNALORDER",
"P_CALENDAR"
],
"BASE":
[
"I_GLACCOUNTLINEITEMSEMTAG"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/