P_RepFinData_RT_AggrNRL_02

@AbapCatalog.sqlViewName: 'PRFDRTAGNRL_02'
@AbapCatalog.compiler.compareFilter: true

@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true

// Aggregate over timestamp and posting date

define view P_RepFinData_RT_AggrNRL_02
  with parameters
    P_CreationDateTimeRgFr :timestamp,
    P_CreationDateTimeRgTo :timestamp

  as select from P_RepFinData_RT_AggrNRL_01
                 (P_CreationDateTimeRgFr   : :P_CreationDateTimeRgFr,
                  P_CreationDateTimeRgTo   : :P_CreationDateTimeRgTo) as Source

    inner join   I_CompanyCode              on Source.CompanyCode = I_CompanyCode.CompanyCode

    inner join   I_CnsldtnUnit_3            on I_CompanyCode.Company = I_CnsldtnUnit_3.Company

    inner join   I_CnsldtnUnitByTimeVersion on  I_CnsldtnUnit_3.ConsolidationDimension               =       I_CnsldtnUnitByTimeVersion.ConsolidationDimension
                                            and I_CnsldtnUnit_3.ConsolidationUnit                    =       I_CnsldtnUnitByTimeVersion.ConsolidationUnit
                                            and Source.FiscalYearPeriod                              between I_CnsldtnUnitByTimeVersion.FromFiscalYearPeriod and I_CnsldtnUnitByTimeVersion.ToFiscalYearPeriod
                                            and I_CnsldtnUnitByTimeVersion.CnsldtnDataTransferMethod =       'H'

    inner join   I_CnsldtnVersion           on  I_CnsldtnUnitByTimeVersion.CnsldtnUnitAttributeVersion = I_CnsldtnVersion.CnsldtnUnitAttributeVersion
                                            and Source.Ledger                                          = I_CnsldtnVersion.CnsldtnSourceLedger
                                            and I_CnsldtnVersion.CnsldtnIsPlanVersion                  = ''

    inner join   I_FiscalCalendarDate       on  (
              I_CnsldtnUnitByTimeVersion.FiscalYearVariant                                        =       I_FiscalCalendarDate.FiscalYearVariant
              and Source.PostingDate                                                              =       I_FiscalCalendarDate.CalendarDate
              and I_CnsldtnUnitByTimeVersion.FiscalYearVariant                                    <>      ''
              and I_CnsldtnUnitByTimeVersion.FiscalYearVariant                                    is not null
            )
                                            or  (
                                                I_CnsldtnVersion.FiscalYearVariant                =       I_FiscalCalendarDate.FiscalYearVariant
                                                and Source.PostingDate                            =       I_FiscalCalendarDate.CalendarDate
                                                and(
                                                  I_CnsldtnUnitByTimeVersion.FiscalYearVariant    =       ''
                                                  or I_CnsldtnUnitByTimeVersion.FiscalYearVariant is null
                                                )
                                                and I_CnsldtnVersion.FiscalYearVariant            <>      ''
                                              )
                                            or  (
                                                I_FiscalCalendarDate.FiscalYearVariant            =       'K4'
                                                and Source.PostingDate                            =       I_FiscalCalendarDate.CalendarDate
                                                and(
                                                  I_CnsldtnUnitByTimeVersion.FiscalYearVariant    =       ''
                                                  or I_CnsldtnUnitByTimeVersion.FiscalYearVariant is null
                                                )
                                                and I_CnsldtnVersion.FiscalYearVariant            =       ''
                                              )
                                            and I_FiscalCalendarDate.FiscalYearPeriod             between I_CnsldtnUnitByTimeVersion.FromFiscalYearPeriod and I_CnsldtnUnitByTimeVersion.ToFiscalYearPeriod

{

  I_CnsldtnUnit_3.ConsolidationDimension,
  I_CnsldtnUnit_3.ConsolidationUnit,

  I_CompanyCode.ChartOfAccounts as ReferenceChartOfAccounts,

  I_CnsldtnVersion.ConsolidationVersion,
  I_CnsldtnVersion.FSItemMappingVersion,
  I_CnsldtnVersion.ConsolidationLedger,
  I_CnsldtnVersion.GroupCurrency,

  I_CnsldtnUnitByTimeVersion.DocumentEntryIsInGroupCurrency,
  I_CnsldtnUnitByTimeVersion.CnsldtnUnitGroupCrcySource,
  I_CnsldtnUnitByTimeVersion.CnsldtnUnitLocalCrcySource,

  I_FiscalCalendarDate.FiscalPeriod,
  I_FiscalCalendarDate.FiscalYear,
  I_FiscalCalendarDate.FiscalYearPeriod,

  // mandatory standard fields

  /*Source.PartnerCompany,*/
  Source.BalanceTransactionCurrency,
  Source.BaseUnit,
  Source.FinancialTransactionType,
  Source.FunctionalArea,
  Source.BusinessArea,
  Source.CostCenter,
  Source.GLAccount,
  Source.ProfitCenter,
  AmountInTransactionCurrency,
  AmountInLocalCurrency,
  AmountInGroupCurrency,
  QuantityInBaseUnit,
  Source.osl,
  Source.vsl,
  Source.bsl,
  Source.csl,
  Source.dsl,
  Source.esl,
  Source.fsl,
  Source.gsl,
  Source.Segment,

  // additional fields

  Source.PartnerCompany,
  Source.CompanyCode,
  Source.ChartOfAccounts,
  Source.AssignmentReference,
  Source.ControllingArea,
  Source.PartnerCostCenter,
  Source.PartnerProfitCenter,
  Source.PartnerFunctionalArea,
  Source.PartnerBusinessArea,
  Source.PartnerSegment,
  Source.OrderID,
  Source.Customer,
  Source.Supplier,
  Source.Material,
  Source.MaterialGroup,
  Source.Plant,
  Source.WBSElementExternalID,
  Source.Project,
  Source.BillingDocumentType,
  Source.SalesOrganization,
  Source.DistributionChannel,
  Source.OrganizationDivision,
  Source.SoldProduct,
  Source.SoldProductGroup,
  Source.CustomerGroup,
  Source.CustomerSupplierCountry,
  Source.CustomerSupplierIndustry,
  Source.SalesDistrict,
  Source.BillToParty,
  Source.ShipToParty,
  Source.CustomerSupplierCorporateGroup,
  Source.WBSElementInternalID,
  Source.CreationDateTime,

  // specific fileds for this cds view

  Source.SourceLedger
  /*Source.Ledger,*/
  /*Source.PostingDate,*/
  /*Source.FiscalYearPeriod,*/

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CNSLDTNUNITBYTIMEVERSION",
"I_CNSLDTNUNIT_3",
"I_CNSLDTNVERSION",
"I_COMPANYCODE",
"I_FISCALCALENDARDATE",
"P_REPFINDATA_RT_AGGRNRL_01"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/