P_SlsOrdProcFlow41

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

@VDM.private: true
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.sqlViewName: 'PSLSORDPROCF41'
@AbapCatalog.preserveKey:true 

define view P_SlsOrdProcFlow41
  as select distinct from P_SlsOrdProcFlow30 as Level3
  inner join              I_AccountingDocument      as AccountingDocument
  on   Level3.Level3Document                    = AccountingDocument.OriginalReferenceDocument
  and  AccountingDocument.ReferenceDocumentType = 'VBRK'    
  
{
      //Key

  key Level3Document,
  key AccountingDocument.AccountingDocument,
      
      //SalesOrder

  key SalesOrder,
      SalesOrderType,
      
      //AccountingDocument additional keys

      AccountingDocument.CompanyCode,
      AccountingDocument.FiscalYear,
      

      //Category

      Level3DocumentCategory,

      //Organization

      SalesOrganization,
      DistributionChannel,
      OrganizationDivision

}
where Level3DocumentCategory = 'M'  --> Invoice      
or    Level3DocumentCategory = '5'  --> Intercompany Invoice 
or    Level3DocumentCategory = 'O'  --> Credit Memo
or    Level3DocumentCategory = '6'  --> Intercompany Credit Memo
or    Level3DocumentCategory = 'P'  --> Debit Memo                                                                             
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ACCOUNTINGDOCUMENT",
"P_SLSORDPROCFLOW30"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/