P_RU_RealReversedDocument

@VDM.private: true
@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'PRURREVERSEDDOC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType: {
    serviceQuality: #B,
    sizeCategory: #XXL,
    dataClass: #TRANSACTIONAL
}
define view P_RU_RealReversedDocument
  as select from I_JournalEntry           as ReversalDoc

    inner join   P_RU_AcctgDocReferenceID as ReversedDoc on  ReversedDoc.CompanyCode                    = ReversalDoc.CompanyCode
                                                         and ReversedDoc.ReferenceDocumentType          = ReversalDoc.ReferenceDocumentType
                                                         and ReversedDoc.OriginalReferenceDocumentCntxt = ReversalDoc.ReversalReferenceDocumentCntxt
                                                         and ReversedDoc.OriginalReferenceDocumentNum   = ReversalDoc.ReversalReferenceDocument
                                                         and ReversedDoc.SenderLogicalSystem            = ReversalDoc.SenderLogicalSystem
                                                         and ReversedDoc.LedgerGroup                    = ReversalDoc.LedgerGroup

{
  key ReversedDoc.CompanyCode,

  key ReversedDoc.AccountingDocument,
  key ReversedDoc.FiscalYear,
      ReversedDoc.AccountingDocumentType,
      ReversedDoc.PostingDate,
      ReversedDoc.TaxReportingDate,
      ReversedDoc.DocumentReferenceID,
      ReversedDoc.ReferenceDocumentType,
      ReversedDoc.OriginalReferenceDocumentCntxt,
      ReversedDoc.OriginalReferenceDocumentNum,
      ReversedDoc.IsReversal,
      ReversedDoc.IsReversed,
      ReversedDoc.ReverseDocument           as ReversalDocumentBKPF,
      ReversedDoc.ReverseDocumentFiscalYear as ReversalDocumentFiscalYearBKPF,

      ReversalDoc.AccountingDocument        as ReversalDocument,
      ReversalDoc.FiscalYear                as ReversalDocumentFiscalYear,
      ReversalDoc.AccountingDocumentType    as ReversalDocumentType,
      ReversalDoc.PostingDate               as ReversalDocumentPostingDate,
      ReversalDoc.TaxReportingDate          as ReversalDocumentTaxRepDate,
      ReversalDoc.DocumentReferenceID       as ReversalDocumentReferenceID,
      ReversalDoc.ReferenceDocumentType     as ReversalDocumentRefDocType,
      ReversalDoc.ReversalReferenceDocumentCntxt,
      ReversalDoc.ReversalReferenceDocument,
      ReversalDoc.IsReversal                as ReversalDocumentIsReversal,
      ReversalDoc.IsReversed                as ReversalDocumentIsReversed,
      ReversalDoc.ReverseDocument           as ReversedDocumentBKPF,
      ReversalDoc.ReverseDocumentFiscalYear as ReversedDocumentFiscalYearBKPF,

      ReversalDoc.LedgerGroup,
      ReversalDoc.CompanyCodeCurrency,
      'REAL'                                as RU_ReverseType
}
where
      ReversedDoc.IsReversed = 'X'
  and ReversalDoc.IsReversal = 'X'
  and ReversedDoc.AccountingDocumentCategory <> 'U' 
  and ReversalDoc.AccountingDocumentCategory <> 'U'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JOURNALENTRY",
"P_RU_ACCTGDOCREFERENCEID"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/