P_SpecAPICustomDefinedAttrib

@AbapCatalog.sqlViewName: 'PSPCAPICUSDA'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S

@VDM.lifecycle.contract.type: #NONE
@VDM.viewType: #COMPOSITE
@VDM.private: true

define view P_SpecAPICustomDefinedAttrib
  as select from I_ProdSpecCompositionTypeAll //custom composition/properties 'C'

{
  key ProdSpecCompositionType,
  key cast('X' as char1 preserving type) as IsCustomComposition,
  key cast(' ' as char1 preserving type) as IsProperty,
      //key cast('C' as char1 preserving type) as ProdSpecAPIAttributeDefTyp,

      ProdSpecCompositionCategory,
      ProdSpecCmpstnHdrValAssgmtType,
      ProdSpecCmpstnHdrRating,
      ProdSpecCmpstnHdrValidityArea,
      ProdSpecCmpstnSpecType,
      ProdSpecCmpstnGroupSpecType
}

union select from I_SpecStdCompositionDefinition //standard compositions/properties ''

{
  key ProdSpecCompositionType,
  key cast(' ' as char1 preserving type) as IsCustomComposition,
  key cast(' ' as char1 preserving type) as IsProperty,
      //key cast('' as char1 preserving type ) as ProdSpecAPIAttributeDefTyp,

      ' '                                as ProdSpecCompositionCategory,
      ProdSpecCmpstnHdrValAssgmtType,
      ProdSpecCmpstnHdrRating,
      ProdSpecCmpstnHdrValidityArea,
      ProdSpecCmpstnSpecType,
      ProdSpecCmpstnGroupSpecType

}

union select from I_SpecCstmPropertyDefinition //property "composition" 'P'

{
  key ProdSpecPrptyDefID                 as ProdSpecCompositionType,
  key cast(' ' as char1 preserving type) as IsCustomComposition,
  key cast('X' as char1 preserving type) as IsProperty,
      //key cast('P' as char1 preserving type) as ProdSpecAPIAttributeDefTyp,

      ' '                                as ProdSpecCompositionCategory,
      ProdSpecPrptyDefValAssgmtType      as ProdSpecCmpstnHdrValAssgmtType,
      ProdSpecPrptyDefRating             as ProdSpecCmpstnHdrRating,
      ProdSpecPrptyDefValidityArea       as ProdSpecCmpstnHdrValidityArea,
      ' '                                as ProdSpecCmpstnSpecType,
      ' '                                as ProdSpecCmpstnGroupSpecType
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PRODSPECCOMPOSITIONTYPEALL",
"I_SPECCSTMPROPERTYDEFINITION",
"I_SPECSTDCOMPOSITIONDEFINITION"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/