P_ServiceContractItemDateConv

@AbapCatalog.sqlViewName: 'PSRVCONTRITEMDAT'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM: {
   private:true,
   viewType: #COMPOSITE
}
@AccessControl: {
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #D,
     sizeCategory:   #XXL
   }
   }

define view P_ServiceContractItemDateConv
  as select from I_ServiceDocumentItemEnhcd

{

      @ObjectModel.foreignKey.association: '_ServiceObjType'
  key ServiceObjectType,
      @ObjectModel.foreignKey.association: '_ServiceDocument'
  key ServiceDocument,
      @ObjectModel.text.element: ['ServiceDocumentItemDescription']
  key ServiceDocumentItem,
      ServiceDocumentItemUUID,
      ServiceDocumentItemCharUUID,
      ServiceDocumentItemObjectType,
      @Semantics.text: true
      ServiceDocumentItemDescription,
      @ObjectModel.foreignKey.association: '_ServiceDocumentType'
      ServiceDocumentType,
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      @Semantics.currencyCode:true
      TransactionCurrency,
      tstmp_to_dats( ServiceContrItemStartDateTime, $session.user_timezone, $session.client, 'NULL' ) as ServiceContractItemStartDate,
      tstmp_to_dats( ServiceContrItemEndDateTime, $session.user_timezone, $session.client,'NULL' )    as ServiceContractItemEndDate,
      PurchaseOrderByCustomer,
      @ObjectModel.foreignKey.association: '_ServiceTeam'
      ServiceTeam,
      @ObjectModel.foreignKey.association: '_RespEmployee'
      ResponsibleEmployee,
      @ObjectModel.foreignKey.association: '_ServiceEmployee'
      ServiceEmployee,
      @ObjectModel.foreignKey.association: '_ContactPerson'
      ContactPerson,
      @ObjectModel.foreignKey.association: '_ShipToParty'
      ShipToParty,
      RefBusinessSolutionOrder,
      RefBusinessSolutionOrderItem,

      @ObjectModel.foreignKey.association: '_Product'
      Product,

      RefInHouseRepairIsExisting,
      ServiceDocumentItemIsQuotation,

      @ObjectModel.foreignKey.association: '_SrvcDocItmLifecycleStatus'
      ServiceDocumentItemStatus,

      @ObjectModel.foreignKey.association: '_ServiceDocumentIsOpen'
      ServiceDocumentItemIsOpen,

      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocumentItemNetAmount,

      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrganization,

      @ObjectModel.foreignKey.association: '_SalesOffice'
      SalesOffice,

      @ObjectModel.foreignKey.association: '_SalesGroup'
      SalesGroup,

      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,

      @ObjectModel.foreignKey.association: '_Division'
      Division,

      @ObjectModel.foreignKey.association: '_SoldToParty'
      SoldToParty,

      @ObjectModel.foreignKey.association: '_ServiceOrganizationOrgUnit_2'
      ServiceOrganization,

      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit_2'
      SalesOrganizationOrgUnitID,

      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit_2'
      SalesOfficeOrgUnitID,

      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit_2'
      SalesGroupOrgUnitID,

      /* Associations */
      _RespEmployee,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_SrvcDocItmLifecycleStatus'
      _ServiceDocItemStatus,
      _SrvcDocItmLifecycleStatus,
      _ServiceDocumentType,
      //     _ServiceContract,

      //      _CurrentDate,

      _ServiceDocument,
      _ServiceObjType,
      _TransactionCurrency,
      _SalesOrganization,
      _SalesOffice,
      _SalesGroup,
      _Division,
      _DistributionChannel,
      _SoldToParty,
      _Product,
      _ServiceDocItemRefObj,
      _ServiceTeam,
      _ServiceEmployee,
      _ContactPerson,
      _ServiceDocumentIsOpen,
      _ServiceOrganizationOrgUnit_2,
      _SalesOrganizationOrgUnit_2,
      _SalesOfficeOrgUnit_2,
      _SalesGroupOrgUnit_2,
      _ShipToParty

}
where
      ServiceObjectType          = 'BUS2000112'
  and ServiceDocumentItemIsQuotation != 'X'
  and RefInHouseRepairIsExisting is initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENTITEMENHCD"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CURRENCY",
"I_CUSTMGMTBUSOBJTYPE",
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_PRODUCT",
"I_SALESGROUP",
"I_SALESOFFICE",
"I_SALESORGANIZATION",
"I_SERVICEDOCOPENSTATUS",
"I_SERVICEDOCUMENTENHCD",
"I_SERVICEDOCUMENTREFOBJECT",
"I_SERVICEDOCUMENTSTATUS",
"I_SERVICEDOCUMENTTYPE",
"I_SRVCDOCLIFECYCLESTATUS",
"I_SRVCMGMTORGANIZATIONUNIT"
],
"BASE":
[
"I_SERVICEDOCUMENTITEMENHCD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/