P_SecClassIntCond

@AbapCatalog.sqlViewName: 'PSECCLASSINTCOND'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@VDM.private:true
define view P_SecClassIntCond
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate : vdm_v_key_date
  as select from vtbfha  as FinancialTransaction
    inner join   vzzkopo as TransactionCondition on  FinancialTransaction.sanlf = TransactionCondition.sanlf
                                                 and FinancialTransaction.ranl  = TransactionCondition.rkey1
    inner join   tzk01   as ConditionType        on  FinancialTransaction.rantyp = ConditionType.rantyp
                                                 and TransactionCondition.skoart = ConditionType.skoart
{
  key FinancialTransaction.bukrs     as CompanyCode,
  key TransactionCondition.sanlf     as FinancialInstrProductCategory,
  key FinancialTransaction.rfhazul   as FinancialInstrumentActivity,
  key TransactionCondition.rkey1     as SecurityClass,
  key TransactionCondition.nstufe    as ConditionLevelNumber,
  key FinancialTransaction.rldepo    as SecurityAccount,
  key TransactionCondition.skoart    as FinInstrConditoinType,
      TransactionCondition.dguel_kp  as ConditionItemValidityStartDate,
      TransactionCondition.sincl     as CalcDateIsAsEndDateInclusive,
      TransactionCondition.pkond     as ConditionPercentageRate,
      TransactionCondition.bkond     as ConditionFixAmount,
      TransactionCondition.szsref    as ReferenceInterestRate,
      FinancialTransaction.sgsart    as FinancialInstrumentProductType,
      cast('' as tb_sfhaart )        as FinancialInstrTransactionType, //keep trans. type as empty for security

      FinancialTransaction.wgschft   as TransactionCurrency,
      FinancialTransaction.rantyp    as ContractType,
      FinancialTransaction.dblfz     as TermStartDate,
      FinancialTransaction.delfz     as TermEndDate,
      TransactionCondition.szsrefvz  as CashFlowDirection,
      TransactionCondition.pkond     as InterestRateInPercent

}
where   //1. Active transaction

        FinancialTransaction.saktiv   =  '0'

  and(  //2. Open transaction

        FinancialTransaction.dblfz    <= $parameters.P_KeyDate
    and TransactionCondition.dguel_kp <= $parameters.P_KeyDate
  )

  and(  //3. relevant product category

        FinancialTransaction.sanlf    =  '020'
    or  FinancialTransaction.sanlf    =  '040'
    or  FinancialTransaction.sanlf    =  '042'
    or  FinancialTransaction.sanlf    =  '060'
    or  FinancialTransaction.sanlf    =  '070'
  )

  and(  //4. Interest condition

        ConditionType.sberfima        =  'TZ'
    or  ConditionType.sberfima        =  'UATZ'
  )

  and(  //5. Interest rate not empty

        TransactionCondition.pkond    >  0
    or  TransactionCondition.bkond    >  0
    or  TransactionCondition.szsref   <> ''
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"TZK01",
"VTBFHA",
"VZZKOPO"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/