P_SlsDocFlfllmntAnalyzerIss1

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

@VDM.private: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'PSOFANALYSISI1'

define view P_SlsDocFlfllmntAnalyzerIss1

as select from I_SalesOrderFlfmtIssueBasic
as SalesOrderFulfillmentIssue    
{ 
   //SalesOrder

   key SalesOrder,
   key IssueCategory,
   
   SalesOrderType,
   
   SalesOrganization,
   DistributionChannel,
   OrganizationDivision,     
   
    //Misc

    RequestedDeliveryDate,
    --OverallSDProcessStatus, --AT14.2.2020 no longer needed after vbap enhancement
    SalesDocumentDate,
    SalesGroup,
    SalesOffice,
    SoldToParty,
   -- PurchaseOrderByCustomer, --AT11.08.2020 VBKD-BSTKD no longer provided by issues (no true hdr attribute & too expensive)
      
   min(DueDays) as DueDays,
   
   sum( NmbrOfIssuesInOrder)    as NmbrOfIssuesInOrder,
   
   cast(
   case 
     when IssueCategory = '10_SO' then min(DueDays) 
     else 1
   end  
   as due_days) as DueDaysInOrder,
    
   sum( NmbrOfIssuesInDelivery) as NmbrOfIssuesInDelivery,
   
   cast(
   case 
     when IssueCategory = '20_DE' then min(DueDays) 
     else 1
   end  
   as due_days) as DueDaysInDelivery,   
   
   sum( NmbrOfIssuesInInvoice) as NmbrOfIssuesInInvoice,
   
   cast(
   case 
     when IssueCategory = '30_IN' then min(DueDays) 
     else 1
   end  
   as due_days) as DueDaysInInvoice,    
   
   sum( NmbrOfIssuesInSupply) as NmbrOfIssuesInSupply,
   
   cast(
   case 
     when IssueCategory = '15_SU' then min(DueDays) 
     else 1
   end  
   as due_days) as DueDaysInSupply,      
   
   sum(NmbrOfAllIssues) as NmbrOfAllIssues 
 }
 
 where IsPotentialFutureIssue = '0'
 group by SalesOrder,
          IssueCategory,
          SalesOrderType,
          SalesOrganization,
          DistributionChannel,          
          OrganizationDivision,
          RequestedDeliveryDate,
          --OverallSDProcessStatus, --AT14.2.2020 no longer needed after vbap enhancement
          SalesDocumentDate,
          SalesGroup,
          SalesOffice,
          SoldToParty --,
          --PurchaseOrderByCustomer     --AT11.08.2020 VBKD-BSTKD no longer provided by issues (no true hdr attribute & too expensive)      
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESORDERFLFMTISSUEBASIC"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/