P_RqdPrsnlProtectiveEquipAtLoc

@VDM.private: true
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'PPPEATLOC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #NOT_REQUIRED

// Client handling by session

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType:{ serviceQuality: #B,        // < 15 msec

                         sizeCategory:  #M,         // < 100.000

                         dataClass: #MIXED }

define view P_RqdPrsnlProtectiveEquipAtLoc  
  as select from ehhssd_rsk_ctrl as EHSRiskControl 
  inner join ehhssd_rsk_root as EHSRiskRoot on EHSRiskRoot.db_key = EHSRiskControl.root_key 
  inner join ehhssd_rsk_rev as EHSRiskRevision on EHSRiskRevision.db_key = EHSRiskControl.parent_key 
  inner join ehfndd_ctrl_root as EHSControlRoot on EHSControlRoot.db_key = EHSRiskControl.control_code
  inner join ehfndc_control as EHSCtrlCatalog on EHSCtrlCatalog.code = catalog_code
  left outer join  ehfndd_ctrl_text as EHSCtrlTitleTxt on EHSCtrlTitleTxt.parent_key =  EHSControlRoot.db_key
{
  key EHSRiskControl.db_key                                                             as EHSControlInstanceUUID,
      cast( EHSRiskRoot.loc_root_key_ref as ehfnd_location_uuid_ref preserving type )   as EHSLocationUUID,      
      cast( EHSRiskRoot.job_key_ref as ehhss_job_uuid_ref preserving type )             as EHSJobUUID,
      cast( EHSRiskControl.root_key as ehhss_risk_key_ref preserving type )             as EHSRiskUUID,
      EHSControlRoot.catalog_code                                                       as EHSControlCatalog,
      EHSCtrlTitleTxt.text                                                              as EHSControlTitle,
      EHSCtrlTitleTxt.language,
      cast( EHSRiskControl.impl_status as ehhss_ctrl_impl_status_nc preserving type )   as EHSControlImplStatus
}
where EHSRiskRevision.status = '03'
  and EHSRiskControl.proposal_ind = ' '
  and EHSCtrlCatalog.type = 'EHFND_ACTT_01_PERSON'
  and EHSCtrlCatalog.subject  = 'EHFND_ACTS_PPE'
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"EHFNDC_CONTROL",
"EHFNDD_CTRL_ROOT",
"EHFNDD_CTRL_TEXT",
"EHHSSD_RSK_CTRL",
"EHHSSD_RSK_REV",
"EHHSSD_RSK_ROOT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0
}
}*/