P_SDMCAPACITYPPOCMIGRATION

@AbapCatalog.sqlViewName: 'PSDMPPOC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'SDM CDS for Capacity PPOC Migration'
@VDM.viewType: #BASIC
@VDM.private: true
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_SDMCAPACITYPPOCMIGRATION
  as select from            kako             as _CapacityHeader
    inner join              /sapapo/reskey   as _ResourceKey     on _ResourceKey.r3kapid = _CapacityHeader.kapid
    inner join              /sapapo/res_head as _ResourceHead    on  _ResourceHead.resuid    = _ResourceKey.resuid
                                                                 and _ResourceHead.simversid = '000'
    left outer to many join /sapapo/res_ppoc as _ResourcePpoc    on  _ResourcePpoc.resuid    = _ResourceHead.resuid
                                                                 and _ResourcePpoc.simversid = _ResourceHead.simversid
                                                                 and _ResourcePpoc.simsessid = _ResourceHead.simsessid
    left outer to many join kappoc           as _CostConstraints on  _CostConstraints.kapid                = _CapacityHeader.kapid
                                                                 and _CostConstraints.offset_wrt_curr_date = _ResourcePpoc.offset_wrt_curr_date
{
  key    _CapacityHeader.kapid              as CapacityID,
  key    case
         when   (   _CostConstraints.kapid             is null
         and        _ResourcePpoc.offset_wrt_curr_date is not initial )
         then '00'
         when   (   _ResourceHead.campaign_snp   is not initial
         and        _ResourceHead.campaign_snp   <> _CapacityHeader.campaign_ppo )
         then '00'
         else '01' end                      as MigrationStatus,
         _ResourcePpoc.offset_wrt_curr_date as OffsetWrtCurrDate,
         _ResourcePpoc.normal_cap_cost      as NormalCapCost,
         _ResourcePpoc.minimum_cap_cost     as MinimumCapCost,
         _ResourcePpoc.extended_cap_cost    as ExtendedCapCost,
         _ResourcePpoc.minimum_cap_util     as MinimumCapUtil,
         _ResourcePpoc.extended_cap_util    as ExtendedCapUtil,
         _ResourceHead.campaign_snp         as CampaignPpo
}

where
     _ResourceHead.campaign_snp         is not initial
  or _ResourcePpoc.offset_wrt_curr_date is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"/SAPAPO/RESKEY",
"/SAPAPO/RES_HEAD",
"/SAPAPO/RES_PPOC",
"KAKO",
"KAPPOC"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/