P_ShopFloorItemComponents

@AbapCatalog.sqlViewName: 'PMPESFICMPS'
@AbapCatalog.compiler.compareFilter:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.dbHints: [{dbSystem: #HDB, hint: 'USE_HEX_PLAN'}]
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE
@VDM.private: true
define view P_ShopFloorItemComponents
  as select from            I_MfgOrderComponentAssembly   as MfgOrderComponentAssembly
    inner join              I_MatlPlntCompAssembleControl as MfgOrderProductPlant        on  MfgOrderProductPlant.Product = MfgOrderComponentAssembly.Material
                                                                                         and MfgOrderProductPlant.Plant   = MfgOrderComponentAssembly.Plant
    left outer to one join  I_OpActyNtwkInstanceBasic     as OpActyNtwkInstance          on OpActyNtwkInstance.OpActyNtwkInstance = MfgOrderComponentAssembly.OpActyNtwkInstance
    left outer to one join  I_OpActyComponentAssignment   as OpActyComponentAssignment   on  OpActyComponentAssignment.OpActyNtwkInstance = MfgOrderComponentAssembly.OpActyNtwkInstance
                                                                                         and OpActyComponentAssignment.OpActyNtwkElement  = MfgOrderComponentAssembly.OpActyNtwkElement
                                                                                         and OpActyComponentAssignment.Reservation        = MfgOrderComponentAssembly.Reservation
                                                                                         and OpActyComponentAssignment.ReservationItem    = MfgOrderComponentAssembly.ReservationItem
                                                                                         and OpActyComponentAssignment.RecordType         = MfgOrderComponentAssembly.RecordType
    left outer to many join I_MfgOrderCompInstceAssembly  as MfgOrderCompInstceAssembly  on  MfgOrderCompInstceAssembly.AssemblyDocument     = MfgOrderComponentAssembly.AssemblyDocument
                                                                                         and MfgOrderCompInstceAssembly.AssemblyDocumentItem = MfgOrderComponentAssembly.AssemblyDocumentItem
                                                                                         and MfgOrderCompInstceAssembly.IsReversed           = ''
                                                                                         and MfgOrderCompInstceAssembly.IsReversal           = ''
    left outer to one join  I_OpActyCompInstceAssignment  as OpActyCompInstceAssignment  on  OpActyCompInstceAssignment.Reservation               = MfgOrderComponentAssembly.Reservation
                                                                                         and OpActyCompInstceAssignment.ReservationItem           = MfgOrderComponentAssembly.ReservationItem
                                                                                         and OpActyCompInstceAssignment.RecordType                = MfgOrderComponentAssembly.RecordType
                                                                                         and OpActyCompInstceAssignment.OpActyNtwkInstance        = MfgOrderComponentAssembly.OpActyNtwkInstance
                                                                                         and OpActyCompInstceAssignment.OpActyNtwkElement         = MfgOrderComponentAssembly.OpActyNtwkElement
                                                                                         and OpActyCompInstceAssignment.OriglDgtlMockUpCharcsUUID = MfgOrderCompInstceAssembly.OriglDgtlMockUpCharcsUUID
    left outer to one join  I_InstanceReferenceDesignator as InstanceReferenceDesignator on InstanceReferenceDesignator.DgtlMockUpCharcsUUID = OpActyCompInstceAssignment.DgtlMockUpCharcsUUID
    left outer to one join  I_ShopFloorItem               as ShopFloorItem               on ShopFloorItem.ShopFloorItem = MfgOrderComponentAssembly.ShopFloorItem
    left outer to one join  I_ShopFloorItem               as AssemblyShopFloorItem       on AssemblyShopFloorItem.ShopFloorItem = MfgOrderComponentAssembly.AssemblyShopFloorItem
    left outer to one join  I_Equipment                   as Equipment                   on  Equipment.Material     = MfgOrderComponentAssembly.Material
                                                                                         and Equipment.SerialNumber = ShopFloorItem.SerialNumber
    left outer to one join  I_BatchDistinct               as BatchDistinct               on  (
                      MfgOrderComponentAssembly.Plant                                                                           = BatchDistinct.Plant
                      or BatchDistinct.Plant                                                                                    = '    '
                    )
                                                                                         and MfgOrderComponentAssembly.Material = BatchDistinct.Material
                                                                                         and MfgOrderComponentAssembly.Batch    = BatchDistinct.Batch
    left outer to one join  I_OrderComponent              as OrderComponent              on  OrderComponent.Reservation     = MfgOrderComponentAssembly.Reservation
                                                                                         and OrderComponent.ReservationItem = MfgOrderComponentAssembly.ReservationItem
                                                                                         and OrderComponent.RecordType      = MfgOrderComponentAssembly.RecordType
    left outer to one join  I_UnitizedMaterial            as UnitizedMaterial            on UnitizedMaterial.Material = MfgOrderComponentAssembly.Material
  association [0..1] to I_Plant                     as _Plant                     on  $projection.Plant = _Plant.Plant
  association [0..1] to I_ProductPlant              as _ProductPlant              on  $projection.Material = _ProductPlant.Product
                                                                                  and $projection.Plant    = _ProductPlant.Plant
  association [1..1] to I_OpActyNtwkInstance        as _OpActyNtwkInstance        on  $projection.OpActyNtwkInstance = _OpActyNtwkInstance.OpActyNtwkInstance
  association [1..1] to I_OperationActivityInstance as _OperationActivityInstance on  $projection.OpActyNtwkInstance = _OperationActivityInstance.OpActyNtwkInstance
                                                                                  and $projection.OpActyNtwkElement  = _OperationActivityInstance.OpActyNtwkElement
  association [1..1] to I_MatlCompAssembleControl   as _MatlCompAssembleControl   on  $projection.MatlCompAssembleControl = _MatlCompAssembleControl.MatlCompAssembleControl
{
      @ObjectModel.foreignKey.association: '_Reservation'
  key MfgOrderComponentAssembly.Reservation                                                                                 as Reservation,
  key MfgOrderComponentAssembly.ReservationItem                                                                             as ReservationItem,
  key MfgOrderComponentAssembly.RecordType                                                                                  as RecordType,
      @ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
  key MfgOrderComponentAssembly.OpActyNtwkInstance                                                                          as OpActyNtwkInstance,
      @ObjectModel.foreignKey.association: '_OperationActivityInstance'
  key MfgOrderComponentAssembly.OpActyNtwkElement                                                                           as OpActyNtwkElement,
  key MfgOrderComponentAssembly.AssemblyShopFloorItem                                                                       as AssemblyShopFloorItem,
  key MfgOrderComponentAssembly.ShopFloorItem                                                                               as ShopFloorItem,
  key MfgOrderComponentAssembly.Batch                                                                                       as Batch,
  key MfgOrderComponentAssembly.Material                                                                                    as Material,
      @ObjectModel.foreignKey.association: '_Plant'
  key MfgOrderComponentAssembly.Plant                                                                                       as Plant,
  key MfgOrderCompInstceAssembly.OriglDgtlMockUpCharcsUUID                                                                  as OriglDgtlMockUpCharcsUUID,
  key MfgOrderComponentAssembly.CreationDateTime                                                                            as CreationDateTime,
      MfgOrderComponentAssembly._Material._Text[1: Language=$session.system_language].MaterialName                          as MaterialName,
      MfgOrderComponentAssembly.StorageLocation                                                                             as StorageLocation,
      OpActyCompInstceAssignment.DgtlMockUpCharcsUUID                                                                       as DgtlMockUpCharcsUUID,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      cast(round(fltp_to_dec( OpActyComponentAssignment.MfgOrderComponentUsageNetQty as abap.dec(13,4) ), 3)
        as co_menge )                                                                                                       as RequiredQuantity,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      cast( case when UnitizedMaterial.ComplexAssemblyType = '1' then 1
                 when UnitizedMaterial.ComplexAssemblyType = '2' then 1
            else cast(case OrderComponent.MaterialCompIsVariableSized
              when 'X' then MfgOrderComponentAssembly.QuantityInEntryUnit
              else MfgOrderComponentAssembly.MaterialComponentQuantity end as kmpmg preserving type)
            end as kmpmg preserving type)                                                                                   as MaterialComponentQuantity,
      @Semantics.unitOfMeasure: true
      cast( case when UnitizedMaterial.ComplexAssemblyType = '1'
                 then UnitizedMaterial.MaterialBaseUnit
                 when UnitizedMaterial.ComplexAssemblyType = '2'
                 then UnitizedMaterial.MaterialBaseUnit
            else MfgOrderComponentAssembly.MaterialBaseUnit end as meins preserving type )                                  as MaterialBaseUnit,
      @Semantics.unitOfMeasure: true
      MfgOrderComponentAssembly.EntryUnit                                                                                   as EntryUnit,
      //      cast( case when ShopFloorItem.ManufacturingOrder is not initial

      //            then ShopFloorItem.ManufacturingOrder

      //            else OpActyNtwkInstance.ManufacturingOrder

      //            end as co_aufnr preserving type )                                                                               as ManufacturingOrder,

      cast( ShopFloorItem.ManufacturingOrder as mpe_part_manufacturing_order preserving type )                              as ManufacturingOrder,
      cast( case MfgOrderComponentAssembly.OpActyNtwkInstance
        when 0 then AssemblyShopFloorItem.ManufacturingOrder
        else OpActyNtwkInstance.ManufacturingOrder
        end as mpe_part_consuming_order preserving type )                                                                   as ConsumingOrder,
      cast( case when ShopFloorItem._MfgOrder.EffectivityParameterVariant is not initial
                 then ShopFloorItem._MfgOrder.EffectivityParameterVariant
            else OpActyNtwkInstance._MfgOrder.EffectivityParameterVariant
            end as techs preserving type )                                                                                  as EffectivityParameterVariant,
      cast(case when ShopFloorItem._MfgOrder.WBSElementInternalID <> '00000000'
                then ShopFloorItem._MfgOrder.WBSElementInternalID
           else OpActyNtwkInstance._MfgOrder.WBSElementInternalID
         end as ps_s4_pspnr preserving type)                                                                                as WBSElementInternalID,
      cast( case when ShopFloorItem._MfgOrder.ProductConfiguration <> '000000000000000000'
                 then ShopFloorItem._MfgOrder.ProductConfiguration
            else OpActyNtwkInstance._MfgOrder.ProductConfiguration
            end as product_configuration preserving type )                                                                  as ProductConfiguration,
      OrderComponent.OrderInternalID                                                                                        as OrderInternalID,
      OrderComponent.OrderOperationInternalID                                                                               as OrderOperationInternalID,
      OpActyNtwkInstance.OperationActivityNetwork                                                                           as OperationActivityNetwork,
      OpActyNtwkInstance.OpActyNtwkVersionCounter                                                                           as OpActyNtwkVersionCounter,
      MfgOrderComponentAssembly._ShopFloorItem.SerialNumber                                                                 as SerialNumber,
      Equipment.Equipment                                                                                                   as Equipment,
      Equipment.ManufacturerSerialNumber                                                                                    as ManufacturerSerialNumber,
      BatchDistinct.BatchBySupplier                                                                                         as BatchBySupplier,
      cast(case when InstanceReferenceDesignator.ReferenceDesignatorValue
            is not null or  InstanceReferenceDesignator.ReferenceDesignatorValue <> ''
            then InstanceReferenceDesignator.ReferenceDesignatorValue
            else bintohex( OpActyCompInstceAssignment.OriglDgtlMockUpCharcsUUID )
           end as vmp_ref_des)                                                                                              as ReferenceDesignatorValue,
      cast('' as mpe_comp_is_for_backflush preserving type)                                                                 as MatlCompIsMarkedForBackflush,
      cast('' as schgt preserving type )                                                                                    as IsBulkMaterialComponent,
      MfgOrderComponentAssembly.DebitCreditCode                                                                             as DebitCreditCode,
      MfgOrderProductPlant.MatlCompAssembleControl                                                                          as MatlCompAssembleControl,
      MfgOrderProductPlant._MatlCompAssembleControl._Text[1: Language=$session.system_language].MatlCompAssembleControlName as MatlCompAssembleControlName,
      OpActyComponentAssignment.RelatedOpActyNtwkElement                                                                    as RelatedOpActyNtwkElement,
      OpActyComponentAssignment.RelatedOpActyNtwkInstance                                                                   as RelatedOpActyNtwkInstance,
      OpActyComponentAssignment.RelatedRecordType                                                                           as RelatedRecordType,
      OpActyComponentAssignment.RelatedReservation                                                                          as RelatedReservation,
      OpActyComponentAssignment.RelatedReservationItem                                                                      as RelatedReservationItem,
      OpActyComponentAssignment.LeadingOpActyNtwkElement                                                                    as LeadingOpActyNtwkElement,
      OpActyComponentAssignment.LeadingOpActyNtwkInstance                                                                   as LeadingOpActyNtwkInstance,
      OpActyComponentAssignment.LeadingReservationRecordType                                                                as LeadingReservationRecordType,
      OpActyComponentAssignment.LeadingReservation                                                                          as LeadingReservation,
      OpActyComponentAssignment.LeadingReservationItem                                                                      as LeadingReservationItem,
      OpActyComponentAssignment.MatlCompInstceAssyIsRequired                                                                as MatlCompInstceAssyIsRequired,
      OrderComponent.BillOfMaterialCategory                                                                                 as BillOfMaterialCategory,
      cast( OrderComponent.BillOfMaterialInternalID as mpe_exec_stnum preserving type )                                     as BillOfMaterialInternalID,
      OrderComponent.BOMItem                                                                                                as BOMItem,
      OrderComponent.BOMItemInternalChangeCount                                                                             as BOMItemInternalChangeCount,
      OrderComponent.BillOfMaterialVariant                                                                                  as BillOfMaterialVariant,
      OrderComponent.BillOfMaterialVersion                                                                                  as BillOfMaterialVersion,
      cast('' as stlan preserving type )                                                                                    as BillOfMaterialVariantUsage,
      OrderComponent.BOMItemCategory                                                                                        as BOMItemCategory,
      OrderComponent._BOMItemCategory._ItemCategoryT[1: Language=$session.system_language].BillOfMaterialItemCategoryDesc   as BillOfMaterialItemCategoryDesc,
      OrderComponent.InheritedBOMItemNode                                                                                   as InheritedBOMItemNode,
      OrderComponent._BillOfMaterialItem.BillOfMaterialItemUUID                                                             as BillOfMaterialItemUUID,
      OrderComponent.BillOfMaterialItemNumber                                                                               as BillOfMaterialItemNumber,
      -- Variable-Size Item Fields
      OrderComponent.MaterialCompIsVariableSized                                                                            as MaterialCompIsVariableSized,
      OrderComponent.FormulaKey                                                                                             as FormulaKey,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      OrderComponent.VariableSizeDimension1                                                                                 as VariableSizeDimension1,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      OrderComponent.VariableSizeDimension2                                                                                 as VariableSizeDimension2,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      OrderComponent.VariableSizeDimension3                                                                                 as VariableSizeDimension3,
      @Semantics.unitOfMeasure: true
      OrderComponent.VariableSizeDimensionUnit                                                                              as VariableSizeDimensionUnit,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeComponentUnit'
      OrderComponent.VariableSizeComponentQuantity                                                                          as VariableSizeComponentQuantity,
      @Semantics.unitOfMeasure: true
      OrderComponent.VariableSizeComponentUnit                                                                              as VariableSizeComponentUnit,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      cast(case OrderComponent.MaterialCompIsVariableSized
        when 'X' then cast(round(fltp_to_dec( OpActyComponentAssignment.MfgOrderComponentUsageNetQty as abap.dec(13,4) ), 3)
        as co_menge ) * OrderComponent.VariableSizeComponentQuantity
        else cast(round(fltp_to_dec( OpActyComponentAssignment.MfgOrderComponentUsageNetQty as abap.dec(13,4) ), 3)
        as co_menge )
      end as mpe_planned_qty_in_base_unit)                                                                                  as RequiredQuantityInBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      cast(MfgOrderComponentAssembly.MaterialComponentQuantity as mpe_consumed_qty_in_base_unit preserving type)            as ResvnItmWithdrawnQtyInBaseUnit,
      ShopFloorItem.ShopFloorItemProductionStatus                                                                           as ShopFloorItemProductionStatus,
      UnitizedMaterial.ComplexAssemblyType                                                                                  as ComplexAssemblyType,

      ---Associations
      MfgOrderComponentAssembly._Reservation,
      MfgOrderComponentAssembly._Material,
      _Plant,
      _ProductPlant,
      _OpActyNtwkInstance,
      _OperationActivityInstance,
      _MatlCompAssembleControl,
      OrderComponent._OrderOperation,
      OrderComponent._OrderInternalID

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BATCHDISTINCT",
"I_BILLOFMATERIALITEMBASIC",
"I_BILLOFMATERIALITEMCATEGORY",
"I_BOMITEMCATEGORYTEXT",
"I_EQUIPMENT",
"I_INSTANCEREFERENCEDESIGNATOR",
"I_MATERIAL",
"I_MATERIALTEXT",
"I_MATLCOMPASSEMBLECONTROL",
"I_MATLCOMPASSEMBLECONTROLTEXT",
"I_MATLPLNTCOMPASSEMBLECONTROL",
"I_MFGORDER",
"I_MFGORDERCOMPINSTCEASSEMBLY",
"I_MFGORDERCOMPONENTASSEMBLY",
"I_OPACTYCOMPINSTCEASSIGNMENT",
"I_OPACTYCOMPONENTASSIGNMENT",
"I_OPACTYNTWKINSTANCEBASIC",
"I_ORDERCOMPONENT",
"I_SHOPFLOORITEM",
"I_UNITIZEDMATERIAL"
],
"ASSOCIATED":
[
"I_MATERIAL",
"I_MATLCOMPASSEMBLECONTROL",
"I_OPACTYNTWKINSTANCE",
"I_OPERATIONACTIVITYINSTANCE",
"I_ORDERINTERNALID",
"I_ORDEROPERATION",
"I_PLANT",
"I_PRODUCTPLANT",
"I_RESERVATIONDOCUMENTHEADER"
],
"BASE":
[
"I_MFGORDERCOMPONENTASSEMBLY",
"I_ORDERCOMPONENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/