P_SlsOrdReqBPOrgAddr

//@AbapCatalog.sqlViewName: 'PSLSORDREQBPORG'

//@ClientHandling.algorithm: #SESSION_VARIABLE

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Organization and Address Info'
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@VDM.private: true
@AccessControl.personalData.blocking: #REQUIRED

define view entity P_SlsOrdReqBPOrgAddr as select from I_BusinessPartnerCustomer as BPCustomer
  inner to many join I_BusinessPartnerAddress as BPAddress  on BPCustomer.BusinessPartner = BPAddress.BusinessPartner
  inner to one  join I_OrganizationAddress    as OrgAddress on OrgAddress.AddressID = BPAddress.AddressNumber
  inner to one  join I_Businesspartneraddressusage as AddressUsage on AddressUsage.BusinessPartner = BPAddress.BusinessPartner
  left outer to one join I_BPAddrTypeAssignment as BPAddrTypeAssignment on BPAddrTypeAssignment.AddressType = AddressUsage.AddressUsage
  left outer to one join I_BPAddressDetermination as BPAddressDetermination on BPAddressDetermination.BPAddrDeterminationTransaction = BPAddrTypeAssignment.BPAddrDeterminationTransaction
{
 key  BPAddress.AddressNumber                                             as BPAddressID,
      BPCustomer.Customer                                                 as Customer,
      BPCustomer.BusinessPartner                                          as BusinessPartner,
      BPCustomer.AddressID                                                as AddressID,
      
      
      //Country,Region,City,Street...

      OrgAddress.CityNumber,
      OrgAddress.CityName,
      OrgAddress.DistrictName,
      OrgAddress.VillageName,
      OrgAddress.Street,
      OrgAddress.StreetName,
      OrgAddress.Building,
      OrgAddress.Floor,
      OrgAddress.Country,
      OrgAddress.Region,
      
      // Address

      OrgAddress.AddresseeName1,
      OrgAddress.AddresseeName2,
      OrgAddress.AddresseeName3,
      OrgAddress.AddresseeName4,
      
      //Code

      OrgAddress.RoomNumber,
      OrgAddress.HouseNumber,
      OrgAddress.HouseNumberSupplementText,
      OrgAddress.PostalCode,
      OrgAddress.CompanyPostalCode,
      
      //Contact Info

      OrgAddress._EmailAddress.EmailAddress                                  as EmailAddress1,
      OrgAddress._CurrentDfltEmailAddress.EmailAddress                       as EmailAddress2,
      OrgAddress._FaxNumber.FaxAreaCodeSubscriberNumber                      as FaxNumber1,
      OrgAddress._CurrentDfltFaxNumber.FaxAreaCodeSubscriberNumber           as FaxNumber2,
      OrgAddress._PhoneNumber.PhoneAreaCodeSubscriberNumber                  as TelePhoneNumber1,
      OrgAddress._CurrentDfltLandlinePhoneNmbr.PhoneAreaCodeSubscriberNumber as TelePhoneNumber2,
      OrgAddress._CurrentDfltMobilePhoneNumber.PhoneAreaCodeSubscriberNumber as TelePhoneNumber3,
      
      //DCL

      BPCustomer.IsBusinessPurposeCompleted                                  as CusIsBusinessPurposeCompleted,
      BPCustomer.CustomerAccountGroup                                        as CustomerAccountGroup,
      BPCustomer.AuthorizationGroup                                          as AuthorizationGroup,
      BPCustomer.AuthorizationGroup                                          as CusAuthorizationGroup,
      BPCustomer.DataControllerSet                                           as DataControllerSet,
      BPCustomer.DataController1                                             as DataController1,
      BPCustomer.DataController2                                             as DataController2,
      BPCustomer.DataController3                                             as DataController3,
      BPCustomer.DataController4                                             as DataController4,
      BPCustomer.DataController5                                             as DataController5,
      BPCustomer.DataController6                                             as DataController6,
      BPCustomer.DataController7                                             as DataController7,
      BPCustomer.DataController8                                             as DataController8,
      BPCustomer.DataController9                                             as DataController9,
      BPCustomer.DataController10                                            as DataController10,
      BPAddress._BusinessPartner.IsBusinessPurposeCompleted                  as BPIsBusinessPurposeCompleted,
      BPCustomer._CustomerToBusinessPartner._BusinessPartner.AuthorizationGroup         as BPAuthorizationGroup,
      BPCustomer._CustomerToBusinessPartner
}
where ( BPCustomer.Customer is not initial or BPCustomer.BusinessPartner is not initial ) and BPAddressDetermination.DataIsProtected is initial
  and BPCustomer.DeletionIndicator <> 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRCURDEFAULTEMAILADDRESS",
"I_ADDRCURDEFAULTFAXNUMBER",
"I_ADDRCURDFLTLANDLINEPHONENMBR",
"I_ADDRCURDFLTMOBILEPHONENUMBER",
"I_ADDRESSEMAILADDRESS_2",
"I_ADDRESSFAXNUMBER_2",
"I_ADDRESSPHONENUMBER_2",
"I_BPADDRESSDETERMINATION",
"I_BPADDRTYPEASSIGNMENT",
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNERADDRESS",
"I_BUSINESSPARTNERADDRESSUSAGE",
"I_BUSINESSPARTNERCUSTOMER",
"I_CUSTOMER_TO_BUSINESSPARTNER",
"I_ORGANIZATIONADDRESS"
],
"ASSOCIATED":
[
"I_CUSTOMER_TO_BUSINESSPARTNER"
],
"BASE":
[
"I_BUSINESSPARTNERCUSTOMER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/