P_ShrtTrmCshPosAccWithProfile

@AbapCatalog.sqlViewName: 'PSTCPACCPROF'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #COMPOSITE
@VDM.private: true
define view P_ShrtTrmCshPosAccWithProfile
  with parameters
    p_CashPositionProfile : fclm_cp_profile_name
  as select from P_ShrtTrmCshPosAccFilter(p_SAPClient: $session.client, p_CashPositionProfile: $parameters.p_CashPositionProfile) as account
    cross join   I_CashPositionProfile                                                                                            as prof
{
  key prof.CashPositionProfile,
  key account.BankAccountInternalID,
      account.BankAccountCurrency,
      account.BankAccountNumber,
      account.BankAccountType,
      account.BankCountry,
      account.CompanyCode,
      account.Bank,
      account.Country,
      account.RiskPartnerNo,
      prof.CashPositionHierLevel1,
      prof.CashPositionHierLevel2,
      prof.CashPositionHierLevel3,
      prof.CashPositionHierSource,
      prof.CashPositionRootNode,
      prof.CashPositionRootNodeIsNeeded,

      case when prof.CashPositionHierLevel1 = '01' then account.CompanyCode
      when prof.CashPositionHierLevel1 = '02' then account.BankCountry
      when prof.CashPositionHierLevel1 = '03' then concat( account.BankCountry, account.Bank )
      when prof.CashPositionHierLevel1 = '04' then account.BankAccountCurrency
      when prof.CashPositionHierLevel1 = '05' then account.Country
      when prof.CashPositionHierLevel1 = '06' then account.RiskPartnerNo
      else ''
      end as GroupValue1,

      case when prof.CashPositionHierLevel2 = '01' then account.CompanyCode
      when prof.CashPositionHierLevel2 = '02' then account.BankCountry
      when prof.CashPositionHierLevel2 = '03' then concat( account.BankCountry, account.Bank )
      when prof.CashPositionHierLevel2 = '04' then account.BankAccountCurrency
      when prof.CashPositionHierLevel2 = '05' then account.Country
      when prof.CashPositionHierLevel2 = '06' then account.RiskPartnerNo
      else ''
      end as GroupValue2,

      case when prof.CashPositionHierLevel3 = '01' then account.CompanyCode
      when prof.CashPositionHierLevel3 = '02' then account.BankCountry
      when prof.CashPositionHierLevel3 = '03' then concat( account.BankCountry, account.Bank )
      when prof.CashPositionHierLevel3 = '04' then account.BankAccountCurrency
      when prof.CashPositionHierLevel3 = '05' then account.Country
      when prof.CashPositionHierLevel3 = '06' then account.RiskPartnerNo
      else ''
      end as GroupValue3
}
where
  prof.CashPositionProfile = $parameters.p_CashPositionProfile
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CASHPOSITIONPROFILE"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/