P_ResvnDocManualGoodsMvtType

@AbapCatalog.sqlViewName: 'PRESVNMNLGOODMVT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM: {
  private: true,
  viewType: #COMPOSITE
}
@ObjectModel: {
                usageType: {
                             sizeCategory: #S,
                             serviceQuality: #A,
                             dataClass:#CUSTOMIZING
                           } }
define view P_ResvnDocManualGoodsMvtType
  as select from I_GdsMvtTypeByInvtryTransCode
    inner join   I_GoodsMovementType as _GoodsMovementType on I_GdsMvtTypeByInvtryTransCode.GoodsMovementType = _GoodsMovementType.GoodsMovementType
{
  key I_GdsMvtTypeByInvtryTransCode.GoodsMovementType,
      I_GdsMvtTypeByInvtryTransCode._Text
}
where
  (
       I_GdsMvtTypeByInvtryTransCode.InventoryTransactionCode =    'MB21'
    or I_GdsMvtTypeByInvtryTransCode.InventoryTransactionCode =    'MB22' // added for Mvt type 541

  ) 
  and(
       I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '201' // Consumption for cost center from warehouse(GI for cost center)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '202' // Consumption for cost center from warehouse – reversal(RE for cost center)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '221' // Consumption for project from warehouse(GI for project)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '222' // Consumption for project from warehouse - reversal(RE for project)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '231' // Consumption for sales order from warehouse(GI for sales order)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '232' // Consumption for sales order from warehouse - reversal(RE for sales order)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '241' // Consumption for asset from warehouse(GI for asset)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '242' // Consumption for asset from warehouse - reversal(RE for asset)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '251' // Consumption for sales from warehouse(GI for sales)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '252' // Consumption for sales from warehouse - reversal(RE for sales)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '261' // Consumption for order from warehouse(GI for order)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '262' // Consumption for order from warehouse - reversal(RE for order)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '291' // Consumption for all account assignments from warehouse(GI all acc. assigmts)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '292' // Consumption for all accnt assigmts from warehouse - reversal(RE all acct assigmts)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '301' // Transfer posting plant to plant (one-step)(TF trfr plnt to plnt)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '302' // Transfer posting plant to plant (one-step) - reversal(TR trfr plnt to plnt)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '311' // Transfer posting storage location (one-step)(TF trfr within plant)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '312' // Transfer posting storage location (one-step) - reversal(TR transfer in plant)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '501' // Receipt w/o purchase order into warehouse(Receipt w/o PO)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '502' // Receipt w/o purchase order into warehouse – reversal(RE receipt w/o PO)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '503' // Receipt w/o purchase order into warehouse(Receipt to QI)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '504' // Receipt w/o purchase order into warehouse – reversal(RE receipt to QI)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '505' // Receipt w/o purchase order into warehouse(Receipt to blocked)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '506' // Receipt w/o purchase order into warehouse - reversal(RE receipt to blockd)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '521' // Receipt from production to unrestricted-use(Receipt w/o order)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '522' // Receipt from production to unrestricted-use - reversal(RE receipt w/o prOrd)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '523' // Receipt from production to quality inspection(Rcpt QI w/o prOrder)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '524' // Receipt from production to quality inspection - reversal(RE quality w/o prOrd(

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '525' // Receipt from production to blocked stock(Rcpt blkd w/o pr.ord)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '526' // Receipt from production to blocked stock - reversal(RE blocked w/o PrOrd)

    or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType        =    '541' // Trfr pstng to stock with subcontractor from unrestr.-use st.

    or (    
       ( I_GdsMvtTypeByInvtryTransCode.GoodsMovementType      like '9%' 
      or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType      like 'X%'
      or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType      like 'Y%'
      or I_GdsMvtTypeByInvtryTransCode.GoodsMovementType      like 'Z%' ) 
    and  _GoodsMovementType.SourceGoodsMovementType           <>   ''   //to eliminate cust Mvt.Types that are copied before MVT_SOURCE was introduced

    )
  )
  //eliminate Cust Mvt.Types that are copied from unsupported Mvt.Types by manual reservations 

  and  _GoodsMovementType.SourceGoodsMovementType          not like '28%'
  and  _GoodsMovementType.SourceGoodsMovementType          not like '41%'
  and  _GoodsMovementType.SourceGoodsMovementType          not like '53%'
  and  _GoodsMovementType.SourceGoodsMovementType          not like '57%'
  and  _GoodsMovementType.SourceGoodsMovementType          not like '58%'
  //eliminate Mvt.Types copied from custom Mvt.Type   

  and  _GoodsMovementType.SourceGoodsMovementType          not like '9%' 
  and  _GoodsMovementType.SourceGoodsMovementType          not like 'X%' 
  and  _GoodsMovementType.SourceGoodsMovementType          not like 'Y%' 
  and  _GoodsMovementType.SourceGoodsMovementType          not like 'Z%' 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_GDSMVTTYPEBYINVTRYTRANSCODE",
"I_GOODSMOVEMENTTYPE"
],
"ASSOCIATED":
[
"I_GOODSMVTTYPEBYSPCLSTKINDT"
],
"BASE":
[
"I_GDSMVTTYPEBYINVTRYTRANSCODE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/