P_RecipeFormulaItmForExplsnScp

@AbapCatalog.sqlViewName: 'PRCPFML4EXPLSCP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.private: true
@VDM.lifecycle.contract.type: #NONE
@VDM.viewType: #COMPOSITE

/**
 * Helper view for handling explosion stop in recipes, which creates a view for the formula items
 * in which a virtual PO line is generated where the property specification is used. The union
 * with the two paths is to replace a calculated attribute (and the filtering on that).
 */
define view P_RecipeFormulaItmForExplsnScp
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate : sydate
  as select from I_RecipeFormulaItemForKeyDate( P_KeyDate : $parameters.P_KeyDate ) as formula
    inner join   I_RecipeFormulaItemForKeyDate( P_KeyDate : $parameters.P_KeyDate ) as po on  formula.RcpFmlaUUID         = po.RcpFmlaUUID
                                                                                          and po.RcpFmlaItemType          = 'PO'
                                                                                          and po.RecipeFmlaItemAltvIsUsed = 'X'

{
  key formula.RcpFmlaItemUUID,
      formula.RcpFmlaUUID,
      formula.RcpFmlaItemSourceFmlaItemUUID,
      formula.RcpFmlaItemPosition,
      formula.RcpFmlaItemAlternativeItemPos,
      formula.RcpFmlaItemType,
      formula.SpecificationInternalID,
      formula.Material,
      formula.RcpFmlaStreamUUID,
      formula.RcpFmlaItemComponentType,
      formula.RcpFmlaItemLowerLimit,
      formula.RcpFmlaItemUpperLimit,
      formula.RcpFmlaItemQuantity,
      formula.RcpFmlaItemUnit,
      formula.RcpFmlaItemExceptionCode,
      formula.RcpFmlaItemScrapInPercent,
      formula.RcpFmlaItemOverrunInPercent,
      formula.RcpFmlaItemAlternativeItemUUID,
      formula.RcpFmlaItemQuantityInKilogram,
      formula.RcpFmlaItemZeroSign,
      formula.RcpFmlaItemIsSelectedForCalc,
      formula.RcpFmlaItemExplosionRecipeUUID,
      formula.RcpFmlaCalculationType,
      formula.RcpFmlaItemIsBalancingItem,
      formula.RecipeFmlaItemAltvIsUsed,
      formula.RecipeUUID,
      ''                          as Path,
      po.RcpFmlaItemComponentType as RcpPrimOutpComponentType,

      formula._ComponentType,
      formula._Product,
      formula._RecipeForKeyDate,
      formula._RecipeProcessElementAssgmt
}
// alternative POs are not relevant

where
     formula.RcpFmlaItemType          <> 'PO'
  or formula.RecipeFmlaItemAltvIsUsed =  'X'
union select from I_RecipeFormulaItemForKeyDate( P_KeyDate : $parameters.P_KeyDate ) as formula
  inner join      I_RecipeFormulaItemForKeyDate( P_KeyDate : $parameters.P_KeyDate ) as po on  formula.RcpFmlaUUID         = po.RcpFmlaUUID
                                                                                           and po.RcpFmlaItemType          = 'PO'
                                                                                           and po.RecipeFmlaItemAltvIsUsed = 'X'

{

  key formula.RcpFmlaItemUUID,
      formula.RcpFmlaUUID,
      formula.RcpFmlaItemSourceFmlaItemUUID,
      formula.RcpFmlaItemPosition,
      formula.RcpFmlaItemAlternativeItemPos,
      formula.RcpFmlaItemType,
      formula._RecipeForKeyDate( P_KeyDate : $parameters.P_KeyDate ).RecipePropertySpecInternalID            as SpecificationInternalID, // replace spec by prop spec.

      formula.Material,
      formula.RcpFmlaStreamUUID,
      formula.RcpFmlaItemComponentType,
      formula.RcpFmlaItemLowerLimit,
      formula.RcpFmlaItemUpperLimit,
      formula.RcpFmlaItemQuantity,
      formula.RcpFmlaItemUnit,
      formula.RcpFmlaItemExceptionCode,
      formula.RcpFmlaItemScrapInPercent,
      formula.RcpFmlaItemOverrunInPercent,
      formula.RcpFmlaItemAlternativeItemUUID,
      formula.RcpFmlaItemQuantityInKilogram,
      formula.RcpFmlaItemZeroSign,
      formula.RcpFmlaItemIsSelectedForCalc,
      formula.RcpFmlaItemExplosionRecipeUUID,
      formula.RcpFmlaCalculationType,
      formula.RcpFmlaItemIsBalancingItem,
      formula.RecipeFmlaItemAltvIsUsed,
      formula.RecipeUUID,
      cast('P' as char1)                                                                                     as Path,
      po.RcpFmlaItemComponentType                                                                            as RcpPrimOutpComponentType,

      formula._ComponentType,
      formula._Product,
      formula._RecipeForKeyDate,
      formula._RecipeProcessElementAssgmt
}
// replacement is only needed for the (used) PO line

where
      formula.RcpFmlaItemType          = 'PO'
  and formula.RecipeFmlaItemAltvIsUsed = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_RECIPEFORKEYDATE",
"I_RECIPEFORMULAITEMFORKEYDATE"
],
"ASSOCIATED":
[
"I_PRODUCT",
"I_RECIPEFORKEYDATE",
"I_RECIPEPROCESSELEMENTASSGMT",
"I_SPECCOMPONENTTYPE"
],
"BASE":
[
"I_RECIPEFORMULAITEMFORKEYDATE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/