P_SalesContractProcessFlow0

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@VDM.private: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'PSLSCONTRPROCF0'
@AbapCatalog.preserveKey:true 
@AbapCatalog.compiler.compareFilter:true
@EndUserText.label: 'Contract process flow level 0'
define view P_SalesContractProcessFlow0
  with parameters P_SalesContract: vbeln_von
  as select from I_SalesContractItem as SalesContractItem
  inner join I_SalesContract         as _SalesContract   on SalesContractItem.SalesContract = _SalesContract.SalesContract
  left outer to one join I_SDDocumentCategory  as _SDDocumentCategory on _SDDocumentCategory.SDDocumentCategory = 'G'
  association [0..1] to I_UnitOfMeasure  as _BaseUnit             on $projection.BaseUnit           = _BaseUnit.UnitOfMeasure
  association [0..1] to I_Currency       as _StatisticsCurrency   on $projection.StatisticsCurrency = _StatisticsCurrency.Currency
{ 
  key  SalesContractItem.SalesContract,
  key  SalesContractItem.SalesContractItem,
  key  cast( 'G' as vbtypl )                              as SDDocumentCategory,
       @Semantics.quantity.unitOfMeasure: 'BaseUnit'
       SalesContractItem.TargetQuantity                   as QuantityInBaseUnit,
       SalesContractItem.TargetQuantityUnit               as BaseUnit,
       @Semantics.amount.currencyCode: 'StatisticsCurrency'
       SalesContractItem.NetAmount,
       @Semantics.currencyCode: true
       SalesContractItem.TransactionCurrency              as StatisticsCurrency,
       cast( '' as status_bez )                           as SDProcessStatusDesc,
       cast( '0000' as gjahr )                            as FiscalYear,
       cast( '' as bukrs )                                as CompanyCode,
       cast( '0000' as mjahr )                            as MaterialDocumentYear,
       cast( 'SalesContract' as bpf_sem_obj )             as SemanticObject,
       _SDDocumentCategory._Text[1:Language=$session.system_language].SDDocumentCategoryName  as SDDocumentCategoryName,
       _SalesContract.CreationDate,
       _SalesContract.CreationTime,
       _BaseUnit, 
       _StatisticsCurrency
} where SalesContractItem.SalesContract = $parameters.P_SalesContract
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESCONTRACT",
"I_SALESCONTRACTITEM",
"I_SDDOCUMENTCATEGORY",
"I_SDDOCUMENTCATEGORYTEXT"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/