P_RU_VATDocumentExtraInfo1

@VDM.private: true
@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'PRUVATDOCEXTINF1'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_RU_VATDocumentExtraInfo1
  //data from ExtraTexts

  as select from           I_JournalEntry          as AccDoc

    inner join             P_RU_CFinVatDocExtrasCm as VatLongTexts  on  VatLongTexts.CompanyCode        =  AccDoc.CompanyCode
                                                                    and VatLongTexts.AccountingDocument =  AccDoc.AccountingDocument
                                                                    and VatLongTexts.FiscalYear         =  AccDoc.FiscalYear
                                                                    and (
                                                                       VatLongTexts.ExternalInvoice     <> ''
                                                                       or VatLongTexts.InvoiceDate      <> '00000000'
                                                                     )

    left outer to one join P_RU_ExtNumByDefault    as ExtNumDefault on  ExtNumDefault.CompanyCode               = AccDoc.CompanyCode
                                                                    and ExtNumDefault.AccountingDocumentType    = AccDoc.AccountingDocumentType
                                                                    and ExtNumDefault.ExtDocNmbrAndDteAreFilled = 'X'

{
  key AccDoc.CompanyCode,
  key AccDoc.AccountingDocument,
  key AccDoc.FiscalYear,
      AccDoc.AccountingDocumentType,

      VatLongTexts.ExternalInvoice as ManualExternalInvoice,
      VatLongTexts.InvoiceDate     as ManualExternalInvoiceDate,

      ExtNumDefault.ExtDocNmbrAndDteAreFilled,
      case when ExtNumDefault.ExtDocNmbrAndDteAreFilled is not null
           then case when AccDoc.SenderLogicalSystem <> ''
                     then ltrim(AccDoc.SenderAccountingDocument, '0')
                     else ltrim(AccDoc.AccountingDocument,       '0')
                end
           else ''
      end                          as DefaultExternalInvoice,
      case when ExtNumDefault.CompanyCode is not null
           then AccDoc.DocumentDate
           else '00010101'                                                  //if set 00000000 - attribute will not output in XML. To output it with empty value, we replace 00010101 on empty in the formatter method

      end                          as DefaultExternalInvoiceDate,

      AccDoc.SenderLogicalSystem,
      AccDoc.SenderCompanyCode,
      AccDoc.SenderAccountingDocument,
      AccDoc.SenderFiscalYear,

      ''                           as ExternalInvoice,
      '00000000'                   as InvoiceDate,
      ''                           as ExternalPayment,
      '00000000'                   as PaymentDate,
      ''                           as Supplier,
      ''                           as Customer,
      ''                           as RU_IncomingInvoiceNumber,
      '00000000'                   as RU_IncomingInvoiceDate
}

//data from BKPF (if ExtraTexts do not exist)

union all select from    I_JournalEntry          as AccDoc

  inner join             P_RU_ExtNumByDefault    as ExtNumDefault on  ExtNumDefault.CompanyCode               = AccDoc.CompanyCode
                                                                  and ExtNumDefault.AccountingDocumentType    = AccDoc.AccountingDocumentType
                                                                  and ExtNumDefault.ExtDocNmbrAndDteAreFilled = 'X'

  left outer to one join P_RU_CFinVatDocExtrasCm as VatLongTexts  on  VatLongTexts.CompanyCode        =  AccDoc.CompanyCode
                                                                  and VatLongTexts.AccountingDocument =  AccDoc.AccountingDocument
                                                                  and VatLongTexts.FiscalYear         =  AccDoc.FiscalYear
                                                                  and (
                                                                     VatLongTexts.ExternalInvoice     <> ''
                                                                     or VatLongTexts.InvoiceDate      <> '00000000'
                                                                   )

{
  key AccDoc.CompanyCode,
  key AccDoc.AccountingDocument,
  key AccDoc.FiscalYear,
      AccDoc.AccountingDocumentType,

      ''                  as ManualExternalInvoice,
      '00000000'          as ManualExternalInvoiceDate,

      ExtNumDefault.ExtDocNmbrAndDteAreFilled,
      case when AccDoc.SenderLogicalSystem <> ''
           then ltrim(AccDoc.SenderAccountingDocument, '0')
           else ltrim(AccDoc.AccountingDocument,       '0')
      end                 as DefaultExternalInvoice,
      AccDoc.DocumentDate as DefaultExternalInvoiceDate,

      AccDoc.SenderLogicalSystem,
      AccDoc.SenderCompanyCode,
      AccDoc.SenderAccountingDocument,
      AccDoc.SenderFiscalYear,

      ''                  as ExternalInvoice,
      '00000000'          as InvoiceDate,
      ''                  as ExternalPayment,
      '00000000'          as PaymentDate,
      ''                  as Supplier,
      ''                  as Customer,
      ''                  as RU_IncomingInvoiceNumber,
      '00000000'          as RU_IncomingInvoiceDate
}
where
      VatLongTexts.CompanyCode is null
  and AccDoc.TaxReportingDate  <> '00000000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JOURNALENTRY",
"P_RU_CFINVATDOCEXTRASCM",
"P_RU_EXTNUMBYDEFAULT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/